Add bzip2 with static-libs, per bug#390163

Package-Manager: portage-2.2.0_alpha151/cvs/Linux x86_64

3 files changed, 152 insertions, 7 deletions

diff --git a/app-crypt/gnupg/ChangeLog b/app-crypt/gnupg/ChangeLog
index 994f8a94baf4..5a7c649a3d7a 100644
--- a/app-crypt/gnupg/ChangeLog
+++ b/app-crypt/gnupg/ChangeLog
@@ -1,11 +1,6 @@
 # ChangeLog for app-crypt/gnupg
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/ChangeLog,v 1.449 2013/01/12 20:15:19 alonbl Exp $
-
-*gnupg-2.0.19-r1 (12 Jan 2013)
-
-  12 Jan 2013; Alon Bar-Lev <alonbl@gentoo.org> +gnupg-2.0.19-r1.ebuild:
-  Add bzip2 with static-libs, per bug#390163
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/ChangeLog,v 1.450 2013/01/12 20:17:40 alonbl Exp $
 
   07 Jan 2013; Agostino Sarubbo <ago@gentoo.org> gnupg-1.4.13.ebuild:
   Stable for alpha, wrt bug #449546
diff --git a/app-crypt/gnupg/Manifest b/app-crypt/gnupg/Manifest
index 4732974da60a..698ea33b9df1 100644
--- a/app-crypt/gnupg/Manifest
+++ b/app-crypt/gnupg/Manifest
@@ -14,6 +14,7 @@ EBUILD gnupg-2.0.17-r2.ebuild 4323 SHA256 0b8eb50d4ed7ccf2e7552815de12feea599d57
 EBUILD gnupg-2.0.17-r3.ebuild 4377 SHA256 51b43e7d8509fc9c111b1e593a39100d8bb9de2b76e0199f5351183345831a83 SHA512 bd8327b6d5684a30e3ab309cfa14d172d32815a919dd0d1db145282769984257886c4ba8d77e81a320f517999270c77fa6a8be8bed18f4be2869a009ac2b4169 WHIRLPOOL 092b35bb77c8bbf6e00442c1dec004ad9bc7747c802e35dba07fb6b4765661928b4f588605ed00c7f7d2e507420902aa7fc9a6051130fdbc4aec04dd950f599e
 EBUILD gnupg-2.0.17.ebuild 4541 SHA256 1446fbb23702497fe625476dca396b52d860c490014d58e39a35b62077899be1 SHA512 71535d16f5f8df7323ee2c5a2e542622c49c76e4abd368faf968db27114a502d3c6b0172288b86072cc2a104652171770188f233fbe6e9a13589d2da13820c55 WHIRLPOOL 164044a6c1951f765ddc32d9c9e755c98d39972f4a0647ab2ebd0b21e66c105bbac7809fb61f247c190193f0395caa5d6496edff7223b3c698dd26e2739aa040
 EBUILD gnupg-2.0.18.ebuild 4491 SHA256 49a17fa71c86e8cfca2d6c118ff1288f99b12908640fc7a374b6dc03fce294ad SHA512 f0e5b4bad97c84cbb6431b2921e92746951e7979be6ff93652882cb664655c12689a9ed02b894d338e128370ce926386fe3532d43599182890c91b9c675ad526 WHIRLPOOL 501f5b99ac67b8d8f08e5416ba91ad47fd4b2edf486bb107e94a1ced3241fc72d1948c152c196ab85a9571af192a8725668be9bceac6bb0f13ec87dc28e3bb8a
+EBUILD gnupg-2.0.19-r1.ebuild 4492 SHA256 a31cdd66058ffd65d7cad0e1ac33f2c36828835e2da957ca604c37da81d67371 SHA512 6138a8afaf3e5293f5441e02c3b897b24420f0d23551a79b7282d0b726c76a649a16fa50f2c410908cdfb6c772d5c20f6a83653dffac5bc8af58c7689f4b874c WHIRLPOOL f2587cc7ff836cc2b6d780b8c5172658964a8ed0cccfeeb0f022b13aa77cdc2a78e74778593a5b6e7a0638d9ae8f5f4b08ba4ac20d12c6d999d472a25ff03f8b
 EBUILD gnupg-2.0.19.ebuild 4472 SHA256 5a5159050703c2cc0831b6b6a7a42e6d1d9a92b3443e5039290fed2b7cfbc5b6 SHA512 48310f5582cf4a95cd20828a7e313bf7bca79e4edbef44ec4f95d048f1f9d7c932f469dc239827f38a3fd6a4b0c5c7624d3f338d8735525a877d623aeb5b0105 WHIRLPOOL 59a01c348c91268690cbc28706d635f511fef2faa2158446a915736652421abb123bf45c9598412b21c8d7b11b5635b55301ec5f44fedce0476eaab7d7e7fd8c
-MISC ChangeLog 67603 SHA256 37888ba64c6705f08ff548feb23a34dda72e2af8af20eeb844f9c80b55241f86 SHA512 2307c2864f69f988c3e678c64a6af60c266bc52bb97849a076536bc07ce792d33f71d455e023b632bcaebb6b5497a8d4b6b12fe9a238fd9d28947f6490d29a1c WHIRLPOOL 0d190f2685386521c00e342f719a4632a89328b57cf8c546cc0f607b27ed42a3cf3cbce8f4b7f49e653788a0a2c7bbf4318dbbf769a9c50b26a62f96f5bfed0e
+MISC ChangeLog 67606 SHA256 b9c45c7038504c716baf99c0173d8fb43ff115b69618cdd4ddc94124596ea484 SHA512 72082f6652e9c4ba9b4285b1117be4cab9fd5db7256d9a2635a59af7bfcdb40f1de57fbff942ef1dbafc55a95c232bcb05de7832735b4255b5771b1b529f1918 WHIRLPOOL 6fa1fe08d347325fe17a94852749d8e98c8986b723582f3a07a791078e599b66c1f04919679c52fda153f22c802407cc29cce5d8cc2c301ba8d555c940798574
 MISC metadata.xml 1292 SHA256 da694ddf99d5ebdf57b48eff9f9a02753ededabd241a9b3d6647b58634dbcbb0 SHA512 df65933098afa09b867c99d01d3b938e0d3110c25f5eae3dae3174ad494b385e72e3cd9404c5a9f9b2f378c1227ebd406d93cd2cd9d6f5aedd3ba28fe058c17c WHIRLPOOL c593d44dae7b82cc438995845f4018e502f668e1b7393256100cdb658f5bef544bf9f0e76c335f336855fff94d0b9408e7ddd0a68cc40425ec863c8035fef630
diff --git a/app-crypt/gnupg/gnupg-2.0.19-r1.ebuild b/app-crypt/gnupg/gnupg-2.0.19-r1.ebuild
new file mode 100644
index 000000000000..fec597d8c45f
--- /dev/null
+++ b/app-crypt/gnupg/gnupg-2.0.19-r1.ebuild
@@ -0,0 +1,149 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/gnupg-2.0.19-r1.ebuild,v 1.1 2013/01/12 20:15:19 alonbl Exp $
+
+EAPI="4"
+
+inherit eutils flag-o-matic toolchain-funcs
+
+DESCRIPTION="The GNU Privacy Guard, a GPL pgp replacement"
+HOMEPAGE="http://www.gnupg.org/"
+SRC_URI="mirror://gnupg/gnupg/${P}.tar.bz2"
+# SRC_URI="ftp://ftp.gnupg.org/gcrypt/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="adns bzip2 doc ldap nls readline static selinux smartcard usb"
+
+COMMON_DEPEND_LIBS="
+	>=dev-libs/libassuan-2
+	>=dev-libs/libgcrypt-1.4
+	>=dev-libs/libgpg-error-1.7
+	>=dev-libs/libksba-1.0.7
+	>=dev-libs/pth-1.3.7
+	>=net-misc/curl-7.10
+	sys-libs/zlib
+	adns? ( >=net-libs/adns-1.4 )
+	bzip2? ( app-arch/bzip2 )
+	readline? ( sys-libs/readline )
+	smartcard? ( usb? ( virtual/libusb:0 ) )
+	ldap? ( net-nds/openldap )"
+COMMON_DEPEND_BINS="|| ( app-crypt/pinentry app-crypt/pinentry-qt )"
+
+# Existence of executables is checked during configuration.
+DEPEND="${COMMON_DEPEND_LIBS}
+	${COMMON_DEPEND_BINS}
+	static? (
+		>=dev-libs/libassuan-2[static-libs]
+		>=dev-libs/libgcrypt-1.4[static-libs]
+		>=dev-libs/libgpg-error-1.7[static-libs]
+		>=dev-libs/libksba-1.0.7[static-libs]
+		>=dev-libs/pth-1.3.7[static-libs]
+		sys-libs/zlib[static-libs]
+		bzip2? ( app-arch/bzip2[static-libs] )
+	)
+	nls? ( sys-devel/gettext )
+	doc? ( sys-apps/texinfo )"
+
+RDEPEND="!static? ( ${COMMON_DEPEND_LIBS} )
+	${COMMON_DEPEND_BINS}
+	virtual/mta
+	!<=app-crypt/gnupg-2.0.1
+	selinux? ( sec-policy/selinux-gpg )
+	nls? ( virtual/libintl )"
+
+REQUIRED_USE="smartcard? ( !static )"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.0.17-gpgsm-gencert.patch
+}
+
+src_configure() {
+	local myconf
+
+	# 'USE=static' support was requested:
+	# gnupg1: bug #29299
+	# gnupg2: bug #159623
+	use static && append-ldflags -static
+
+	if use smartcard; then
+		myconf+=" --enable-scdaemon $(use_enable usb ccid-driver)"
+	else
+		myconf+=" --disable-scdaemon"
+	fi
+
+	econf \
+		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
+		--enable-gpg \
+		--enable-gpgsm \
+		--enable-agent \
+		${myconf} \
+		$(use_with adns) \
+		$(use_enable bzip2) \
+		$(use_enable !elibc_SunOS symcryptrun) \
+		$(use_enable nls) \
+		$(use_enable ldap) \
+		$(use_with readline) \
+		CC_FOR_BUILD="$(tc-getBUILD_CC)"
+}
+
+src_compile() {
+	emake
+
+	if use doc; then
+		cd doc
+		emake html
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	emake DESTDIR="${D}" -f doc/Makefile uninstall-nobase_dist_docDATA
+	rm -r "${ED}usr/share/gnupg/help"*
+
+	dodoc ChangeLog NEWS README THANKS TODO VERSION doc/FAQ doc/DETAILS \
+		doc/HACKING doc/TRANSLATE doc/OpenPGP doc/KEYSERVER doc/help*
+
+	dosym gpg2 /usr/bin/gpg
+	dosym gpgv2 /usr/bin/gpgv
+	dosym gpg2keys_hkp /usr/libexec/gpgkeys_hkp
+	dosym gpg2keys_finger /usr/libexec/gpgkeys_finger
+	dosym gpg2keys_curl /usr/libexec/gpgkeys_curl
+	if use ldap; then
+		dosym gpg2keys_ldap /usr/libexec/gpgkeys_ldap
+	fi
+	echo ".so man1/gpg2.1" > "${ED}usr/share/man/man1/gpg.1"
+	echo ".so man1/gpgv2.1" > "${ED}usr/share/man/man1/gpgv.1"
+
+	dodir /etc/env.d
+	echo "CONFIG_PROTECT=/usr/share/gnupg/qualified.txt" >>"${ED}etc/env.d/30gnupg"
+
+	if use doc; then
+		dohtml doc/gnupg.html/* doc/*.png
+	fi
+}
+
+pkg_postinst() {
+	elog "If you wish to view images emerge:"
+	elog "media-gfx/xloadimage, media-gfx/xli or any other viewer"
+	elog "Remember to use photo-viewer option in configuration file to activate"
+	elog "the right viewer."
+	elog
+
+	if use smartcard; then
+		elog "To use your OpenPGP smartcard (or token) with GnuPG you need one of"
+		use usb && elog " - a CCID-compatible reader, used directly through libusb;"
+		elog " - sys-apps/pcsc-lite and a compatible reader device;"
+		elog " - dev-libs/openct and a compatible reader device;"
+		elog " - a reader device and drivers exporting either PC/SC or CT-API interfaces."
+		elog ""
+		elog "General hint: you probably want to try installing sys-apps/pcsc-lite and"
+		elog "app-crypt/ccid first."
+	fi
+
+	ewarn "Please remember to restart gpg-agent if a different version"
+	ewarn "of the agent is currently used. If you are unsure of the gpg"
+	ewarn "agent you are using please run 'killall gpg-agent',"
+	ewarn "and to start a fresh daemon just run 'gpg-agent --daemon'."
+}