www-apps/radicale: bump to 3.2.2

Closes: https://bugs.gentoo.org/933996
Signed-off-by: Henning Schild <henning@hennsch.de>
Closes: https://github.com/gentoo/gentoo/pull/38136
Signed-off-by: Eli Schwartz <eschwartz@gentoo.org>

2 files changed, 93 insertions, 0 deletions

diff --git a/www-apps/radicale/Manifest b/www-apps/radicale/Manifest
index 470c6848c9be..3fec068191cb 100644
--- a/www-apps/radicale/Manifest
+++ b/www-apps/radicale/Manifest
@@ -1 +1,2 @@
 DIST Radicale-3.1.9.gh.tar.gz 141258 BLAKE2B 6d74eabd7e09b1804a6a3c556a9f629fb72c4685fdf5d96d0d53ffaf5db712968b054678be866002ab4ceafaf1d3d8ad3f52aae7a9a4ecabbc129149c96ab9b6 SHA512 f4d0b26149c331b4bc02f01bb637cea1d29e1d563a4133c4293ec13990f1553988181582c2e726ce33b563403a14e9ec863403f86e66b13fd8cfd62cf74439e4
+DIST Radicale-3.2.2.gh.tar.gz 155283 BLAKE2B e82e59bd90275cb6f5a32479a163032e12201144b250a7c7987619bc5343a4494952d263957aafc2ff1e2983b2edb339648f5aeb7bd84718b7ae0d1d20159d0f SHA512 12d1d40e6c63a5229948b9eed8d1311fcebc0b59506497966712810b8745475c3407f68cbafbf0a16b11985e1179aea4355ff2ab67ad9a8b7440443ea451cdcd
diff --git a/www-apps/radicale/radicale-3.2.2.ebuild b/www-apps/radicale/radicale-3.2.2.ebuild
new file mode 100644
index 000000000000..76e6c53a8225
--- /dev/null
+++ b/www-apps/radicale/radicale-3.2.2.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 optfeature systemd
+
+MY_P=${P^}
+DESCRIPTION="A simple CalDAV calendar server"
+HOMEPAGE="https://radicale.org/"
+SRC_URI="
+	https://github.com/Kozea/Radicale/archive/refs/tags/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+
+RDEPEND="
+	>=acct-user/radicale-0-r2
+	acct-group/radicale
+	dev-python/bcrypt[${PYTHON_USEDEP}]
+	dev-python/defusedxml[${PYTHON_USEDEP}]
+	dev-python/passlib[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/vobject[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	sys-apps/util-linux
+"
+
+BDEPEND="
+	test? (
+		<dev-python/pytest-8[${PYTHON_USEDEP}]
+		dev-python/waitress[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+RDIR=/var/lib/"${PN}"
+
+DOCS=( DOCUMENTATION.md CHANGELOG.md )
+
+python_test() {
+	epytest -o addopts= radicale/tests/
+}
+
+python_install_all() {
+	rm README* || die
+	# init file
+	newinitd "${FILESDIR}"/radicale-r4.init.d radicale
+	systemd_dounit "${FILESDIR}/${PN}.service"
+
+	# directories
+	keepdir "${RDIR}"
+	fperms 0750 "${RDIR}"
+	fowners "${PN}:${PN}" "${RDIR}"
+
+	# config file
+	insinto /etc/"${PN}"
+	doins config
+
+	# fcgi and wsgi files
+	exeinto /usr/share/"${PN}"
+	doexe radicale.wsgi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	local _erdir="${EROOT}${RDIR}"
+
+	einfo "A sample WSGI script has been put into ${EROOT}/usr/share/${PN}."
+	einfo "You will also find there an example FastCGI script."
+	if [[ $(stat --format="%U:%G:%a" "${_erdir}") != "${PN}:${PN}:750" ]]
+	then
+		ewarn ""
+		ewarn "Unsafe file permissions detected on ${_erdir}."
+		ewarn "This probably comes from an earlier version of this ebuild."
+		ewarn "To fix run:"
+		ewarn "#  \`chown -R ${PN}:${PN} ${_erdir}\`"
+		ewarn "#  \`chmod 0750 ${_erdir}\`"
+		ewarn "#  \`chmod -R o= ${_erdir}\`"
+	fi
+
+	optfeature "Publish changes to rabbitmq" dev-python/pika
+}