sci-libs/lrslib/lrslib-051.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/lrslib/lrslib-051.ebuild,v 1.1 2015/03/08 15:18:28 tomka Exp $

EAPI=5

inherit toolchain-funcs

DESCRIPTION="self-contained ANSI C implementation of the reverse search algorithm"
HOMEPAGE="http://cgm.cs.mcgill.ca/~avis/C/lrs.html"
SRC_URI="http://cgm.cs.mcgill.ca/~avis/C/lrslib/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gmp"

DEPEND="gmp? ( dev-libs/gmp )"
RDEPEND="${DEPEND}"

src_prepare(){
	sed -i "s/gcc/$(tc-getCC)/g" makefile || die
	sed -i "s/-O3/${CFLAGS} ${LDFLAGS}/g" makefile || die
	# Prefix for install
	sed -i "s,/usr/local,/usr,g" makefile || die
}

src_compile () {
	if use gmp ; then
		emake all
		emake all-shared
	else
		emake allmp
	fi
}

src_install() {
	dodoc readme
	# Library
	if use gmp ; then
		emake DESTDIR="${D}" install-shared
	fi
	# Install default set of binaries
	emake DESTDIR="${D}" install-common
}