Update to EAPI=2 and USE deps.

Package-Manager: portage-2.2_rc12/cvs/Linux 2.6.26-gentoo-r1 x86_64

12 files changed, 433 insertions, 7 deletions

diff --git a/media-sound/jack-rack/ChangeLog b/media-sound/jack-rack/ChangeLog
index 492f6ecc6ac8..1bde5c8caff0 100644
--- a/media-sound/jack-rack/ChangeLog
+++ b/media-sound/jack-rack/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/jack-rack
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/jack-rack/ChangeLog,v 1.32 2008/04/14 18:12:23 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/jack-rack/ChangeLog,v 1.33 2008/10/10 12:26:17 flameeyes Exp $
+
+*jack-rack-1.4.7-r1 (10 Oct 2008)
+
+  10 Oct 2008; Diego Pettenò <flameeyes@gentoo.org>
+  +jack-rack-1.4.7-r1.ebuild:
+  Update to EAPI=2 and USE deps.
 
 *jack-rack-1.4.7 (14 Apr 2008)
 
diff --git a/media-sound/jack-rack/jack-rack-1.4.7-r1.ebuild b/media-sound/jack-rack/jack-rack-1.4.7-r1.ebuild
new file mode 100644
index 000000000000..4d2d17910acd
--- /dev/null
+++ b/media-sound/jack-rack/jack-rack-1.4.7-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/jack-rack/jack-rack-1.4.7-r1.ebuild,v 1.1 2008/10/10 12:26:17 flameeyes Exp $
+
+EAPI=2
+
+WANT_AUTOMAKE="1.9"
+
+inherit autotools
+
+IUSE="alsa gnome lash nls xml"
+
+DESCRIPTION="JACK Rack is an effects rack for the JACK low latency audio API."
+HOMEPAGE="http://jack-rack.sourceforge.net/"
+SRC_URI="mirror://sourceforge/jack-rack/${P}.tar.gz"
+LICENSE="GPL-2"
+SLOT="0"
+
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+
+RDEPEND=">=x11-libs/gtk+-2
+	>=media-libs/ladspa-sdk-1.12
+	media-sound/jack-audio-connection-kit
+	alsa? ( media-libs/alsa-lib[midi] )
+	lash? ( >=media-sound/lash-0.5 )
+	gnome? ( >=gnome-base/libgnomeui-2 )
+	nls? ( virtual/libintl )
+	xml? ( dev-libs/libxml2
+		media-libs/liblrdf )"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}/${PN}-1.4.5-asneeded.patch"
+	epatch "${FILESDIR}/${PN}-1.4.6-noalsa.patch"
+	eautomake
+}
+
+src_configure() {
+	local myconf
+	myconf="--disable-ladcca --enable-desktop-inst"
+
+	econf \
+		$(use_enable alsa aseq) \
+		$(use_enable gnome) \
+		$(use_enable lash) \
+		$(use_enable nls) \
+		$(use_enable xml) \
+		$(use_enable xml lrdf ) \
+		--disable-dependency-tracking \
+		${myconf} || die "econf failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	dodoc AUTHORS BUGS ChangeLog NEWS README THANKS TODO WISHLIST
+}
diff --git a/media-sound/lash/ChangeLog b/media-sound/lash/ChangeLog
index a715326b9b33..36bf012db925 100644
--- a/media-sound/lash/ChangeLog
+++ b/media-sound/lash/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/lash
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/lash/ChangeLog,v 1.20 2008/08/07 17:07:39 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/lash/ChangeLog,v 1.21 2008/10/10 12:27:11 flameeyes Exp $
+
+*lash-0.5.4-r1 (10 Oct 2008)
+
+  10 Oct 2008; Diego Pettenò <flameeyes@gentoo.org> +lash-0.5.4-r1.ebuild:
+  Update to EAPI=2 and USE deps.
 
   07 Aug 2008; Alexis Ballier <aballier@gentoo.org>
   +files/lash-0.5.4-glibc2.8.patch, lash-0.5.4.ebuild:
diff --git a/media-sound/lash/lash-0.5.4-r1.ebuild b/media-sound/lash/lash-0.5.4-r1.ebuild
new file mode 100644
index 000000000000..2d38ea5203f4
--- /dev/null
+++ b/media-sound/lash/lash-0.5.4-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/lash/lash-0.5.4-r1.ebuild,v 1.1 2008/10/10 12:27:11 flameeyes Exp $
+
+EAPI=2
+
+inherit eutils libtool
+
+DESCRIPTION="LASH Audio Session Handler"
+HOMEPAGE="http://www.nongnu.org/lash/"
+SRC_URI="http://download.savannah.gnu.org/releases/lash/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="alsa debug gtk python"
+
+RDEPEND="alsa? ( media-libs/alsa-lib[midi] )
+	media-sound/jack-audio-connection-kit
+	dev-libs/libxml2
+	gtk? ( >=x11-libs/gtk+-2.0 )
+	python? ( dev-lang/python )
+	|| ( sys-libs/readline dev-libs/libedit )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	python? ( >=dev-lang/swig-1.3.31 )"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${FILESDIR}/${P}-glibc2.8.patch"
+	elibtoolize
+}
+
+src_configure() {
+	local myconf
+
+	# Yet-another-broken-configure: --enable-pylash would disable it.
+	use python || myconf="${myconf} --disable-pylash"
+
+	econf \
+		$(use_enable alsa alsa-midi) \
+		$(use_enable gtk gtk2) \
+		$(use_enable debug) \
+		${myconf} \
+		--disable-dependency-tracking \
+		|| die "econf failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	dodoc AUTHORS ChangeLog NEWS README TODO
+}
diff --git a/media-sound/mixxx/ChangeLog b/media-sound/mixxx/ChangeLog
index 7061ed4e4379..cab969a2f7f7 100644
--- a/media-sound/mixxx/ChangeLog
+++ b/media-sound/mixxx/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/mixxx
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mixxx/ChangeLog,v 1.41 2008/08/13 07:58:11 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mixxx/ChangeLog,v 1.42 2008/10/10 12:31:57 flameeyes Exp $
+
+*mixxx-1.6.0-r1 (10 Oct 2008)
+
+  10 Oct 2008; Diego Pettenò <flameeyes@gentoo.org> +mixxx-1.6.0-r1.ebuild:
+  Update to EAPI=2 and USE deps.
 
 *mixxx-1.6.0 (13 Aug 2008)
 
diff --git a/media-sound/mixxx/mixxx-1.6.0-r1.ebuild b/media-sound/mixxx/mixxx-1.6.0-r1.ebuild
new file mode 100644
index 000000000000..260813c7e9db
--- /dev/null
+++ b/media-sound/mixxx/mixxx-1.6.0-r1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mixxx/mixxx-1.6.0-r1.ebuild,v 1.1 2008/10/10 12:31:57 flameeyes Exp $
+
+EAPI=2
+
+inherit eutils
+
+MY_P=${P/_/-}
+
+DESCRIPTION="a QT based Digital DJ tool"
+HOMEPAGE="http://mixxx.sourceforge.net"
+SRC_URI="http://downloads.mixxx.org/${MY_P}/${MY_P}-src.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="debug djconsole hifieq ladspa recording shout +vinylcontrol"
+
+# TODO. It bundles libs, like samplerate, why?
+RDEPEND="media-libs/mesa
+	media-libs/libmad
+	media-libs/libid3tag
+	media-libs/libvorbis
+	media-libs/libsndfile
+	>=media-libs/portaudio-19_pre
+	djconsole? ( media-libs/libdjconsole )
+	shout? ( media-libs/libshout )
+	ladspa? ( media-libs/ladspa-sdk )
+	virtual/glu
+	|| ( ( x11-libs/qt-core
+		x11-libs/qt-gui
+		x11-libs/qt-opengl )
+		=x11-libs/qt-4.3*:4[opengl,qt3support] )"
+DEPEND="${RDEPEND}
+	dev-util/scons
+	dev-util/pkgconfig"
+
+S=${WORKDIR}/${P/_/\~}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	sed -i -e 's:-O3::g' lib/cmetrics/SConscript || die "sed failed."
+}
+
+src_configure() {
+	local myconf="optimize=0 ffmpeg=0 script=0 prefix=/usr"
+
+	use djconsole && myconf+=" djconsole=1" || myconf+=" djconsole=0"
+	use hifieq && myconf+=" hifieq=1" || myconf+=" hifieq=0"
+	use debug && myconf+=" cmetrics=1" || myconf+=" cmetrics=0"
+	use shout && myconf+=" shoutcast=1" || myconf+=" shoutcast=0"
+	use ladspa && myconf+=" ladspa=1" || myconf+=" ladspa=0"
+	use recording && myconf+=" experimentalrecord=1" || myconf+=" experimentalrecord=0"
+	use vinylcontrol && myconf+=" vinylcontrol=1" || myconf+=" vinylcontrol=0"
+
+	$(type -P scons) ${myconf} -c . || die "scons -c . failed."
+}
+
+src_compile() {
+	$(type -P scons) ${myconf} || die "scons failed."
+}
+
+src_install() {
+	dobin mixxx || die "dobin failed."
+
+	insinto /usr/share/mixxx
+	doins -r src/{skins,midi,keyboard} || die "doins failed."
+
+	doicon src/mixxx-icon.png
+	domenu src/mixxx.desktop
+
+	dodoc HERCULES.txt README*
+
+	insinto /usr/share/doc/${PF}
+	doins Mixxx-Manual.pdf
+}
diff --git a/media-sound/qjackctl/ChangeLog b/media-sound/qjackctl/ChangeLog
index 1dfde0688a9c..53753cfe2073 100644
--- a/media-sound/qjackctl/ChangeLog
+++ b/media-sound/qjackctl/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/qjackctl
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/qjackctl/ChangeLog,v 1.57 2008/07/27 01:08:05 carlo Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/qjackctl/ChangeLog,v 1.58 2008/10/10 12:28:39 flameeyes Exp $
+
+*qjackctl-0.3.3-r1 (10 Oct 2008)
+
+  10 Oct 2008; Diego Pettenò <flameeyes@gentoo.org>
+  +qjackctl-0.3.3-r1.ebuild:
+  Update to EAPI=2 and USE deps.
 
   27 Jul 2008; Carsten Lohrke <carlo@gentoo.org> qjackctl-0.3.2.ebuild,
   qjackctl-0.3.3.ebuild:
diff --git a/media-sound/qjackctl/qjackctl-0.3.3-r1.ebuild b/media-sound/qjackctl/qjackctl-0.3.3-r1.ebuild
new file mode 100644
index 000000000000..49f81fc574c1
--- /dev/null
+++ b/media-sound/qjackctl/qjackctl-0.3.3-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/qjackctl/qjackctl-0.3.3-r1.ebuild,v 1.1 2008/10/10 12:28:39 flameeyes Exp $
+
+EAPI=2
+
+inherit eutils qt4
+
+DESCRIPTION="A Qt application to control the JACK Audio Connection Kit and ALSA sequencer connections."
+HOMEPAGE="http://qjackctl.sourceforge.net/"
+SRC_URI="mirror://sourceforge/qjackctl/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+
+IUSE="alsa debug"
+
+DEPEND="alsa? ( media-libs/alsa-lib[midi] )
+	|| ( (
+			x11-libs/qt-core:4
+			x11-libs/qt-gui:4
+		) =x11-libs/qt-4.3*:4 )
+	media-sound/jack-audio-connection-kit"
+
+src_configure() {
+	econf \
+		$(use_enable alsa alsa-seq) \
+		$(use_enable debug) \
+		|| die "econf failed"
+
+	# Emulate what the Makefile does, so that we can get the correct
+	# compiler used.
+	eqmake4 ${PN}.pro -o ${PN}.mak || die "eqmake4 failed"
+}
+
+src_compile() {
+	emake -f ${PN}.mak || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "make install failed"
+
+	rm "${D}/usr/share/applications/qjackctl.desktop"
+
+	# Upstream desktop file is invalid, better stick with our for now.
+	make_desktop_entry "${PN}" "QjackCtl" "${PN}"
+
+	dodoc README ChangeLog TODO AUTHORS
+}
diff --git a/media-sound/qsynth/ChangeLog b/media-sound/qsynth/ChangeLog
index b78125f0f824..ae6f2e1e5dd6 100644
--- a/media-sound/qsynth/ChangeLog
+++ b/media-sound/qsynth/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/qsynth
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/qsynth/ChangeLog,v 1.43 2008/07/28 21:24:17 carlo Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/qsynth/ChangeLog,v 1.44 2008/10/10 12:29:34 flameeyes Exp $
+
+*qsynth-0.3.3-r1 (10 Oct 2008)
+
+  10 Oct 2008; Diego Pettenò <flameeyes@gentoo.org>
+  +qsynth-0.3.3-r1.ebuild:
+  Update to EAPI=2 and USE deps.
 
   28 Jul 2008; Carsten Lohrke <carlo@gentoo.org> qsynth-0.3.1-r1.ebuild:
   QA: Get rid of deprecated qt4_min_version().
diff --git a/media-sound/qsynth/qsynth-0.3.3-r1.ebuild b/media-sound/qsynth/qsynth-0.3.3-r1.ebuild
new file mode 100644
index 000000000000..ac8f88dce407
--- /dev/null
+++ b/media-sound/qsynth/qsynth-0.3.3-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/qsynth/qsynth-0.3.3-r1.ebuild,v 1.1 2008/10/10 12:29:34 flameeyes Exp $
+
+EAPI=2
+
+inherit qt4 eutils flag-o-matic
+
+DESCRIPTION="A Qt application to control FluidSynth"
+HOMEPAGE="http://qsynth.sourceforge.net/"
+SRC_URI="mirror://sourceforge/qsynth/${P}.tar.gz"
+LICENSE="GPL-2"
+
+SLOT="0"
+IUSE="debug jack alsa"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+
+DEPEND="
+	|| ( (
+			x11-libs/qt-core:4
+			x11-libs/qt-gui:4
+		) =x11-libs/qt-4.3*:4 )
+	>=media-sound/fluidsynth-1.0.7a[jack?,alsa?]
+	!jack? ( !alsa? ( >=media-sound/fluidsynth-1.0.7a[oss] ) )"
+
+src_configure() {
+	# Stupidly, qsynth's configure does *not* use pkg-config to
+	# discover the presence of Qt4, but uses fixed paths; as they
+	# don't really work that well for our case, let's just use this
+	# nasty hack and be done with it. *NOTE*: this hinders
+	# cross-compile.
+	append-flags -I/usr/include/qt4
+	append-ldflags -L/usr/$(get_libdir)/qt4
+
+	econf \
+		$(use_enable debug) \
+		|| die "econf failed"
+}
+
+src_install () {
+	emake DESTDIR="${D}" install || die "make install failed"
+	dodoc AUTHORS ChangeLog README TODO
+
+	# The desktop file is invalid, and we also change the command
+	# depending on useflags
+	rm -rf "${D}/usr/share/applications/qsynth.desktop"
+
+	local cmd
+	if use jack; then
+		cmd="qsynth"
+	elif use alsa; then
+		cmd="qsynth -a alsa"
+	else
+		cmd="qsynth -a oss"
+	fi
+
+	make_desktop_entry "${cmd}" Qsynth qsynth
+}
diff --git a/media-sound/zynaddsubfx/ChangeLog b/media-sound/zynaddsubfx/ChangeLog
index 85907606b50d..71d7c65a4aea 100644
--- a/media-sound/zynaddsubfx/ChangeLog
+++ b/media-sound/zynaddsubfx/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/zynaddsubfx
-# Copyright 2000-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/zynaddsubfx/ChangeLog,v 1.29 2007/10/01 20:08:11 eldad Exp $
+# Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/zynaddsubfx/ChangeLog,v 1.30 2008/10/10 12:34:52 flameeyes Exp $
+
+*zynaddsubfx-2.2.1-r4 (10 Oct 2008)
+
+  10 Oct 2008; Diego Pettenò <flameeyes@gentoo.org>
+  +zynaddsubfx-2.2.1-r4.ebuild:
+  Update to EAPI=2 and USE deps.
 
   01 Oct 2007; <eldad@gentoo.org> -zynaddsubfx-2.2.0.ebuild,
   -zynaddsubfx-2.2.1.ebuild, -zynaddsubfx-2.2.1-r1.ebuild:
diff --git a/media-sound/zynaddsubfx/zynaddsubfx-2.2.1-r4.ebuild b/media-sound/zynaddsubfx/zynaddsubfx-2.2.1-r4.ebuild
new file mode 100644
index 000000000000..85ca298da782
--- /dev/null
+++ b/media-sound/zynaddsubfx/zynaddsubfx-2.2.1-r4.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/zynaddsubfx/zynaddsubfx-2.2.1-r4.ebuild,v 1.1 2008/10/10 12:34:53 flameeyes Exp $
+
+EAPI=2
+
+inherit eutils toolchain-funcs
+
+MY_P=ZynAddSubFX-${PV}
+DESCRIPTION="ZynAddSubFX is an opensource software synthesizer."
+HOMEPAGE="http://zynaddsubfx.sourceforge.net/"
+SRC_URI="mirror://sourceforge/zynaddsubfx/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+#IUSE="oss alsa jack mmx"
+IUSE="oss alsa jack"
+
+DEPEND=">=x11-libs/fltk-1.1.2
+	=sci-libs/fftw-3*
+	jack? ( media-sound/jack-audio-connection-kit )
+	alsa? ( media-libs/alsa-lib[midi] )
+	>=dev-libs/mini-xml-2.2.1"
+#	portaudio? ( media-libs/portaudio )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	sed -i -e '/CXXFLAGS +=/s:CXXFLAGS +=:override CXXFLAGS +=:' \
+		-e '/export CXXFLAGS/d' \
+		-e '/\$(MAKE) -C UI/s:$: CXXFLAGS="${CXXFLAGS}":' \
+		"${S}/src/Makefile" || die "unable to reset CXXFLAGS overrides."
+}
+
+src_compile() {
+	local FFTW_VERSION=3
+	local ASM_F2I=NO
+	local LINUX_MIDIIN=NONE
+	local LINUX_AUDIOOUT=NONE
+
+	if use oss ; then
+		LINUX_MIDIIN=OSS
+		LINUX_AUDIOOUT=OSS
+		use jack && LINUX_AUDIOOUT=OSS_AND_JACK
+	else
+		use jack && LINUX_AUDIOOUT=JACK
+	fi
+
+	use alsa && LINUX_MIDIIN=ALSA
+#	use portaudio && LINUX_AUDIOOUT=PA
+#	use mmx && ASM_F2I=YES
+
+	cd ${S}/src
+	make \
+		FFTW_VERSION=${FFTW_VERSION} \
+		ASM_F2I=${ASM_F2I} \
+		LINUX_MIDIIN=${LINUX_MIDIIN} \
+		LINUX_AUDIOOUT=${LINUX_AUDIOOUT} \
+		CFLAGS="${CFLAGS}" CXXFLAGS="${CXXFLAGS}" \
+		CXX="$(tc-getCXX)" \
+		|| die "compile failed"
+	cd ${S}/ExternalPrograms/Spliter
+	./compile.sh
+	cd ${S}/ExternalPrograms/Controller
+	./compile.sh
+}
+
+src_install() {
+	dobin ${S}/src/zynaddsubfx
+	dobin ${S}/ExternalPrograms/Spliter/spliter
+	dobin ${S}/ExternalPrograms/Controller/controller
+	dodoc ChangeLog FAQ.txt HISTORY.txt README.txt ZynAddSubFX.lsm bugs.txt
+
+	for i in "Arpeggios" "Bass" "Brass" "Choir and Voice" "Drums" \
+			 "Dual" "Fantasy" "Guitar" "Misc" "Noises" "Organ" \
+			 "Pads" "Plucked" "Reed and Wind" "Rhodes" "Splited" \
+			 "Strings" "Synth" "SynthPiano"
+	do
+		insinto "/usr/share/${PN}/banks/${i}"
+		doins "${S}/banks/${i}/"*
+	done
+
+	insinto /usr/share/${PN}/presets
+	doins "${S}/presets/"*
+	insinto /usr/share/${PN}
+	doins "${S}/examples/"*
+}