add patch from python team to fix compiling with python 2.3 (bug #60091); tidy

4 files changed, 84 insertions, 2 deletions

diff --git a/games-puzzle/kiki/ChangeLog b/games-puzzle/kiki/ChangeLog
index 573c32b5c373..4f1f5c04c1d0 100644
--- a/games-puzzle/kiki/ChangeLog
+++ b/games-puzzle/kiki/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for games-puzzle/kiki
 # Copyright 2000-2004 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-puzzle/kiki/ChangeLog,v 1.4 2004/06/24 23:06:38 agriffis Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-puzzle/kiki/ChangeLog,v 1.5 2004/08/30 20:45:30 mr_bones_ Exp $
+
+*kiki-0.9.0-r1 (30 Aug 2004)
+
+  30 Aug 2004; Michael Sterrett <mr_bones_@gentoo.org> +kiki-0.9.0-r1.ebuild:
+  add patch from python team to fix compiling with python 2.3 (bug #60091); tidy
 
   21 Apr 2004; Michael Sterrett <mr_bones_@gentoo.org> kiki-0.9.0.ebuild:
   source has hard-coded python 2.2 stuff.  Didn't work with python 2.3.3 either
diff --git a/games-puzzle/kiki/Manifest b/games-puzzle/kiki/Manifest
index be9baf4038bb..5fa07917a381 100644
--- a/games-puzzle/kiki/Manifest
+++ b/games-puzzle/kiki/Manifest
@@ -1,4 +1,6 @@
-MD5 a6a002477a3a85af9031c484c8e86397 ChangeLog 606
+MD5 c0605862315f7c012f672b57d56d9e35 ChangeLog 797
 MD5 f17b9b8fa07a38914fe1c03268f51678 metadata.xml 158
+MD5 feda1e6bf01b58ecac241ec0b62c4ae0 kiki-0.9.0-r1.ebuild 2107
 MD5 6c209b6c07867998c378875f4b29bddd kiki-0.9.0.ebuild 1690
 MD5 9721438ad8f7d2ff3cadd7c82d71eb94 files/digest-kiki-0.9.0 64
+MD5 9721438ad8f7d2ff3cadd7c82d71eb94 files/digest-kiki-0.9.0-r1 64
diff --git a/games-puzzle/kiki/files/digest-kiki-0.9.0-r1 b/games-puzzle/kiki/files/digest-kiki-0.9.0-r1
new file mode 100644
index 000000000000..1f8c68b9ed64
--- /dev/null
+++ b/games-puzzle/kiki/files/digest-kiki-0.9.0-r1
@@ -0,0 +1 @@
+MD5 60ec6bdf0196c9c934f683d3bf7a12ea kiki-src-0.9.0.tgz 2978977
diff --git a/games-puzzle/kiki/kiki-0.9.0-r1.ebuild b/games-puzzle/kiki/kiki-0.9.0-r1.ebuild
new file mode 100644
index 000000000000..28f61976af6d
--- /dev/null
+++ b/games-puzzle/kiki/kiki-0.9.0-r1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2004 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-puzzle/kiki/kiki-0.9.0-r1.ebuild,v 1.1 2004/08/30 20:45:30 mr_bones_ Exp $
+
+inherit python games
+
+DATA="${GAMES_DATADIR}/${PN}"
+S="${WORKDIR}"
+DESCRIPTION="Fun 3D puzzle game using SDL/OpenGL"
+HOMEPAGE="http://kiki.sourceforge.net/"
+SRC_URI="mirror://sourceforge/kiki/${PN}-src-${PV}.tgz"
+
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="x86"
+IUSE=""
+
+RDEPEND=">=media-libs/libsdl-1.2
+		>=media-libs/sdl-image-1.2.2
+		>=media-libs/sdl-mixer-1.2.5
+		>=dev-lang/python-2.2
+		virtual/glut"
+DEPEND="${RDEPEND}
+	>=sys-devel/gcc-3
+	>=sys-apps/sed-4"
+
+src_unpack() {
+	unpack ${A}
+
+	cd ${S}
+	# There are CVS directories in the tgz file
+	rm -rf $(find -name CVS -type d)
+	rm -rf $(find -name .cvsignore)
+	chmod a-x kiki_src/kiki/sounds/*.*
+
+	# Change the hard-coded data dir for sounds, etc...
+	sed -i \
+		-e "s:kiki_home += \"/\";:kiki_home = \"${DATA}/\";:g" \
+		-e "s:KConsole\:\:printf(\"WARNING \:\: environment variable KIKI_HOME not set ...\");::g" \
+		-e "s:KConsole\:\:printf(\"           ... assuming resources in current directory\");::g" \
+		kiki_src/kiki/src/main/KikiController.cpp \
+		|| die "sed KikiController.cpp failed"
+	sed -i \
+		-e 's/import random/import random, types/' \
+		kiki_src/kiki/py/world.py \
+		|| die "sed world.py failed"
+	python_version
+	sed -i \
+		-e "/^PYTHON_VERSION/s/2.2/${PYVER}/" \
+		-e '/lib-dynload/d' \
+		-e '/^PYTHONLIBS/s:\\:-lpython$(PYTHON_VERSION):' \
+		kiki_src/kiki/linux/Makefile \
+		|| die "sed kiki_src/kiki/linux/Makefile failed"
+}
+
+
+src_compile() {
+	cd "${S}/kiki_src/kodilib/linux"
+	emake || die "emake in kodilib/linux failed"
+	cd "${S}/kiki_src/kiki/linux"
+	emake || die "emake in kiki/linux failed"
+}
+
+src_install() {
+	dogamesbin kiki_src/kiki/linux/kiki || die "dogamesbin failed"
+
+	dodir "${DATA}/misc" "${DATA}/py" "${DATA}/sounds"
+	cp -R "${S}/kiki_src/kiki/"{misc,py,sounds} "${D}${DATA}" \
+		|| die "cp failed"
+
+	cd "${S}/kiki_src/kiki"
+	dodoc Readme.txt Thanks.txt "uDevGame Readme.txt"
+	prepgamesdirs
+}