Version bump

Package-Manager: portage-2.2_rc77/cvs/Linux x86_64

4 files changed, 139 insertions, 2 deletions

diff --git a/dev-lang/parrot/ChangeLog b/dev-lang/parrot/ChangeLog
index ea4e68402e74..82bd8f1ac36c 100644
--- a/dev-lang/parrot/ChangeLog
+++ b/dev-lang/parrot/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-lang/parrot
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/parrot/ChangeLog,v 1.35 2010/09/11 10:14:52 tove Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/parrot/ChangeLog,v 1.36 2010/09/11 10:35:01 tove Exp $
+
+*parrot-2.7.0 (11 Sep 2010)
+
+  11 Sep 2010; Torsten Veller <tove@gentoo.org> +parrot-2.7.0.ebuild:
+  Version bump
 
   11 Sep 2010; Torsten Veller <tove@gentoo.org> -parrot-2.4.0.ebuild,
   -parrot-2.5.0.ebuild, parrot-2.6.0.ebuild:
diff --git a/dev-lang/parrot/parrot-2.7.0.ebuild b/dev-lang/parrot/parrot-2.7.0.ebuild
new file mode 100644
index 000000000000..8fb816013a6c
--- /dev/null
+++ b/dev-lang/parrot/parrot-2.7.0.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/parrot/parrot-2.7.0.ebuild,v 1.1 2010/09/11 10:35:01 tove Exp $
+
+EAPI=3
+
+inherit eutils multilib
+
+DESCRIPTION="Virtual machine designed to efficiently compile and execute bytecode for dynamic languages"
+HOMEPAGE="http://www.parrot.org/"
+SRC_URI="ftp://ftp.parrot.org/pub/parrot/releases/supported/${PV}/${P}.tar.bz2"
+SRC_URI="ftp://ftp.parrot.org/pub/parrot/releases/devel/${PV}/${P}.tar.bz2"
+
+LICENSE="Artistic-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="opengl nls doc examples gdbm gmp ssl +unicode pcre"
+
+RDEPEND="sys-libs/readline
+	opengl? ( virtual/glut )
+	nls? ( sys-devel/gettext )
+	unicode? ( >=dev-libs/icu-2.6 )
+	gdbm? ( >=sys-libs/gdbm-1.8.3-r1 )
+	gmp? ( >=dev-libs/gmp-4.1.4 )
+	ssl? ( dev-libs/openssl )
+	pcre? ( dev-libs/libpcre )"
+
+DEPEND="dev-lang/perl[doc?]
+	${RDEPEND}"
+
+src_configure() {
+	myconf="--disable-rpath"
+	use unicode || myconf+=" --without-icu"
+	use ssl     || myconf+=" --without-crypto"
+	use gdbm    || myconf+=" --without-gdbm"
+	use nls     || myconf+=" --without-gettext"
+	use gmp     || myconf+=" --without-gmp"
+	use opengl  || myconf+=" --without-opengl"
+	use pcre    || myconf+=" --without-pcre"
+
+	perl Configure.pl \
+		--ccflags="${CFLAGS}" \
+		--linkflags="${LDFLAGS}" \
+		--prefix="${EROOT}"/usr \
+		--libdir="${EROOT}"/usr/$(get_libdir) \
+		--mandir="${EROOT}"/usr/share/man \
+		--sysconfdir="${EROOT}"/etc \
+		--sharedstatedir="${EROOT}"/var/lib/parrot \
+		--pkgconfigdir=pkgconfig \
+		$myconf || die
+}
+
+src_compile() {
+	export LD_LIBRARY_PATH=${LD_LIBRARY_PATH:+$LD_LIBRARY_PATH:}"${S}"/blib/lib
+	# occasionally dies in parallel make
+	emake -j1 || die
+	if use doc ; then
+		emake -j1 html || die
+	fi
+}
+
+src_test() {
+	emake -j1 test || die
+}
+
+src_install() {
+	emake -j1 install-dev DESTDIR="${ED}" DOC_DIR="${EROOT}/usr/share/doc/${PF}" || die
+	dodoc CREDITS DEPRECATED.pod DONORS.pod NEWS PBC_COMPAT PLATFORMS RESPONSIBLE_PARTIES TODO || die
+	if use examples; then
+		insinto "${EROOT}/usr/share/doc/${PF}/examples"
+		doins -r examples/* || die
+	fi
+	if use doc; then
+		insinto "${EROOT}/usr/share/doc/${PF}/editor"
+		doins -r editor || die
+		cd docs/html
+		dohtml -r developer.html DONORS.pod.html index.html ops.html parrotbug.html pdds.html \
+			pmc.html tools.html docs src tools || die
+	fi
+}
diff --git a/dev-lang/rakudo/ChangeLog b/dev-lang/rakudo/ChangeLog
index 3dee97b0ded0..9352cfe980f5 100644
--- a/dev-lang/rakudo/ChangeLog
+++ b/dev-lang/rakudo/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-lang/rakudo
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/rakudo/ChangeLog,v 1.9 2010/09/11 10:15:41 tove Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/rakudo/ChangeLog,v 1.10 2010/09/11 10:35:28 tove Exp $
+
+*rakudo-2010.08 (11 Sep 2010)
+
+  11 Sep 2010; Torsten Veller <tove@gentoo.org> +rakudo-2010.08.ebuild:
+  Version bump
 
   11 Sep 2010; Torsten Veller <tove@gentoo.org> -rakudo-2010.05.ebuild,
   -rakudo-2010.06.ebuild:
diff --git a/dev-lang/rakudo/rakudo-2010.08.ebuild b/dev-lang/rakudo/rakudo-2010.08.ebuild
new file mode 100644
index 000000000000..2df35fbe2505
--- /dev/null
+++ b/dev-lang/rakudo/rakudo-2010.08.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/rakudo/rakudo-2010.08.ebuild,v 1.1 2010/09/11 10:35:28 tove Exp $
+
+EAPI=3
+
+PARROT_VERSION="2.7.0"
+inherit eutils multilib
+
+DESCRIPTION="A Perl 6 implementation built on the Parrot virtual machine"
+HOMEPAGE="http://rakudo.org/"
+SRC_URI="http://cloud.github.com/downloads/${PN}/${PN}/${P}.tar.gz"
+
+LICENSE="Artistic-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+RDEPEND="~dev-lang/parrot-${PARROT_VERSION}[unicode]"
+DEPEND="${RDEPEND}
+	dev-lang/perl"
+#	>=dev-lang/perl-5.10"
+
+src_prepare() {
+	sed -i "s,\$(DOCDIR)/rakudo$,&-${PVR}," build/Makefile.in || die
+}
+
+src_configure() {
+	perl Configure.pl || die
+}
+
+src_test() {
+	emake -j1 test || die
+}
+
+src_install() {
+	emake DESTDIR="${ED}" install || die
+
+	dodoc CREDITS README docs/ChangeLog docs/ROADMAP || die
+
+	if use doc; then
+		dohtml -A svg docs/architecture.html docs/architecture.svg || die
+		dodoc docs/*.pod || die
+		docinto announce
+		dodoc docs/announce/* || die
+	fi
+}