Version bump KDE SC 4.11.2

Package-Manager: portage-2.2.7/cvs/Linux x86_64
Manifest-Sign-Key: 0x42618354

2 files changed, 97 insertions, 1 deletions

diff --git a/kde-base/marble/ChangeLog b/kde-base/marble/ChangeLog
index f1f7f9f6e68a..61a2132d0d27 100644
--- a/kde-base/marble/ChangeLog
+++ b/kde-base/marble/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/marble
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/marble/ChangeLog,v 1.215 2013/09/08 07:54:08 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/marble/ChangeLog,v 1.216 2013/10/09 23:04:32 creffett Exp $
+
+*marble-4.11.2 (08 Oct 2013)
+
+  08 Oct 2013; Chris Reffett <creffett@gentoo.org> +marble-4.11.2.ebuild:
+  Version bump KDE SC 4.11.2
 
   08 Sep 2013; Agostino Sarubbo <ago@gentoo.org> marble-4.10.5.ebuild,
   marble-4.11.1.ebuild:
diff --git a/kde-base/marble/marble-4.11.2.ebuild b/kde-base/marble/marble-4.11.2.ebuild
new file mode 100644
index 000000000000..89b840724007
--- /dev/null
+++ b/kde-base/marble/marble-4.11.2.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/marble/marble-4.11.2.ebuild,v 1.1 2013/10/09 23:04:32 creffett Exp $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KDE_REQUIRED="optional"
+CPPUNIT_REQUIRED="optional"
+PYTHON_DEPEND="python? 2"
+inherit kde4-base python
+
+DESCRIPTION="Generic geographical map widget"
+HOMEPAGE="http://marble.kde.org/"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug designer-plugin gps +kde plasma python shapefile test zip"
+
+# tests fail / segfault. Last checked for 4.9.0
+RESTRICT="test"
+
+RDEPEND="
+	dev-qt/qtcore:4
+	dev-qt/qtdbus:4
+	dev-qt/qtdeclarative:4
+	dev-qt/qtgui:4
+	dev-qt/qtscript:4
+	dev-qt/qtsql:4
+	dev-qt/qtsvg:4
+	dev-qt/qtwebkit:4
+	gps? ( >=sci-geosciences/gpsd-2.95[qt4] )
+	python? (
+		>=dev-python/PyQt4-4.4.4-r1
+		kde? ( $(add_kdebase_dep pykde4) )
+	)
+	shapefile? ( sci-libs/shapelib )
+	zip? ( dev-libs/quazip )
+"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-qt/qttest:4 )
+"
+# the qt dependencies are needed because with USE=-kde nothing is pulled in
+# by default... bugs 414165 & 429346
+
+REQUIRED_USE="
+	plasma? ( kde )
+	python? ( kde )
+"
+
+pkg_setup() {
+	python_set_active_version 2
+	kde4-base_pkg_setup
+	python_pkg_setup
+}
+
+src_prepare() {
+	kde4-base_src_prepare
+	python_convert_shebangs -r $(python_get_version) .
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with designer-plugin DESIGNER_PLUGIN)
+		$(cmake-utils_use python EXPERIMENTAL_PYTHON_BINDINGS)
+		$(cmake-utils_use_with python PyQt4)
+		$(cmake-utils_use_with python PythonLibrary)
+		$(cmake-utils_use_with python SIP)
+		$(cmake-utils_use_with gps libgps)
+		$(cmake-utils_use !kde QTONLY)
+		$(cmake-utils_use_with plasma)
+		$(cmake-utils_use_with shapefile libshp)
+		$(cmake-utils_use_with zip quazip)
+		-DBUILD_MARBLE_TESTS=OFF
+		-DWITH_liblocation=0
+		-DWITH_QextSerialPort=OFF
+		$(use kde && cmake-utils_use_with python PyKDE4)
+	)
+
+	kde4-base_src_configure
+}
+
+src_test() {
+	if use kde; then
+		elog "Marble tests can only be run in the qt-only version"
+	else
+		local mycmakeargs=(
+			-DBUILD_MARBLE_TESTS=ON
+		)
+		kde4-base_src_test
+	fi
+}