1 files changed, 46 insertions, 0 deletions
diff --git a/dev-ruby/actionpack/actionpack-4.1.7.ebuild b/dev-ruby/actionpack/actionpack-4.1.7.ebuild
new file mode 100644
index 000000000000..f535b1bbb6b0
--- /dev/null
+++ b/dev-ruby/actionpack/actionpack-4.1.7.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/actionpack/actionpack-4.1.7.ebuild,v 1.1 2014/10/31 08:57:35 graaff Exp $
+
+EAPI=5
+
+USE_RUBY="ruby19 ruby20 ruby21"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.rdoc"
+
+RUBY_FAKEGEM_GEMSPEC="actionpack.gemspec"
+
+inherit ruby-fakegem versionator
+
+DESCRIPTION="Eases web-request routing, handling, and response"
+HOMEPAGE="http://rubyforge.org/projects/actionpack/"
+SRC_URI="http://github.com/rails/rails/archive/v${PV}.tar.gz -> rails-${PV}.tgz"
+
+LICENSE="MIT"
+SLOT="$(get_version_component_range 1-2)"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64"
+IUSE=""
+
+RUBY_S="rails-${PV}/${PN}"
+
+ruby_add_rdepend "
+	~dev-ruby/activesupport-${PV}
+	~dev-ruby/actionview-${PV}
+	>=dev-ruby/rack-1.5.2:1.5
+	>=dev-ruby/rack-test-0.6.2:0.6"
+
+ruby_add_bdepend "
+	test? (
+		dev-ruby/mocha:0.14
+		dev-ruby/bundler
+		~dev-ruby/activemodel-${PV}
+		>=dev-ruby/rack-cache-1.2:1.2
+	)"
+
+all_ruby_prepare() {
+	# Remove items from the common Gemfile that we don't need for this
+	# test run. This also requires handling some gemspecs.
+	sed -i -e "/\(system_timer\|sdoc\|w3c_validators\|pg\|jquery-rails\|'mysql'\|journey\|ruby-prof\|benchmark-ips\|kindlerb\|turbolinks\|coffee-rails\|debugger\|sprockets-rails\|redcarpet\|bcrypt\|uglifier\|minitest\)/ s:^:#:" ../Gemfile || die
+}