blob: 3b12f787a549599bfc922c50d17315b4ff0ae496 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
|
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/ceres-solver/ceres-solver-1.4.0.ebuild,v 1.1 2012/11/19 22:45:17 bicatali Exp $
EAPI=4
inherit cmake-utils eutils multilib
DESCRIPTION="Nonlinear least-squares minimizer"
HOMEPAGE="https://code.google.com/p/ceres-solver/"
SRC_URI="https://${PN}.googlecode.com/files/${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc examples gflags metis openmp protobuf +schur +sparse static-libs test"
REQUIRED_USE="test? ( gflags )"
RDEPEND="
dev-cpp/eigen:3
dev-cpp/glog[gflags?]
protobuf? ( dev-libs/protobuf )
sparse? (
sci-libs/amd
sci-libs/camd
sci-libs/ccolamd
sci-libs/cholmod[metis?]
sci-libs/colamd
sci-libs/cxsparse
virtual/blas
virtual/lapack )"
DEPEND="${RDEPEND}
sparse? ( virtual/pkgconfig )
doc? (
dev-python/pygments
virtual/latex-base
dev-texlive/texlive-science )"
src_prepare() {
# prefix love
# disable blas/lapack forced library names
sed -i \
-e "s:/usr:${EPREFIX}/usr:g" \
-e '/FIND_LIBRARY(BLAS_LIB NAMES blas)/d' \
-e '/FIND_LIBRARY(LAPACK_LIB NAMES lapack)/d' \
-e 's/EXISTS ${BLAS_LIB}/BLAS_LIB/g' \
-e 's/EXISTS ${LAPACK_LIB}/LAPACK_LIB/g' \
CMakeLists.txt || die
sed -i \
-e "s:share/ceres/docs:share/doc/${PF}:" \
docs/CMakeLists.txt || die
epatch \
"${FILESDIR}"/${P}-test-no-suitesparse.patch \
"${FILESDIR}"/${P}-respect-libdir.patch
}
src_configure() {
local blibs llibs
if use sparse; then
blibs=$(pkg-config --libs blas)
llibs=$(pkg-config --libs lapack)
fi
local mycmakeargs=(
-DBLAS_LIB="${blibs}"
-DLAPACK_LIB="${llibs}"
$(cmake-utils_use_enable test TESTING)
$(cmake-utils_use doc BUILD_DOCUMENTATION)
$(cmake-utils_use gflags GFLAGS)
$(cmake-utils_use openmp OPENMP)
$(cmake-utils_use protobuf PROTOBUF)
$(cmake-utils_use schur SCHUR_SPECIALIZATIONS)
$(cmake-utils_use sparse CXSPARSE)
$(cmake-utils_use sparse SUITESPARSE)
)
cmake-utils_src_configure
}
src_install() {
cmake-utils_src_install
dodoc README VERSION
use static-libs || rm "${ED}"/usr/$(get_libdir)/libceres.a
dosym libceres_shared.so /usr/$(get_libdir)/libceres.so
if use examples; then
insinto /usr/share/doc/${PF}
doins -r examples
fi
}
|
GitWeb