kde-apps/kalzium: 23.08.4 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 68 insertions, 0 deletions

diff --git a/kde-apps/kalzium/Manifest b/kde-apps/kalzium/Manifest
new file mode 100644
index 0000000000..4952996d5e
--- /dev/null
+++ b/kde-apps/kalzium/Manifest
@@ -0,0 +1 @@
+DIST kalzium-23.08.4.tar.xz 24642260 BLAKE2B 2c6ed12a8d4e0c69f5725ea56edf5ea3dd2654c54a9912d33d5515037f4ae8a97d5fe7824d925dc40a99f43c7b3de5900b112d9e6e766f0d69a80e80b0ab1e13 SHA512 70d599f47bd84c728fa7459c51890d2814591b91a3fb5d768145e5da57eb196832d3995f780e143166e67e0689f99d9497084a0f76ddd797358ad5129f7a82e6
diff --git a/kde-apps/kalzium/kalzium-23.08.4.ebuild b/kde-apps/kalzium/kalzium-23.08.4.ebuild
new file mode 100644
index 0000000000..787014d64f
--- /dev/null
+++ b/kde-apps/kalzium/kalzium-23.08.4.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org flag-o-matic
+
+DESCRIPTION="Periodic table of the elements"
+HOMEPAGE="https://apps.kde.org/kalzium/ https://edu.kde.org/kalzium/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="editor solver"
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtscript-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kplotting-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kunitconversion-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	editor? (
+		dev-cpp/eigen:3
+		>=dev-qt/qtopengl-${QTMIN}:5
+		>=kde-frameworks/knewstuff-${KFMIN}:5
+		sci-chemistry/openbabel:=
+		>=sci-libs/avogadrolibs-1.93[qt5]
+	)
+	solver? ( dev-ml/facile:=[ocamlopt] )
+"
+RDEPEND="${DEPEND}
+	sci-chemistry/chemical-mime-data
+"
+
+PATCHES=( "${FILESDIR}/${PN}-21.03.90-cmake.patch" )
+
+src_configure() {
+	# Fix missing finite()
+	[[ ${CHOST} == *-solaris* ]] && append-cppflags -DHAVE_IEEEFP_H
+
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_OpenBabel3=ON # TODO: bug 823101
+		$(cmake_use_find_package editor Eigen3)
+		$(cmake_use_find_package editor AvogadroLibs)
+		$(cmake_use_find_package editor OpenBabel2)
+		$(cmake_use_find_package solver OCaml)
+		$(cmake_use_find_package solver Libfacile)
+	)
+
+	ecm_src_configure
+}