1 files changed, 46 insertions, 0 deletions
diff --git a/x11-terms/qterminal/qterminal-2.0.0.ebuild b/x11-terms/qterminal/qterminal-2.0.0.ebuild
new file mode 100644
index 00000000..5e4b94e0
--- /dev/null
+++ b/x11-terms/qterminal/qterminal-2.0.0.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg-utils
+
+DESCRIPTION="Qt-based multitab terminal emulator"
+HOMEPAGE="https://lxqt-project.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-2 GPL-2+"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND=">=dev-util/lxqt-build-tools-2.0.0"
+DEPEND="
+	>=dev-qt/qtbase-6.6:6[dbus,gui,widgets]
+	x11-libs/libX11
+	~x11-libs/qtermwidget-${PV}:=
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTS=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}