1 files changed, 100 insertions, 0 deletions
diff --git a/media-libs/swfdec/swfdec-9999.ebuild b/media-libs/swfdec/swfdec-9999.ebuild
new file mode 100644
index 0000000..d2774e7
--- /dev/null
+++ b/media-libs/swfdec/swfdec-9999.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/swfdec/swfdec-0.7.4.ebuild,v 1.2 2008/08/17 20:27:46 ford_prefect Exp $
+
+EAPI=1
+
+inherit autotools eutils git versionator
+
+DESCRIPTION="Macromedia Flash decoding library"
+HOMEPAGE="http://swfdec.freedesktop.org"
+EGIT_REPO_URI="git://anongit.freedesktop.org/git/${PN}/${PN}"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS=""
+
+IUSE="alsa doc ffmpeg gstreamer gtk oss pulseaudio"
+
+RDEPEND=">=dev-libs/glib-2.12
+	>=dev-libs/liboil-0.3.1
+	>=x11-libs/pango-1.16.4
+	gtk? (
+		>=x11-libs/gtk+-2.8.0
+		net-libs/libsoup:2.4
+		)
+	>=x11-libs/cairo-1.6
+	gstreamer? (
+		>=media-libs/gstreamer-0.10.11
+		>=media-libs/gst-plugins-base-0.10.15
+		ffmpeg? ( media-plugins/gst-plugins-ffmpeg )
+		)
+	alsa? ( >=media-libs/alsa-lib-1.0.12 )
+	pulseaudio? ( media-sound/pulseaudio )"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	doc? ( >=dev-util/gtk-doc-1.6 )"
+
+pkg_setup() {
+	if use !gtk ; then
+		ewarn "swfdec will be built without swfdec-gtk convenience"
+		ewarn "library, which is needed by swfdec-mozilla and"
+		ewarn "swfdec-gnome. Please add 'gtk' to your USE flags"
+		ewarn "unless you really know what you are doing."
+	fi
+
+	if use !gstreamer && use ffmpeg; then
+		ewarn
+		ewarn "The 'ffmpeg' USE flag enables video support via gst-plugins-ffmpeg"
+		ewarn "as such it requires the 'gstreamer' USE flag to be enabled."
+	fi
+
+	if use alsa && use pulseaudio; then
+		ewarn
+		ewarn "Pulseaudio and ALSA selected. Selecting mature ALSA backend."
+	fi
+}
+
+src_unpack() {
+	git_src_unpack
+
+	eautoreconf
+}
+
+src_compile() {
+	# Backend logic is from configure.ac:
+	# alsa > pulseaudio > oss
+	local audio="none"
+	use oss && audio="oss"
+	use pulseaudio && audio="pulse"
+	use alsa && audio="alsa"
+
+	# bug #216009
+	# avoid writing to /root/.gstreamer-0.10/registry.xml
+	export GST_REGISTRY="${T}"/registry.xml
+	# also avoid loading gconf plugins, which may write to /root/.gconfd
+	export GST_PLUGIN_SYSTEM_PATH="${T}"
+
+	econf \
+		$(use_enable doc gtk-doc) \
+		$(use_enable gstreamer) \
+		$(use_enable gtk) \
+		--disable-ffmpeg \
+		--disable-mad \
+		--with-audio=${audio} || die "configure failed"
+
+	# bug #216284 image tests are not ready yet
+	cat  >test/image/Makefile <<EOF
+all:
+check:
+install:
+EOF
+
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die "emake install failed"
+	dodoc AUTHORS ChangeLog README
+}