media-gfx/gimp: Port linguas handling (bug #416597) and deletion of .la files to 2.6.x

Package-Manager: portage-2.1.10.56/cvs/Linux x86_64

3 files changed, 167 insertions, 5 deletions

diff --git a/media-gfx/gimp/ChangeLog b/media-gfx/gimp/ChangeLog
index 9cc2e4e298a8..67b67b542ed8 100644
--- a/media-gfx/gimp/ChangeLog
+++ b/media-gfx/gimp/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-gfx/gimp
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/ChangeLog,v 1.369 2012/05/28 21:46:36 sping Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/ChangeLog,v 1.370 2012/05/28 22:26:41 sping Exp $
+
+*gimp-2.6.12-r1 (28 May 2012)
+
+  28 May 2012; Sebastian Pipping <sping@gentoo.org> +gimp-2.6.12-r1.ebuild:
+  Port linguas handling (bug #416597) and deletion of .la files to latest 2.6.x
+  ebuild
 
   28 May 2012; Sebastian Pipping <sping@gentoo.org> gimp-2.8.0-r1.ebuild:
   Resolve linguas code duplication for bug #418053
diff --git a/media-gfx/gimp/Manifest b/media-gfx/gimp/Manifest
index 4fbf8dd01651..446509b057a9 100644
--- a/media-gfx/gimp/Manifest
+++ b/media-gfx/gimp/Manifest
@@ -28,6 +28,7 @@ EBUILD gimp-2.6.11-r3.ebuild 3435 RMD160 827ffdca63119261a2815ed7f115ff7dcf0118f
 EBUILD gimp-2.6.11-r4.ebuild 3592 RMD160 c31c57e3efe9bfbd986492375956a6a043224ae5 SHA1 090d35fb5d6859909e86bf2f2f480174b37bb86c SHA256 c3e5497e6cd5699a15beff982ee1e00134818c518ab0377c021f68e57253c2c8
 EBUILD gimp-2.6.11-r5.ebuild 3860 RMD160 312435af1cb9aea93e5c1cae5928996b34f08097 SHA1 7eca0eb13df34a64fb97622ad2c82e0e14999182 SHA256 9c281a31d6b73ce539cf3c900967c2a151b145065f5fa7e541ccfa77c6f386c5
 EBUILD gimp-2.6.11-r6.ebuild 4087 RMD160 e0fc1eedefb122cccc8317eb9abfe914e02475cf SHA1 ab49b429e4910d703dad2d93f7cc425296691029 SHA256 73363236f423cd87341c1a9d14b69da103cdac2fa0e5c0540f094cd40448fe52
+EBUILD gimp-2.6.12-r1.ebuild 4159 RMD160 a35c3dbc486948f571867681d50ce61fb8e1d055 SHA1 cc7d435a9317366f72ad89591bb0ec278b856b0e SHA256 000de9c5b6d795839287059e7c2c5a3bc82b8b3daeceea34549ad0e84429b3d9
 EBUILD gimp-2.6.12.ebuild 3502 RMD160 4e0fd3ae96ec46500b95f39c239d4d8d4e9d33e8 SHA1 28a9368980d4c70d7d721b44d901b3d8b7b2d615 SHA256 54c71b43a91c0ab52ca97ff01adb9bdb8023c6723b65d7b8cea93441c4c7d3ea
 EBUILD gimp-2.7.3-r1.ebuild 3619 RMD160 9a0442bae9acad14346f89ee7d7341daa25a58c4 SHA1 8699aa4739d44918918cc7dd301d93ad797e0c6c SHA256 ef525f90f19a2a5fb21ceefc77c7332764749b1d5476eaa2a0956d1ec22af75b
 EBUILD gimp-2.7.3.ebuild 3225 RMD160 7184efc8e9b6b38b10e5ac2a0fa745113f470668 SHA1 14d0c039f5f7655f880db96cf865c90c85e5c7a4 SHA256 2d947c62bae5e393e9dcdca6b7029e5284b782b55f47b5e945734b671454c755
@@ -37,12 +38,12 @@ EBUILD gimp-2.8.0-r1.ebuild 4513 RMD160 c8503f78232a9f1ba805c858879d3213e86f5481
 EBUILD gimp-2.8.0.ebuild 3899 RMD160 1a260444bc0f91cecf076fb57afa697b715d94e9 SHA1 0b243a00f3f9d2b11f4c6823e03039ab0c65fc63 SHA256 31a6c1417655aea7a132eaab97d3ec4fcb40eb32c692bf2218c88d4445c8c823
 EBUILD gimp-2.8.0_rc1.ebuild 3811 RMD160 1f04bb84e88b83f51bb539109145ef4935b9dc3b SHA1 4dfdc3d8ebc5a8595f0ebcf21e93a15560fb98c0 SHA256 40461fec11c64e3edc53d5ce28bb5bd77a785141fe6a63def506cf82f60113f7
 EBUILD gimp-9999.ebuild 3818 RMD160 6c0d0c5d870307225645d94eafc25f775cffc042 SHA1 66167de3d7331222da359bcf9902552210d7f06f SHA256 4d13ed3a754f2c13d93a722826fc7f36486a245ded7796743d857efeb751979a
-MISC ChangeLog 51897 RMD160 4bded46af3f7d475e17262447d77ab0614a41e74 SHA1 e6aa50efd25283f8672d7af039ab3a8dfcc107c1 SHA256 ea8d679b69196888f23cf52c6f0e7763d40c003bec2705d0395f9d06819cf05a
+MISC ChangeLog 52094 RMD160 4fa7989d4a82a6d5360ee6262e78d7a79d46f031 SHA1 f70078ab87f9354d5bfe4d82811710ce268f08e3 SHA256 579cd7338f01ecb64ed78a76eb4f1602cd27396b05cb4b955fa940f564990cd1
 MISC metadata.xml 492 RMD160 726b88e9d8bbd64c8eeffbec365c0492a7ee2fcc SHA1 f52fc1466de1fd9e1dc2024c12c89ffbc968021d SHA256 80f5f35119a32f0506f77776ef3bb77c889dd345aa34463b48362f7860bf47dc
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.19 (GNU/Linux)
 
-iEYEARECAAYFAk/D8ioACgkQsAvGakAaFgAqxACgzFAbbj1ku4gv9m5ENFg9SDqi
-fqEAn36sgjvupFH7ByunkV7cCAUCMuBb
-=Z+3x
+iEYEARECAAYFAk/D+5AACgkQsAvGakAaFgA91wCfWKmOoFTZIMBoAeCDIuR0+zfF
+ZL0AoIEGaWIJoncXBWz4dcWEjt2LcPSH
+=kslH
 -----END PGP SIGNATURE-----
diff --git a/media-gfx/gimp/gimp-2.6.12-r1.ebuild b/media-gfx/gimp/gimp-2.6.12-r1.ebuild
new file mode 100644
index 000000000000..f9ea84ccd343
--- /dev/null
+++ b/media-gfx/gimp/gimp-2.6.12-r1.ebuild
@@ -0,0 +1,155 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/gimp-2.6.12-r1.ebuild,v 1.1 2012/05/28 22:26:41 sping Exp $
+
+EAPI="3"
+
+PYTHON_DEPEND="python? 2:2.5"
+
+inherit eutils gnome2 fdo-mime multilib python
+
+DESCRIPTION="GNU Image Manipulation Program"
+HOMEPAGE="http://www.gimp.org/"
+SRC_URI="
+	http://dev.gentoo.org/~jlec/distfiles/${PN}-2.6.11-underlinking.patch.xz
+	mirror://gimp/v2.6/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+LANGS="am ar ast az be bg ca ca@valencia cs da de dz el en_CA en_GB eo es et eu fa fi fr ga gl gu he hi hr hu id is it ja ka kk km kn ko lt lv mk ml mr ms my nb nds ne nl nn oc or pa pl pt pt_BR ro ru rw si sk sl sr sr@latin sv ta th tr tt uk vi xh yi zh_CN zh_HK zh_TW"
+IUSE="alsa aalib altivec curl dbus debug doc exif gnome jpeg lcms mmx mng pdf png python smp sse svg tiff webkit wmf"
+
+for lang in ${LANGS}; do
+	[[ ${lang} == yi ]] && continue  # bug #418053
+	IUSE+=" linguas_${lang}"
+done
+
+RDEPEND="
+	>=dev-libs/glib-2.18.1:2
+	dev-libs/libxml2
+	dev-libs/libxslt
+	>=media-libs/fontconfig-2.2.0
+	>=media-libs/freetype-2.1.7
+	>=media-libs/gegl-0.0.22 <media-libs/gegl-0.2
+	>=x11-libs/gtk+-2.12.5:2
+	x11-libs/libXpm
+	>=x11-libs/pango-1.18.0
+	sys-libs/zlib
+	x11-themes/hicolor-icon-theme
+	aalib? ( media-libs/aalib )
+	alsa? ( media-libs/alsa-lib )
+	curl? ( net-misc/curl )
+	dbus? ( dev-libs/dbus-glib )
+	exif? ( >=media-libs/libexif-0.6.15 )
+	gnome? ( gnome-base/gvfs )
+	jpeg? ( virtual/jpeg:0 )
+	lcms? ( =media-libs/lcms-1* )
+	mng? ( media-libs/libmng )
+	pdf? ( >=app-text/poppler-0.12.3-r3[cairo] )
+	png? ( >=media-libs/libpng-1.2.2:0 )
+	python?	( >=dev-python/pygtk-2.10.4:2 )
+	svg? ( >=gnome-base/librsvg-2.8.0:2 )
+	tiff? ( >=media-libs/tiff-3.5.7:0 )
+	webkit? ( net-libs/webkit-gtk:2 )
+	wmf? ( >=media-libs/libwmf-0.2.8 )"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig
+	>=sys-devel/gettext-0.17
+	doc? ( >=dev-util/gtk-doc-1 )"
+
+DOCS="AUTHORS ChangeLog* HACKING NEWS README*"
+
+pkg_setup() {
+	G2CONF="--enable-default-binary \
+		--with-x \
+		$(use_with aalib aa) \
+		$(use_with alsa) \
+		$(use_enable altivec) \
+		$(use_with curl libcurl) \
+		$(use_with dbus) \
+		--without-hal \
+		$(use_with gnome gvfs) \
+		--without-gnomevfs \
+		$(use_with webkit) \
+		$(use_with jpeg libjpeg) \
+		$(use_with exif libexif) \
+		$(use_with lcms) \
+		$(use_enable mmx) \
+		$(use_with mng libmng) \
+		$(use_with pdf poppler) \
+		$(use_with png libpng) \
+		$(use_enable python) \
+		$(use_enable smp mp) \
+		$(use_enable sse) \
+		$(use_with svg librsvg) \
+		$(use_with tiff libtiff) \
+		$(use_with wmf)"
+
+	if use python; then
+		python_set_active_version 2
+		python_pkg_setup
+	fi
+}
+
+src_prepare() {
+	# don't use empty, removed header
+	# https://bugs.gentoo.org/show_bug.cgi?id=377075
+	epatch "${FILESDIR}"/gimp-curl-headers.diff
+
+	# apply file-uri patch by upstream
+	# https://bugs.gentoo.org/show_bug.cgi?id=372941
+	# https://bugzilla.gnome.org/show_bug.cgi?id=653980#c6
+	epatch "${FILESDIR}"/${PN}-2.6.11-file-uri.patch
+
+	# fix test suite
+	# https://bugs.gentoo.org/show_bug.cgi?id=406625
+	epatch "${FILESDIR}"/${P}-potfiles-skip.patch
+
+	echo '#!/bin/sh' > py-compile
+	gnome2_src_prepare
+}
+
+_clean_up_locales() {
+	elog "Cleaning up locales..."
+	for lang in ${LANGS}; do
+		use "linguas_${lang}" && {
+			elog "- keeping ${lang}"
+			continue
+		}
+		rm -Rf "${D}"/usr/share/locale/"${lang}" || die
+	done
+}
+
+src_install() {
+	gnome2_src_install
+
+	if use python; then
+		python_convert_shebangs -r $(python_get_version) "${ED}"
+		python_need_rebuild
+	fi
+
+	# Workaround for bug #321111 to give GIMP the least
+	# precedence on PDF documents by default
+	mv "${D}"/usr/share/applications/{,zzz-}gimp.desktop || die
+
+	find "${D}" -name '*.la' -delete || die
+
+	_clean_up_locales
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	use python && python_mod_optimize /usr/$(get_libdir)/gimp/2.0/python \
+		/usr/$(get_libdir)/gimp/2.0/plug-ins
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+
+	use python && python_mod_cleanup /usr/$(get_libdir)/gimp/2.0/python \
+		/usr/$(get_libdir)/gimp/2.0/plug-ins
+}