1 files changed, 54 insertions, 0 deletions
diff --git a/app-admin/eselect-python/eselect-python-20091230.ebuild b/app-admin/eselect-python/eselect-python-20091230.ebuild
new file mode 100644
index 000000000000..ba2328f2f572
--- /dev/null
+++ b/app-admin/eselect-python/eselect-python-20091230.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/eselect-python/eselect-python-20091230.ebuild,v 1.1 2009/12/30 22:17:12 arfrever Exp $
+
+EAPI="1"
+
+inherit flag-o-matic toolchain-funcs
+
+DESCRIPTION="Eselect module for management of multiple Python versions"
+HOMEPAGE="http://www.gentoo.org"
+SRC_URI="mirror://gentoo/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+IUSE=""
+
+RDEPEND=">=app-admin/eselect-1.2.3"
+DEPEND="${RDEPEND}
+	sys-devel/autoconf
+	>=sys-devel/gcc-3.4"
+
+pkg_setup() {
+	append-flags -fno-PIC -fno-PIE
+
+	if [[ $(gcc-major-version) -lt 3 || ($(gcc-major-version) -eq 3 && $(gcc-minor-version) -lt 4) ]]; then
+		die "GCC >=3.4 is required"
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	./autogen.sh || die "autogen.sh failed"
+}
+
+src_install() {
+	keepdir /etc/env.d/python
+	emake DESTDIR="${D}" install || die "emake install failed"
+}
+
+pkg_preinst() {
+	if has_version "<${CATEGORY}/${PN}-20090804" || ! has_version "${CATEGORY}/${PN}"; then
+		run_eselect_python_update="1"
+	fi
+}
+
+pkg_postinst() {
+	if [[ "${run_eselect_python_update}" == "1" ]]; then
+		ebegin "Running \`eselect python update\`"
+		eselect python update --ignore 3.0 --ignore 3.1 --ignore 3.2 > /dev/null
+		eend "$?"
+	fi
+}