games-util/atlas/atlas-0.2.2-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-util/atlas/atlas-0.2.2-r1.ebuild,v 1.5 2005/08/23 20:36:15 wolf31o2 Exp $

inherit eutils games

MY_P="Atlas-${PV}"
DESCRIPTION="Chart Program to use with Flightgear Flight Simulator"
HOMEPAGE="http://atlas.sourceforge.net/"
SRC_URI="mirror://sourceforge/atlas/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="ppc ~sparc x86"
IUSE=""

DEPEND=">=games-simulation/flightgear-0.9.4
	>=media-libs/libpng-1.2.5
	>=media-libs/plib-1.4
	virtual/glut"

S=${WORKDIR}/${MY_P}

INSDESTTREE="${GAMES_LIBDIR}/FlightGear"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${PV}-fix.patch"
}

src_compile() {
	egamesconf --with-fgbase="${GAMES_LIBDIR}/FlightGear" || die
	emake || die "emake failed"
}

src_install() {
	doins "${S}/src/AtlasPalette" || die
	egamesinstall || die
	keepdir "${GAMES_LIBDIR}/FlightGear/Atlas/lowres"
	dodoc AUTHORS README
	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	einfo "You now can make the maps with the following commands:"
	einfo "${GAMES_BINDIR}/Map --atlas=${GAMES_LIBDIR}/FlightGear/Atlas"
	einfo "${GAMES_BINDIR}/Map --atlas=${GAMES_LIBDIR}/FlightGear/Atlas/lowres --size=64"
	echo
	einfo "To run Atlas concurrently with FlightGear use the following:"
	einfo "Atlas --path=[path of map images] --udp=[port number]"
	einfo "and start fgfs with the following switch (or in .fgfsrc):"
	einfo "--nmea=socket,out,0.5,[host that you run Atlas on],[port number],udp"
	echo
}

pkg_postrm() {
	einfo "You must manually remove the maps if you don't want them around."
	einfo "They are found in the following directory:"
	echo
	einfo "${GAMES_LIBDIR}/FlightGear/Atlas"
	echo
}