sys-apps/lshw/lshw-02.04b.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/lshw/lshw-02.04b.ebuild,v 1.5 2005/07/22 04:06:54 vapier Exp $

inherit flag-o-matic eutils toolchain-funcs

MAJ_PV=${PV:0:5}
MIN_PVE=${PV:5:7}
MIN_PV=${MIN_PVE/b/B}

MY_P="$PN-$MIN_PV.$MAJ_PV"
DESCRIPTION="Hardware Lister"
HOMEPAGE="http://ezix.sourceforge.net/"
SRC_URI="http://ezix.sourceforge.net/software/files/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ppc sparc x86"
IUSE="gtk static"

DEPEND="gtk? ( >=x11-libs/gtk+-2 )
	>=sys-devel/binutils-2.15"

S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${A}
	cd "${S}"

	use static && append-ldflags -static
	sed -i \
		-e "/^CXXFLAGS/s:-Os:${CXXFLAGS}:" \
		-e '/^LDFLAGS=/s:-Os -s::' \
		-e '/^CXX=/d' -e '/^CC=/d' \
		src/{gui/,core/,}/Makefile \
		|| die "sed failed"
	sed -i \
		-e "/^LDFLAGS=/s:$: ${LDFLAGS}:" \
		src/Makefile || die "sed ldflags failed"

	#epatch ${FILESDIR}/${PV}-dev.patch #75168
	epatch "${FILESDIR}"/02.00b-cpuid-PIC.patch #61947
}

src_compile() {
	tc-export CC CXX AR
	emake || die "make failed"
	if use gtk ; then
		emake gui || die "make gui failed"
	fi
}

src_install() {
	make DESTDIR="${D}" install || die "install failed"

	if use gtk ; then
		make DESTDIR="${D}" install-gui || die "install gui failed"
	fi

	dodoc README docs/*
}