1 files changed, 39 insertions, 0 deletions
diff --git a/games-misc/opengfx/opengfx-0.5.1.ebuild b/games-misc/opengfx/opengfx-0.5.1.ebuild
new file mode 100644
index 000000000000..33275ac3c798
--- /dev/null
+++ b/games-misc/opengfx/opengfx-0.5.1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-misc/opengfx/opengfx-0.5.1.ebuild,v 1.1 2014/06/13 08:57:57 mr_bones_ Exp $
+
+EAPI=5
+inherit eutils games
+
+DESCRIPTION="OpenGFX data files for OpenTTD"
+HOMEPAGE="http://bundles.openttdcoop.org/opengfx/"
+SRC_URI="http://bundles.openttdcoop.org/opengfx/releases/${PV}/${P}-source.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+IUSE=""
+RESTRICT="test" # nml version affects the checksums that the test uses (bug #451444)
+
+DEPEND=">=games-util/nml-0.3.0
+	games-util/grfcodec"
+RDEPEND=""
+
+S=${WORKDIR}/${P}-source
+
+src_prepare() {
+	# ensure that we will not use gimp to regenerate the pngs
+	# causes sandbox violations and not worth the effort anyway
+	sed -i -e '/^GFX_SCRIPT_LIST_FILES/s/^/#/' Makefile.config || die
+}
+
+src_compile() {
+	_V= emake bundle_tar
+}
+
+src_install() {
+	insinto "${GAMES_DATADIR}/openttd/data/"
+	doins *.grf opengfx.obg
+	dodoc docs/{changelog.txt,readme.txt}
+	prepgamesdirs
+}