1 files changed, 44 insertions, 0 deletions
diff --git a/app-text/gocr/gocr-0.48.ebuild b/app-text/gocr/gocr-0.48.ebuild
new file mode 100644
index 000000000000..1fcdb58a5c3b
--- /dev/null
+++ b/app-text/gocr/gocr-0.48.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/gocr/gocr-0.48.ebuild,v 1.1 2010/02/28 20:08:37 billie Exp $
+
+EAPI=3
+
+inherit base eutils
+
+DESCRIPTION="An OCR (Optical Character Recognition) reader"
+HOMEPAGE="http://jocr.sourceforge.net"
+SRC_URI="http://www-e.uni-magdeburg.de/jschulen/ocr/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="doc tk"
+
+DEPEND=">=media-libs/netpbm-9.12
+	doc? ( >=media-gfx/transfig-3.2 app-text/ghostscript-gpl )
+	tk? ( dev-lang/tk )"
+
+DOCS="AUTHORS BUGS CREDITS HISTORY RE* TODO"
+
+src_compile() {
+	local mymakes="src man"
+
+	use doc && mymakes="${mymakes} doc examples"
+
+	emake ${mymakes} || die "make ${mymakes} failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" prefix="${EPREFIX}/usr"  exec_prefix="${EPREFIX}/usr" install || die "make install failed"
+	# remove the tk frontend if tk is not selected
+	use tk || rm "${ED}"/usr/bin/gocr.tcl
+	# and install the documentation and examples
+	if use doc ; then
+		DOCS="${DOCS} doc/gocr.html doc/examples.txt doc/unicode.txt"
+		insinto /usr/share/doc/${PF}/examples
+		doins "${S}"/examples/*.{fig,tex,pcx}
+	fi
+	# and then install all the docs
+	dodoc ${DOCS}
+}