1 files changed, 56 insertions, 0 deletions
diff --git a/dev-python/pygtkhelpers/pygtkhelpers-0.4.3.ebuild b/dev-python/pygtkhelpers/pygtkhelpers-0.4.3.ebuild
new file mode 100644
index 000000000000..b2937f27d96d
--- /dev/null
+++ b/dev-python/pygtkhelpers/pygtkhelpers-0.4.3.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pygtkhelpers/pygtkhelpers-0.4.3.ebuild,v 1.1 2012/01/11 23:38:52 ssuominen Exp $
+
+EAPI="3"
+PYTHON_DEPEND="2:2.6"
+SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="2.4 2.5 3.*"
+
+inherit distutils
+
+DESCRIPTION="PyGTKHelpers is a library to assist the building of PyGTK applications"
+HOMEPAGE="http://packages.python.org/pygtkhelpers/ http://pypi.python.org/pypi/pygtkhelpers"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="doc examples"
+
+RDEPEND="dev-python/pygtk"
+DEPEND="${RDEPEND}
+	dev-python/setuptools
+	doc? ( dev-python/sphinx )"
+
+src_prepare() {
+	distutils_src_prepare
+
+	# docs/_static/scope.jpg does not exist.
+	sed -e "s/^\(html_logo =.*\)/#\1/" -i docs/conf.py || die "sed failed"
+}
+
+src_compile() {
+	distutils_src_compile
+
+	if use doc; then
+		einfo "Generation of documentation"
+		"$(PYTHON -f)" setup.py build_sphinx || die "Generation of documentation failed"
+	fi
+}
+
+src_install() {
+	distutils_src_install
+
+	if use doc; then
+		pushd build/sphinx/html > /dev/null
+		docinto html
+		cp -R [a-z]* _images _static "${ED}usr/share/doc/${PF}/html" || die "Installation of documentation failed"
+		popd > /dev/null
+	fi
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins -r examples/* || die "Installation of examples failed"
+	fi
+}