upstream revision bump. Remove OpenGL XvMC and OpenGL video support after discussions with upstream and how other distros are packaging MythTV. Support for those features is known to be an issue. Most users don't want it anyway since they have worse performance unless you've got a specific Quatro card. Additionally, we're always using XvMCW and requiring users to configure their XvMC provider via eselect-xvmc, based on patch from Rick Harris <rickfharris@yahoo.com.au> on bug #220857

Package-Manager: portage-2.1.5.3

3 files changed, 329 insertions, 5 deletions

diff --git a/media-tv/mythtv/ChangeLog b/media-tv/mythtv/ChangeLog
index cffcb6e2b297..1ae85372922a 100644
--- a/media-tv/mythtv/ChangeLog
+++ b/media-tv/mythtv/ChangeLog
@@ -1,6 +1,18 @@
 # ChangeLog for media-tv/mythtv
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/mythtv/ChangeLog,v 1.239 2008/05/29 17:26:10 hawking Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/mythtv/ChangeLog,v 1.240 2008/06/02 15:53:58 cardoe Exp $
+
+*mythtv-0.21_p17435 (02 Jun 2008)
+
+  02 Jun 2008; Doug Goldstein <cardoe@gentoo.org>
+  +mythtv-0.21_p17435.ebuild:
+  upstream revision bump. Remove OpenGL XvMC and OpenGL video support after
+  discussions with upstream and how other distros are packaging MythTV.
+  Support for those features is known to be an issue. Most users don't want
+  it anyway since they have worse performance unless you've got a specific
+  Quatro card. Additionally, we're always using XvMCW and requiring users to
+  configure their XvMC provider via eselect-xvmc, based on patch from Rick
+  Harris <rickfharris@yahoo.com.au> on bug #220857
 
   29 May 2008; Ali Polatel <hawking@gentoo.org> mythtv-0.21_p16867.ebuild,
   mythtv-0.21_p16926.ebuild, mythtv-0.21_p16944.ebuild,
diff --git a/media-tv/mythtv/Manifest b/media-tv/mythtv/Manifest
index b5a17dc9f7f7..5f31053e004f 100644
--- a/media-tv/mythtv/Manifest
+++ b/media-tv/mythtv/Manifest
@@ -15,14 +15,15 @@ EBUILD mythtv-0.21_p16867.ebuild 9267 RMD160 717f85f988591ce66feb60d0385ca91cb98
 EBUILD mythtv-0.21_p16926.ebuild 9433 RMD160 5d8aa6a3abd06123978b9edfcfc5676a9a4df72a SHA1 35819448e12ddbaad4040509309f6a000bfc3bf3 SHA256 74f9546e79fa1ebfd5df18635d92f3c749df7da2ad559878d03cbe6db1524020
 EBUILD mythtv-0.21_p16944.ebuild 9460 RMD160 7e3e70e00f8e88ba58eee81d44dea750111e6d0f SHA1 4c99bf53b09ce3c181885fedee1d3a7d63c2ba24 SHA256 b8530f31e928c9d588c26e521ff20774da857b02d9c43c67eafa090da634f47e
 EBUILD mythtv-0.21_p17100.ebuild 9460 RMD160 5fa8563417b5907da1db111da9f10f25b0d0772a SHA1 1d7bc7d7c1c415ac5d60513ca736d50a4bf79031 SHA256 de7650ff8d9ba18fef9da1718a4d5b7ffc2718389a67fcab527dfe458e4c1f72
+EBUILD mythtv-0.21_p17435.ebuild 9137 RMD160 5834305f9555d641892d87e1483613bc51b2c363 SHA1 bed5dbcd98b4a5e02ec130c7a4df5edadb591052 SHA256 2782bb53c460d3fd0f0bedac1b024573adda8eddfe8c003feabe6c68ca537dc7
 EBUILD mythtv-0.22_alpha16929.ebuild 9577 RMD160 815971a945d7a5be521f2a57278c9482510a2a01 SHA1 66e97486555a3f4285ccfc99856eb6453a480c72 SHA256 c72ae61c60f9a874b20d27601d72cfab9f049ae098349cf48232c30e2506c910
 EBUILD mythtv-0.22_alpha17132.ebuild 9577 RMD160 c2bfcd5cbd4b1f306d49edeca98ba8ba7d5ee775 SHA1 40004d8bdf4cb4db9dab802f82301f8f761c28e6 SHA256 6f642c40b8389a7ea4196a52fc33d0adae0d1f6257becd4eb32860f3eb1e9980
-MISC ChangeLog 45852 RMD160 7b2807184d89884cc0eb6b40ee6c23da5c2b9439 SHA1 e84f63252120dd7ca160ee445e2c0f9209756be6 SHA256 4b2bb125103e0ecf1b019f6bb9bc08da12da324c37cf220c156c0788be8e2b13
+MISC ChangeLog 46469 RMD160 8cd9e6a8ae08b5dfa00faf357e1c83c11d6030dd SHA1 ce35546fd216b13eaeb68dcfc90b59c83e7f09ec SHA256 bbf4e0523d4c6eb5b33722b860fe63ef86e7313c8762748da50120ea7826cabd
 MISC metadata.xml 4714 RMD160 c65d058e83e36342d6a49b63a6e9609e11242b66 SHA1 0de80f93ca1adfede5783d30a45953ec4cd27c9b SHA256 7501a841c218dd17bee56aeefcfc60194241b3a5468898850c5bedf5dafd28e5
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.9 (GNU/Linux)
 
-iEYEARECAAYFAkg+5zUACgkQQU4yORhF8iCgmQCglIru3ojDCdgTsg6JC0xWw3j9
-kHMAoJLQeAzCDMN4eIV9RsfHcXPx+maJ
-=32Yp
+iEYEARECAAYFAkhEF6AACgkQoeSe8B0zEfxDOQCdFG5NT48Gg1koV1G3auepV/uS
+KUMAnj7892now+8e+k/C7Da55Dfv9xyF
+=kWYx
 -----END PGP SIGNATURE-----
diff --git a/media-tv/mythtv/mythtv-0.21_p17435.ebuild b/media-tv/mythtv/mythtv-0.21_p17435.ebuild
new file mode 100644
index 000000000000..fb81862c676b
--- /dev/null
+++ b/media-tv/mythtv/mythtv-0.21_p17435.ebuild
@@ -0,0 +1,311 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-tv/mythtv/mythtv-0.21_p17435.ebuild,v 1.1 2008/06/02 15:53:58 cardoe Exp $
+
+EAPI=1
+inherit flag-o-matic multilib eutils qt3 mythtv toolchain-funcs python confutils
+
+DESCRIPTION="Homebrew PVR project"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+IUSE_VIDEO_CARDS="video_cards_nvidia"
+IUSE="aac alsa altivec autostart debug directv dvb dvd fftw ieee1394 jack lcd \
+lirc mmx opengl perl python x264 xvid xvmc ${IUSE_VIDEO_CARDS}"
+
+RDEPEND=">=media-libs/freetype-2.0
+	>=media-sound/lame-3.93.1
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXinerama
+	x11-libs/libXv
+	x11-libs/libXrandr
+	x11-libs/libXxf86vm
+	>=x11-libs/qt-3.3:3
+	virtual/mysql
+	virtual/opengl
+	virtual/glu
+	|| ( >=net-misc/wget-1.9.1 >=media-tv/xmltv-0.5.43 )
+	aac? ( media-libs/faac
+			media-libs/faad2 )
+	alsa? ( >=media-libs/alsa-lib-0.9 )
+	autostart? ( net-dialup/mingetty
+				x11-wm/evilwm
+				x11-apps/xset )
+	directv? ( virtual/perl-Time-HiRes )
+	dvb? ( media-libs/libdvb media-tv/linuxtv-dvb-headers )
+	dvd? ( 	media-libs/libdvdnav )
+	fftw? ( sci-libs/fftw:3.0 )
+	ieee1394? (	>=sys-libs/libraw1394-1.2.0
+			>=sys-libs/libavc1394-0.5.3
+			>=media-libs/libiec61883-1.0.0 )
+	jack? ( media-sound/jack-audio-connection-kit )
+	lcd? ( app-misc/lcdproc )
+	lirc? ( app-misc/lirc )
+	perl? ( dev-perl/DBD-mysql )
+	python? ( dev-python/mysql-python )
+	x264? ( media-libs/x264 )
+	xvid? ( media-libs/xvid )
+	xvmc? ( x11-libs/libXvMC
+		app-admin/eselect-xvmc )"
+
+DEPEND="${RDEPEND}
+	x11-proto/xineramaproto
+	x11-proto/xf86vidmodeproto
+	x11-apps/xinit"
+
+PDEPEND="=x11-themes/mythtv-themes-${MY_PV}*"
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+MYTHTV_GROUPS="video,audio,tty,uucp"
+
+pkg_setup() {
+
+	confutils_require_built_with_all =x11-libs/qt-3 mysql opengl
+
+	elog "This ebuild now uses a heavily stripped down version of your CFLAGS"
+
+	if use xvmc && use video_cards_nvidia; then
+		elog
+		elog "For NVIDIA based cards, the XvMC renderer only works on"
+		elog "the NVIDIA 4, 5, 6 & 7 series cards."
+	fi
+
+	enewuser mythtv -1 /bin/bash /home/mythtv ${MYTHTV_GROUPS} \
+		|| die "Problem adding mythtv user"
+	usermod -a -G ${MYTHTV_GROUPS} mythtv
+}
+
+src_unpack() {
+	subversion_src_unpack
+
+	# upstream wants the revision number in their version.cpp
+	# since the subversion.eclass strips out the .svn directory
+	# svnversion in MythTV's build doesn't work
+	sed -e "s:\`(svnversion \$\${SVNTREEDIR} 2>\/dev\/null) || echo Unknown\`:${MYTHTV_REV}:" \
+		-i "${S}"/version.pro || die "svnversion sed failed"
+
+	# Perl bits need to go into vender_perl and not site_perl
+	sed -e "s:pure_install:pure_install INSTALLDIRS=vendor:" \
+		-i "${S}"/bindings/perl/perl.pro
+}
+
+src_compile() {
+	local myconf="--prefix=/usr
+		--mandir=/usr/share/man
+		--libdir-name=$(get_libdir)"
+	use aac && myconf="${myconf} --enable-libfaad --enable-libfaac"
+	use alsa || myconf="${myconf} --disable-audio-alsa"
+	use altivec || myconf="${myconf} --disable-altivec"
+	use fftw && myconf="${myconf} --enable-libfftw3"
+	use jack || myconf="${myconf} --disable-audio-jack"
+	use x264 && myconf="${myconf} --enable-libx264"
+	use xvid && myconf="${myconf} --enable-libxvid"
+	# let's give this a whirl from bug #220857
+	use xvmc && myconf="${myconf} --enable-xvmc --enable-xvmcw \
+		--disable-xvmc-vld"
+	#use xvmc && ! use video_cards_via && \
+	#	myconf="${myconf} --enable-xvmc"
+	#use xvmc && use video_cards_via && myconf="${myconf} --enable-xvmc \
+	#	--enable-xvmc-pro --disable-xvmcw"
+	# nvidia-drivers-71 don't support GLX 1.4
+	#use video_cards_nvidia && has_version =x11-drivers/nvidia-drivers-71* \
+	#	&& myconf="${myconf} --enable-glx-procaddrarb"
+	# according to the Ubuntu guys, this works better always on
+	myconf="${myconf} --enable-glx-procaddrarb"
+
+	myconf="${myconf}
+		$(use_enable dvb)
+		$(use_enable ieee1394 firewire)
+	(use_enable lirc)
+		--disable-audio-arts
+		--disable-directfb
+		--dvb-path=/usr/include
+		--enable-opengl-vsync
+		--enable-libmp3lame
+		--enable-xrandr
+		--enable-xv
+		--enable-x11"
+
+	if use mmx || use amd64; then
+		myconf="${myconf} --enable-mmx"
+	else
+		myconf="${myconf} --disable-mmx"
+	fi
+
+	if use perl && use python; then
+		myconf="${myconf} --with-bindings=perl,python"
+	elif use perl; then
+		myconf="${myconf} --with-bindings=perl"
+	elif use python; then
+		myconf="${myconf} --with-bindings=python"
+	else
+		myconf="${myconf} --without-bindings=perl,python"
+	fi
+
+	if use debug; then
+		myconf="${myconf} --compile-type=debug"
+	else
+		myconf="${myconf} --compile-type=profile"
+	fi
+
+	## CFLAG cleaning so it compiles
+	MARCH=$(get-flag "march")
+	MTUNE=$(get-flag "mtune")
+	strip-flags
+	filter-flags "-march=*" "-mtune=*" "-mcpu=*"
+	filter-flags "-O" "-O?"
+
+	if [[ -n "${MARCH}" ]]; then
+		myconf="${myconf} --cpu=${MARCH}"
+	fi
+	if [[ -n "${MTUNE}" ]]; then
+		myconf="${myconf} --tune=${MTUNE}"
+	fi
+
+#	myconf="${myconf} --extra-cxxflags=\"${CXXFLAGS}\" --extra-cflags=\"${CFLAGS}\""
+	hasq distcc ${FEATURES} || myconf="${myconf} --disable-distcc"
+	hasq ccache ${FEATURES} || myconf="${myconf} --disable-ccache"
+
+	# let MythTV come up with our CFLAGS. Upstream will support this
+	CFLAGS=""
+	CXXFLAGS=""
+	einfo "Running ./configure ${myconf}"
+	./configure ${myconf} || die "configure died"
+
+	eqmake3 mythtv.pro -o "Makefile" || die "eqmake3 failed"
+	emake || die "emake failed"
+
+	# firewire support should build the tester
+	if use ieee1394; then
+		cd contrib
+		$(tc-getCC) ${CFLAGS} ${CPPFLAGS} -o ../firewire_tester firewire_tester.c \
+			${LDFLAGS} -liec61883 -lraw1394 || \
+			die "failed to compile firewire_tester"
+
+		cd channel_changers
+		$(tc-getCC) ${CFLAGS} ${CPPFLAGS} -std=gnu99 -o ../../6200ch 6200ch.c \
+			${LDFLAGS} -lrom1394 -lavc1394 -lraw1394 || \
+			die "failed to compile 6200ch"
+		$(tc-getCC) ${CFLAGS} ${CPPFLAGS} -o ../../sa3250ch sa3250ch.c \
+			${LDFLAGS} -lrom1394 -lavc1394 -lraw1394 || \
+			die "failed to compile sa3250ch"
+	fi
+
+	cd "${S}"/contrib/channel_changers
+	$(tc-getCC) ${CFLAGS} ${CPPFLAGS} -o ../../red_eye red_eye.c ${LDFLAGS} || \
+		die "failed to compile red_eye"
+}
+
+src_install() {
+
+	einstall INSTALL_ROOT="${D}" || die "install failed"
+	dodoc AUTHORS FAQ UPGRADING  README
+
+	insinto /usr/share/mythtv/database
+	doins database/*
+
+	exeinto /usr/share/mythtv
+	doexe "${FILESDIR}/mythfilldatabase.cron"
+
+	newinitd "${FILESDIR}"/mythbackend-0.18.2.rc mythbackend
+	newconfd "${FILESDIR}"/mythbackend-0.18.2.conf mythbackend
+
+	dodoc keys.txt docs/*.{txt,pdf}
+	dohtml docs/*.html
+
+	keepdir /etc/mythtv
+	chown -R mythtv "${D}"/etc/mythtv
+	keepdir /var/log/mythtv
+	chown -R mythtv "${D}"/var/log/mythtv
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/mythtv.logrotate.d mythtv
+
+	insinto /usr/share/mythtv/contrib
+	doins -r contrib/*
+
+	dobin "${FILESDIR}"/runmythfe
+
+	if use autostart; then
+		dodir /etc/env.d/
+		echo 'CONFIG_PROTECT="/home/mythtv/"' > "${D}"/etc/env.d/95mythtv
+
+		insinto /home/mythtv
+		newins "${FILESDIR}"/bash_profile .bash_profile
+		newins "${FILESDIR}"/xinitrc .xinitrc
+	fi
+
+	if use ieee1394; then
+		dobin firewire_tester || die "failed to install firewire_tester"
+		dodoc contrib/firewire_tester-README
+
+		dobin 6200ch || die "failed to install 6200ch"
+		dodoc contrib/channel_changers/6200ch-README
+
+		dobin sa3250ch || die "failed to install sa3250ch"
+		dodoc contrib/channel_changers/sa3250ch-README
+	fi
+
+	dobin red_eye || die "failed to install red_eye"
+	dodoc contrib/channel_changers/red_eye-README
+
+	if use directv; then
+		dobin contrib/channel_changers/d10control.pl || die "failed to install d10control"
+		dodoc contrib/channel_changers/d10control-README
+	fi
+}
+
+pkg_preinst() {
+	export CONFIG_PROTECT="${CONFIG_PROTECT} ${ROOT}/home/mythtv/"
+}
+
+pkg_postinst() {
+	python_version
+	python_mod_optimize /usr/$(get_libdir)/python${PYVER}/site-packages/MythTV
+
+	echo
+	elog "Want mythfrontend to start automatically?"
+	elog "Set USE=autostart. Details can be found at:"
+	elog "http://dev.gentoo.org/~cardoe/mythtv/autostart.html"
+
+	elog
+	elog "To always have MythBackend running and available run the following:"
+	elog "rc-update add mythbackend default"
+	elog
+	ewarn "Your recordings folder must be owned by the user 'mythtv' now"
+	ewarn "chown -R mythtv /path/to/store"
+
+	if use xvmc && [ ! -f /etc/X11/XvMCConfig ] || \
+		[ -z `cat /etc/X11/XvMCConfig` ]; then
+		ewarn
+		ewarn "No XvMC implementation has been selected yet"
+		ewarn "Use 'eselect xvmc list' for a list of available choices"
+		ewarn "Then use 'eselect xvmc set <choice>' to choose"
+		ewarn "'eselect xvmc set nvidia' for example"
+	fi
+
+	if use autostart; then
+		elog
+		elog "Please add the following to your /etc/inittab file at the end of"
+		elog "the TERMINALS section"
+		elog "c8:2345:respawn:/sbin/mingetty --autologin mythtv tty8"
+	fi
+
+}
+
+pkg_postrm()
+{
+	python_mod_cleanup /usr/$(get_libdir)/python*/site-packages/MythTV
+}
+
+pkg_info() {
+	"${ROOT}"/usr/bin/mythfrontend --version
+}
+
+pkg_config() {
+	echo "Creating mythtv MySQL user and mythconverg database if it does not"
+	echo "already exist. You will be prompted for your MySQL root password."
+	"${ROOT}"/usr/bin/mysql -u root -p < "${ROOT}"/usr/share/mythtv/database/mc.sql
+}