1 files changed, 37 insertions, 0 deletions
diff --git a/dev-ruby/prawn/prawn-1.3.0.ebuild b/dev-ruby/prawn/prawn-1.3.0.ebuild
new file mode 100644
index 000000000000..22cf49c93fcb
--- /dev/null
+++ b/dev-ruby/prawn/prawn-1.3.0.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/prawn/prawn-1.3.0.ebuild,v 1.1 2014/10/04 17:42:01 mrueg Exp $
+
+EAPI=5
+USE_RUBY="ruby19 ruby20 ruby21"
+
+RUBY_FAKEGEM_RECIPE_DOC="yard"
+RUBY_FAKEGEM_RECIPE_TEST="rspec"
+RUBY_FAKEGEM_EXTRAINSTALL="data"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Fast, Nimble PDF Generation For Ruby"
+HOMEPAGE="http://prawn.majesticseacreature.com/"
+SRC_URI="https://github.com/prawnpdf/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="|| ( GPL-2 Ruby )"
+SLOT="1"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE=""
+
+ruby_add_rdepend ">=dev-ruby/pdf-core-0.4.0
+	>=dev-ruby/ttfunk-1.4.0"
+ruby_add_bdepend "test? ( dev-ruby/coderay
+	dev-ruby/mocha
+	>=dev-ruby/pdf-inspector-1.1.0
+	>=dev-ruby/pdf-reader-1.2
+	)"
+
+all_ruby_prepare() {
+	sed -i -e "/[Bb]undler/d" Rakefile spec/spec_helper.rb || die
+	# Remove failing tests
+	# https://github.com/prawnpdf/prawn/pull/693
+	# https://github.com/prawnpdf/prawn/issues/603
+	sed -i -e "/should process UTF-8 chars/,+9 s/^/#/" spec/line_wrap_spec.rb || die
+	sed -i -e "/shrink_to_fit with special utf-8 text/,+12 s/^/#/" spec/text_spec.rb || die
+}