1 files changed, 64 insertions, 0 deletions
diff --git a/dev-python/pylint/pylint-0.19.0.ebuild b/dev-python/pylint/pylint-0.19.0.ebuild
new file mode 100644
index 000000000000..b892ed7a61af
--- /dev/null
+++ b/dev-python/pylint/pylint-0.19.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pylint/pylint-0.19.0.ebuild,v 1.1 2009/12/19 18:59:19 arfrever Exp $
+
+EAPI="2"
+SUPPORT_PYTHON_ABIS="1"
+
+inherit distutils
+
+DESCRIPTION="a tool to check if a Python module satisfies a coding standard"
+HOMEPAGE="http://www.logilab.org/projects/pylint/ http://pypi.python.org/pypi/pylint"
+SRC_URI="ftp://ftp.logilab.org/pub/${PN}/${P}.tar.gz http://pypi.python.org/packages/source/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-macos"
+IUSE="doc examples test tk"
+
+DEPEND=">=dev-python/logilab-common-0.44.0
+	>=dev-python/astng-0.19.0"
+RDEPEND="${DEPEND}
+	dev-lang/python[tk?]"
+RESTRICT_PYTHON_ABIS="3.*"
+
+src_prepare() {
+	distutils_src_prepare
+
+	# Disable failing tests.
+	rm -f test/input/func_arguments.py
+	sed -e "s/test_exhaustivity/_&/" -i test/test_func.py || die "sed failed"
+}
+
+src_test() {
+	testing() {
+		PYTHONPATH="build-${PYTHON_ABI}/lib" pytest -v
+	}
+	python_execute_function testing
+}
+
+src_install() {
+	distutils_src_install
+
+	doman man/{pylint,pyreverse}.1 || die "doman failed"
+	dodoc doc/FAQ.txt || die "dodoc failed"
+
+	if use doc; then
+		dodoc doc/*.txt || die "dodoc failed"
+	fi
+
+	if use examples; then
+		docinto examples
+		dodoc examples/* || die "dodoc failed"
+	fi
+}
+
+pkg_postinst() {
+	distutils_pkg_postinst
+
+	if ! has_version dev-lang/python[tk]; then
+		ewarn "dev-lang/python has been built without tk support,"
+		ewarn "${PN}-gui doesn't work without Tkinter so if you really need it,"
+		ewarn "re-install dev-lang/python with \"tk\" useflag enabled."
+	fi
+}