1 files changed, 52 insertions, 0 deletions
diff --git a/app-pda/jpilot/jpilot-1.8.1.ebuild b/app-pda/jpilot/jpilot-1.8.1.ebuild
new file mode 100644
index 000000000000..ebfccbe3138c
--- /dev/null
+++ b/app-pda/jpilot/jpilot-1.8.1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-pda/jpilot/jpilot-1.8.1.ebuild,v 1.1 2011/06/15 20:42:05 ssuominen Exp $
+
+EAPI=4
+inherit autotools eutils
+
+DESCRIPTION="Desktop Organizer Software for the Palm Pilot"
+HOMEPAGE="http://www.jpilot.org/"
+SRC_URI="http://www.jpilot.org/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~x86"
+IUSE="nls"
+
+RDEPEND=">=app-pda/pilot-link-0.12.5
+	dev-libs/libgcrypt
+	>=x11-libs/gtk+-2.18.9:2"
+DEPEND="${RDEPEND}
+	nls? ( dev-util/intltool
+		sys-devel/gettext )
+	dev-util/pkgconfig"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-char.patch
+	mv -vf empty/Ma*anaDB.pdb empty/MananaDB.pdb || die
+
+	sed -i \
+		-e '/^Icon/s:jpilot.xpm:/usr/share/pixmaps/jpilot/jpilot-icon1.xpm:' \
+		jpilot.desktop || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls)
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		icondir="/usr/share/pixmaps/${PN}" \
+		miscdir="/usr/share/doc/${PF}" \
+		install
+
+	rm -f "${D}"/usr/share/doc/${PF}/{COPYING,INSTALL} \
+		"${D}"/usr/share/pixmaps/${PN}/README
+
+	find "${D}" -name '*.la' -exec rm -f {} +
+}