Version bump.

Package-Manager: portage-2.2.8-r1/cvs/Linux x86_64
Manifest-Sign-Key: 0x4868F14D

1 files changed, 59 insertions, 0 deletions

diff --git a/dev-libs/granite/granite-0.2.3.1.ebuild b/dev-libs/granite/granite-0.2.3.1.ebuild
new file mode 100644
index 000000000000..30b76ff35773
--- /dev/null
+++ b/dev-libs/granite/granite-0.2.3.1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/granite/granite-0.2.3.1.ebuild,v 1.1 2014/04/07 15:31:18 ssuominen Exp $
+
+EAPI=5
+
+VALA_MIN_API_VERSION=0.16
+
+inherit cmake-utils gnome2-utils multilib vala versionator
+
+DESCRIPTION="A development library for elementary development"
+HOMEPAGE="http://launchpad.net/granite"
+SRC_URI="http://launchpad.net/${PN}/$(get_version_component_range 1-2)/${PV}/+download/${P}.tgz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND=">=dev-libs/glib-2.32
+	dev-libs/gobject-introspection
+	dev-libs/libgee:0[introspection]
+	>=x11-libs/gtk+-3.3.14:3"
+DEPEND="${RDEPEND}
+	$(vala_depend)
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS )
+
+src_prepare() {
+	vala_src_prepare
+	sed -i -e "/NAMES/s:valac:${VALAC}:" cmake/FindVala.cmake || die
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	mycmakeargs=(
+		-DLIB_INSTALL_DIR=$(get_libdir)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	HTML_DOCS=( doc/. )
+	cmake-utils_src_install
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}