1 files changed, 57 insertions, 0 deletions
diff --git a/app-text/multitail/multitail-6.1.ebuild b/app-text/multitail/multitail-6.1.ebuild
new file mode 100644
index 000000000000..d39436816484
--- /dev/null
+++ b/app-text/multitail/multitail-6.1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/multitail/multitail-6.1.ebuild,v 1.1 2014/02/13 07:59:26 jlec Exp $
+
+EAPI=5
+
+inherit eutils flag-o-matic toolchain-funcs
+
+DESCRIPTION="Tail with multiple windows"
+HOMEPAGE="http://www.vanheusden.com/multitail/"
+SRC_URI="http://www.vanheusden.com/multitail/${P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ia64 ~ppc ~sparc ~x86 ~x86-interix ~amd64-linux ~x86-linux"
+IUSE="debug examples unicode"
+
+RDEPEND="sys-libs/ncurses[unicode?]"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+RESTRICT="test" # bug #492270
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-6.0-as-needed.patch
+
+	use x86-interix && epatch "${FILESDIR}"/${PN}-5.2.6-interix.patch
+
+	sed \
+		-e '/gcc/d' \
+		-e '/scan-build/d' \
+		-e 's:make clean::g' \
+		-e "/^DESTDIR/s:=.*$:=${EROOT}:g" \
+		-i Makefile || die
+
+	tc-export CC PKG_CONFIG
+
+	use debug && append-flags "-D_DEBUG"
+}
+
+src_configure() {
+	emake UTF8_SUPPORT=$(usex unicode)
+}
+
+src_install () {
+	dobin multitail
+
+	insinto /etc
+	doins multitail.conf
+
+	dodoc Changes readme.txt thanks.txt
+	doman multitail.1
+
+	dohtml manual.html
+
+	docinto examples
+	use examples && dodoc colors-example.{pl,sh} convert-{geoip,simple}.pl
+}