Xfce 4.12 version bump, bug #541962. https://github.com/gentoo/gentoo-portage-rsync-mirror/pull/63 by me and damex.

(Portage version: 2.2.17/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

27 files changed, 718 insertions, 15 deletions

diff --git a/xfce-base/exo/ChangeLog b/xfce-base/exo/ChangeLog
index f2d81571bb1c..f0664acf84f3 100644
--- a/xfce-base/exo/ChangeLog
+++ b/xfce-base/exo/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for xfce-base/exo
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/exo/ChangeLog,v 1.111 2015/03/03 12:59:33 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/exo/ChangeLog,v 1.112 2015/03/08 15:06:39 mgorny Exp $
+
+*exo-0.10.3 (08 Mar 2015)
+
+  08 Mar 2015; Michał Górny <mgorny@gentoo.org> +exo-0.10.3.ebuild:
+  Xfce 4.12 version bump, bug #541962. https://github.com/gentoo/gentoo-portage-
+  rsync-mirror/pull/63 by me and damex.
 
   03 Mar 2015; Yixun Lan <dlan@gentoo.org> exo-0.10.2-r1.ebuild:
   add arm64 support, tested on A53 board
diff --git a/xfce-base/exo/exo-0.10.3.ebuild b/xfce-base/exo/exo-0.10.3.ebuild
new file mode 100644
index 000000000000..1ec9707f6d38
--- /dev/null
+++ b/xfce-base/exo/exo-0.10.3.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/exo/exo-0.10.3.ebuild,v 1.1 2015/03/08 15:06:39 mgorny Exp $
+
+EAPI=5
+inherit xfconf
+
+DESCRIPTION="Extensions, widgets and framework library with session support for the Xfce desktop environment"
+HOMEPAGE="http://www.xfce.org/projects/"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x64-solaris ~x86-solaris"
+IUSE="debug"
+
+RDEPEND=">=dev-lang/perl-5.6
+	>=dev-libs/glib-2.30
+	dev-perl/URI
+	>=x11-libs/gtk+-2.24:2
+	>=xfce-base/libxfce4ui-4.10
+	>=xfce-base/libxfce4util-4.10"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+pkg_setup() {
+	XFCONF=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		$(xfconf_use_debug)
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
+		)
+
+	[[ ${CHOST} == *-darwin* ]] && XFCONF+=( --disable-visibility ) #366857
+
+	DOCS=( AUTHORS ChangeLog HACKING NEWS README THANKS TODO )
+}
diff --git a/xfce-base/garcon/ChangeLog b/xfce-base/garcon/ChangeLog
index bce5421e587b..418ba8b206fb 100644
--- a/xfce-base/garcon/ChangeLog
+++ b/xfce-base/garcon/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for xfce-base/garcon
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/garcon/ChangeLog,v 1.69 2015/03/03 13:00:59 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/garcon/ChangeLog,v 1.70 2015/03/08 15:06:39 mgorny Exp $
+
+*garcon-0.4.0 (08 Mar 2015)
+
+  08 Mar 2015; Michał Górny <mgorny@gentoo.org> +garcon-0.4.0.ebuild:
+  Xfce 4.12 version bump, bug #541962. https://github.com/gentoo/gentoo-portage-
+  rsync-mirror/pull/63 by me and damex.
 
   03 Mar 2015; Yixun Lan <dlan@gentoo.org> garcon-0.3.0.ebuild:
   add arm64 support, tested on A53 board
diff --git a/xfce-base/garcon/garcon-0.4.0.ebuild b/xfce-base/garcon/garcon-0.4.0.ebuild
new file mode 100644
index 000000000000..305c02928a02
--- /dev/null
+++ b/xfce-base/garcon/garcon-0.4.0.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/garcon/garcon-0.4.0.ebuild,v 1.1 2015/03/08 15:06:39 mgorny Exp $
+
+EAPI=5
+inherit xfconf
+
+DESCRIPTION="Xfce's freedesktop.org specification compatible menu implementation library"
+HOMEPAGE="http://www.xfce.org/projects/libraries/"
+SRC_URI="mirror://xfce/src/libs/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="LGPL-2 FDL-1.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug"
+
+RDEPEND=">=dev-libs/glib-2.30
+	>=x11-libs/gtk+-2.24:2
+	>=xfce-base/libxfce4ui-4.11
+	>=xfce-base/libxfce4util-4.11"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+pkg_setup() {
+	XFCONF=(
+		$(xfconf_use_debug)
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
+		)
+
+	DOCS=( AUTHORS ChangeLog HACKING NEWS README STATUS TODO )
+}
diff --git a/xfce-base/libxfce4ui/ChangeLog b/xfce-base/libxfce4ui/ChangeLog
index 4e56fce3450e..31771cf90189 100644
--- a/xfce-base/libxfce4ui/ChangeLog
+++ b/xfce-base/libxfce4ui/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for xfce-base/libxfce4ui
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/libxfce4ui/ChangeLog,v 1.54 2015/03/03 13:02:16 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/libxfce4ui/ChangeLog,v 1.55 2015/03/08 15:06:39 mgorny Exp $
+
+*libxfce4ui-4.12.0 (08 Mar 2015)
+
+  08 Mar 2015; Michał Górny <mgorny@gentoo.org> +libxfce4ui-4.12.0.ebuild:
+  Xfce 4.12 version bump, bug #541962. https://github.com/gentoo/gentoo-portage-
+  rsync-mirror/pull/63 by me and damex.
 
   03 Mar 2015; Yixun Lan <dlan@gentoo.org> libxfce4ui-4.11.1.ebuild:
   add arm64 support, tested on A53 board
diff --git a/xfce-base/libxfce4ui/libxfce4ui-4.12.0.ebuild b/xfce-base/libxfce4ui/libxfce4ui-4.12.0.ebuild
new file mode 100644
index 000000000000..3194664ed92a
--- /dev/null
+++ b/xfce-base/libxfce4ui/libxfce4ui-4.12.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/libxfce4ui/libxfce4ui-4.12.0.ebuild,v 1.1 2015/03/08 15:06:39 mgorny Exp $
+
+EAPI=5
+inherit xfconf
+
+DESCRIPTION="Unified widgets and session management libraries for the Xfce desktop environment"
+HOMEPAGE="http://www.xfce.org/projects/libxfce4"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug glade startup-notification"
+
+RDEPEND=">=dev-libs/glib-2.30
+	>=x11-libs/gtk+-2.24:2
+	>=x11-libs/gtk+-3.2:3
+	x11-libs/libX11
+	x11-libs/libICE
+	x11-libs/libSM
+	>=xfce-base/libxfce4util-4.12
+	>=xfce-base/xfconf-4.12
+	glade? ( dev-util/glade:3 )
+	startup-notification? ( x11-libs/startup-notification )
+	!xfce-base/xfce-utils"
+DEPEND="${RDEPEND}
+	dev-lang/perl
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+pkg_setup() {
+	XFCONF=(
+		--enable-gtk3
+		$(use_enable startup-notification)
+		$(use_enable glade gladeui)
+		$(xfconf_use_debug)
+		--with-vendor-info=Gentoo
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
+		)
+
+	[[ ${CHOST} == *-darwin* ]] && XFCONF+=( --disable-visibility ) #366857
+
+	DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO )
+}
diff --git a/xfce-base/libxfce4util/ChangeLog b/xfce-base/libxfce4util/ChangeLog
index 76564b2e2836..6f355f2f4770 100644
--- a/xfce-base/libxfce4util/ChangeLog
+++ b/xfce-base/libxfce4util/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for xfce-base/libxfce4util
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/libxfce4util/ChangeLog,v 1.197 2015/03/03 13:03:36 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/libxfce4util/ChangeLog,v 1.198 2015/03/08 15:06:39 mgorny Exp $
+
+*libxfce4util-4.12.1 (08 Mar 2015)
+
+  08 Mar 2015; Michał Górny <mgorny@gentoo.org> +libxfce4util-4.12.1.ebuild:
+  Xfce 4.12 version bump, bug #541962. https://github.com/gentoo/gentoo-portage-
+  rsync-mirror/pull/63 by me and damex.
 
   03 Mar 2015; Yixun Lan <dlan@gentoo.org> libxfce4util-4.11.0.ebuild:
   add arm64 support, tested on A53 board
diff --git a/xfce-base/libxfce4util/libxfce4util-4.12.1.ebuild b/xfce-base/libxfce4util/libxfce4util-4.12.1.ebuild
new file mode 100644
index 000000000000..ec0a5dca37c7
--- /dev/null
+++ b/xfce-base/libxfce4util/libxfce4util-4.12.1.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/libxfce4util/libxfce4util-4.12.1.ebuild,v 1.1 2015/03/08 15:06:39 mgorny Exp $
+
+EAPI=5
+inherit xfconf
+
+DESCRIPTION="A basic utility library for the Xfce desktop environment"
+HOMEPAGE="http://www.xfce.org/projects/"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="0/7"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x64-solaris ~x86-solaris"
+IUSE="debug"
+
+RDEPEND=">=dev-libs/glib-2.24"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+pkg_setup() {
+	XFCONF=(
+		$(xfconf_use_debug)
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
+		)
+
+	[[ ${CHOST} == *-darwin* ]] && XFCONF+=( --disable-visibility ) #366857
+
+	DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO )
+}
diff --git a/xfce-base/thunar/ChangeLog b/xfce-base/thunar/ChangeLog
index 02c8264f6c57..056ff75d1ab9 100644
--- a/xfce-base/thunar/ChangeLog
+++ b/xfce-base/thunar/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for xfce-base/thunar
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/thunar/ChangeLog,v 1.176 2015/03/03 13:04:56 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/thunar/ChangeLog,v 1.177 2015/03/08 15:06:39 mgorny Exp $
+
+*thunar-1.6.6 (08 Mar 2015)
+
+  08 Mar 2015; Michał Górny <mgorny@gentoo.org> +thunar-1.6.6.ebuild:
+  Xfce 4.12 version bump, bug #541962. https://github.com/gentoo/gentoo-portage-
+  rsync-mirror/pull/63 by me and damex.
 
   03 Mar 2015; Yixun Lan <dlan@gentoo.org> thunar-1.6.3.ebuild:
   add arm64 support, tested on A53 board
diff --git a/xfce-base/thunar/thunar-1.6.6.ebuild b/xfce-base/thunar/thunar-1.6.6.ebuild
new file mode 100644
index 000000000000..c43c9da831f5
--- /dev/null
+++ b/xfce-base/thunar/thunar-1.6.6.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/thunar/thunar-1.6.6.ebuild,v 1.1 2015/03/08 15:06:39 mgorny Exp $
+
+EAPI=5
+inherit virtualx xfconf
+
+MY_P=${P/t/T}
+
+DESCRIPTION="File manager for the Xfce desktop environment"
+HOMEPAGE="http://www.xfce.org/projects/ http://thunar.xfce.org/"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="+dbus debug exif libnotify pcre startup-notification test udisks +xfce_plugins_trash"
+
+GVFS_DEPEND=">=gnome-base/gvfs-1.18.3"
+COMMON_DEPEND=">=dev-lang/perl-5.6
+	>=dev-libs/glib-2.30
+	>=x11-libs/gdk-pixbuf-2.14
+	>=x11-libs/gtk+-2.24:2
+	>=xfce-base/exo-0.10
+	>=xfce-base/libxfce4ui-4.10
+	>=xfce-base/libxfce4util-4.10.1
+	>=xfce-base/xfconf-4.10
+	dbus? ( >=dev-libs/dbus-glib-0.100 )
+	exif? ( >=media-libs/libexif-0.6.19 )
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	pcre? ( >=dev-libs/libpcre-6 )
+	startup-notification? ( x11-libs/startup-notification )
+	udisks? ( virtual/libgudev:= )
+	xfce_plugins_trash? ( >=xfce-base/xfce4-panel-4.10 )"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-util/desktop-file-utils-0.20-r1
+	x11-misc/shared-mime-info
+	dbus? ( ${GVFS_DEPEND} )
+	udisks? (
+		virtual/udev
+		${GVFS_DEPEND}[udisks,udev]
+		)
+	xfce_plugins_trash? ( ${GVFS_DEPEND} )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+REQUIRED_USE="xfce_plugins_trash? ( dbus )"
+
+S=${WORKDIR}/${MY_P}
+
+pkg_setup() {
+	XFCONF=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable dbus)
+		$(use_enable startup-notification)
+		$(use_enable udisks gudev)
+		$(use_enable libnotify notifications)
+		$(xfconf_use_debug)
+		$(use_enable exif)
+		$(use_enable pcre)
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
+		)
+
+	use xfce_plugins_trash || XFCONF+=( --disable-tpa-plugin )
+
+	DOCS=( AUTHORS ChangeLog FAQ HACKING NEWS README THANKS TODO )
+}
+
+src_test() {
+	Xemake check
+}
diff --git a/xfce-base/xfce4-appfinder/ChangeLog b/xfce-base/xfce4-appfinder/ChangeLog
index f2107dbcb3d0..cdd25d69aa8e 100644
--- a/xfce-base/xfce4-appfinder/ChangeLog
+++ b/xfce-base/xfce4-appfinder/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for xfce-base/xfce4-appfinder
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-appfinder/ChangeLog,v 1.40 2015/03/03 13:06:12 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-appfinder/ChangeLog,v 1.41 2015/03/08 15:06:39 mgorny Exp $
+
+*xfce4-appfinder-4.12.0 (08 Mar 2015)
+
+  08 Mar 2015; Michał Górny <mgorny@gentoo.org> +xfce4-appfinder-4.12.0.ebuild:
+  Xfce 4.12 version bump, bug #541962. https://github.com/gentoo/gentoo-portage-
+  rsync-mirror/pull/63 by me and damex.
 
   03 Mar 2015; Yixun Lan <dlan@gentoo.org> xfce4-appfinder-4.11.0.ebuild:
   add arm64 support, tested on A53 board
diff --git a/xfce-base/xfce4-appfinder/xfce4-appfinder-4.12.0.ebuild b/xfce-base/xfce4-appfinder/xfce4-appfinder-4.12.0.ebuild
new file mode 100644
index 000000000000..62ff15211741
--- /dev/null
+++ b/xfce-base/xfce4-appfinder/xfce4-appfinder-4.12.0.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-appfinder/xfce4-appfinder-4.12.0.ebuild,v 1.1 2015/03/08 15:06:39 mgorny Exp $
+
+EAPI=5
+inherit xfconf
+
+DESCRIPTION="A tool to find and launch installed applications for the Xfce desktop environment"
+HOMEPAGE="http://www.xfce.org/projects/"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug"
+
+RDEPEND=">=dev-libs/dbus-glib-0.100
+	>=dev-libs/glib-2.30
+	>=x11-libs/gtk+-3.2:3
+	>=xfce-base/garcon-0.3
+	>=xfce-base/libxfce4util-4.11
+	>=xfce-base/libxfce4ui-4.11
+	>=xfce-base/xfconf-4.10
+	!xfce-base/xfce-utils"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+pkg_setup() {
+	XFCONF=(
+		--enable-gtk3
+		$(xfconf_use_debug)
+		)
+
+	DOCS=( AUTHORS ChangeLog NEWS )
+}
diff --git a/xfce-base/xfce4-meta/ChangeLog b/xfce-base/xfce4-meta/ChangeLog
index bc1978952106..19ce911de18a 100644
--- a/xfce-base/xfce4-meta/ChangeLog
+++ b/xfce-base/xfce4-meta/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for xfce-base/xfce4-meta
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-meta/ChangeLog,v 1.45 2015/03/03 13:07:25 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-meta/ChangeLog,v 1.46 2015/03/08 15:06:39 mgorny Exp $
+
+*xfce4-meta-4.12 (08 Mar 2015)
+
+  08 Mar 2015; Michał Górny <mgorny@gentoo.org> +xfce4-meta-4.12.ebuild:
+  Xfce 4.12 version bump, bug #541962. https://github.com/gentoo/gentoo-portage-
+  rsync-mirror/pull/63 by me and damex.
 
   03 Mar 2015; Yixun Lan <dlan@gentoo.org> xfce4-meta-4.10.ebuild:
   add arm64 support, tested on A53 board
@@ -156,4 +162,3 @@
   23 Aug 2009; Samuli Suominen <ssuominen@gentoo.org>
   +xfce4-meta-4.6.1.ebuild:
   Initial commit.
-
diff --git a/xfce-base/xfce4-meta/xfce4-meta-4.12.ebuild b/xfce-base/xfce4-meta/xfce4-meta-4.12.ebuild
new file mode 100644
index 000000000000..87a9e9599167
--- /dev/null
+++ b/xfce-base/xfce4-meta/xfce4-meta-4.12.ebuild
@@ -0,0 +1,28 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-meta/xfce4-meta-4.12.ebuild,v 1.1 2015/03/08 15:06:39 mgorny Exp $
+
+EAPI=5
+
+DESCRIPTION="The Xfce Desktop Environment (meta package)"
+HOMEPAGE="http://www.xfce.org/"
+SRC_URI=""
+
+LICENSE="metapackage"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux"
+IUSE="minimal +svg"
+
+RDEPEND=">=x11-themes/gtk-engines-xfce-3:0
+	x11-themes/hicolor-icon-theme
+	>=xfce-base/xfce4-appfinder-4.12
+	>=xfce-base/xfce4-panel-4.12
+	>=xfce-base/xfce4-session-4.12
+	>=xfce-base/xfce4-settings-4.12
+	>=xfce-base/xfdesktop-4.12
+	>=xfce-base/xfwm4-4.12
+	!minimal? (
+		media-fonts/dejavu
+		virtual/freedesktop-icon-theme
+		)
+	svg? ( gnome-base/librsvg )"
diff --git a/xfce-base/xfce4-panel/ChangeLog b/xfce-base/xfce4-panel/ChangeLog
index 075bf9766f63..b7053c6ef87a 100644
--- a/xfce-base/xfce4-panel/ChangeLog
+++ b/xfce-base/xfce4-panel/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for xfce-base/xfce4-panel
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-panel/ChangeLog,v 1.254 2015/03/03 13:08:47 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-panel/ChangeLog,v 1.255 2015/03/08 15:06:38 mgorny Exp $
+
+*xfce4-panel-4.12.0 (08 Mar 2015)
+
+  08 Mar 2015; Michał Górny <mgorny@gentoo.org> +xfce4-panel-4.12.0.ebuild:
+  Xfce 4.12 version bump, bug #541962. https://github.com/gentoo/gentoo-portage-
+  rsync-mirror/pull/63 by me and damex.
 
   03 Mar 2015; Yixun Lan <dlan@gentoo.org> xfce4-panel-4.11.1.ebuild:
   add arm64 support, tested on A53 board
diff --git a/xfce-base/xfce4-panel/xfce4-panel-4.12.0.ebuild b/xfce-base/xfce4-panel/xfce4-panel-4.12.0.ebuild
new file mode 100644
index 000000000000..cb5d5504aaa5
--- /dev/null
+++ b/xfce-base/xfce4-panel/xfce4-panel-4.12.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-panel/xfce4-panel-4.12.0.ebuild,v 1.1 2015/03/08 15:06:38 mgorny Exp $
+
+EAPI=5
+inherit xfconf
+
+DESCRIPTION="Panel for the Xfce desktop environment"
+HOMEPAGE="http://www.xfce.org/projects/"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug"
+
+RDEPEND=">=dev-libs/dbus-glib-0.100
+	>=dev-libs/glib-2.24
+	>=x11-libs/cairo-1
+	>=x11-libs/gtk+-2.20:2
+	>=x11-libs/gtk+-3.2:3
+	x11-libs/libX11
+	>=x11-libs/libwnck-2.31:1
+	>=xfce-base/exo-0.8
+	>=xfce-base/garcon-0.3
+	>=xfce-base/libxfce4ui-4.11
+	>=xfce-base/libxfce4util-4.11
+	>=xfce-base/xfconf-4.10"
+DEPEND="${RDEPEND}
+	dev-lang/perl
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+pkg_setup() {
+	XFCONF=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		--enable-gtk3
+		$(xfconf_use_debug)
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
+		)
+
+	DOCS=( AUTHORS ChangeLog NEWS THANKS )
+}
diff --git a/xfce-base/xfce4-session/ChangeLog b/xfce-base/xfce4-session/ChangeLog
index 2bfe93c1cfd3..426278b3e0f8 100644
--- a/xfce-base/xfce4-session/ChangeLog
+++ b/xfce-base/xfce4-session/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for xfce-base/xfce4-session
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/ChangeLog,v 1.226 2015/03/03 13:10:17 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/ChangeLog,v 1.227 2015/03/08 15:06:39 mgorny Exp $
+
+*xfce4-session-4.12.0 (08 Mar 2015)
+
+  08 Mar 2015; Michał Górny <mgorny@gentoo.org> +xfce4-session-4.12.0.ebuild,
+  metadata.xml:
+  Xfce 4.12 version bump, bug #541962. https://github.com/gentoo/gentoo-portage-
+  rsync-mirror/pull/63 by me and damex.
 
   03 Mar 2015; Yixun Lan <dlan@gentoo.org> xfce4-session-4.11.0-r2.ebuild:
   add arm64 support, tested on A53 board
diff --git a/xfce-base/xfce4-session/xfce4-session-4.12.0.ebuild b/xfce-base/xfce4-session/xfce4-session-4.12.0.ebuild
new file mode 100644
index 000000000000..9b416ad1eda2
--- /dev/null
+++ b/xfce-base/xfce4-session/xfce4-session-4.12.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/xfce4-session-4.12.0.ebuild,v 1.1 2015/03/08 15:06:39 mgorny Exp $
+
+EAPI=5
+EAUTORECONF=1
+inherit xfconf
+
+DESCRIPTION="A session manager for the Xfce desktop environment"
+HOMEPAGE="http://docs.xfce.org/xfce/xfce4-session/start"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug nls policykit systemd upower +xscreensaver"
+
+COMMON_DEPEND=">=dev-libs/dbus-glib-0.100
+	x11-apps/iceauth
+	x11-libs/libSM
+	>=x11-libs/libwnck-2.30:1
+	x11-libs/libX11
+	>=xfce-base/libxfce4util-4.11
+	>=xfce-base/libxfce4ui-4.11
+	>=xfce-base/xfconf-4.10
+	!xfce-base/xfce-utils
+	policykit? ( >=sys-auth/polkit-0.102 )
+	upower? ( || ( >=sys-power/upower-0.9.23 sys-power/upower-pm-utils ) )"
+RDEPEND="${COMMON_DEPEND}
+	x11-apps/xrdb
+	nls? ( x11-misc/xdg-user-dirs )
+	!systemd? ( upower? ( sys-power/pm-utils ) )
+	xscreensaver? ( || (
+		>=x11-misc/xscreensaver-5.26
+		gnome-extra/gnome-screensaver
+		>=x11-misc/xlockmore-5.43
+		x11-misc/slock
+		x11-misc/alock[pam]
+		) )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+REQUIRED_USE="systemd? ( policykit )"
+
+pkg_setup() {
+	PATCHES=( "${FILESDIR}"/${PN}-4.10.1-alock_support_to_xflock4.patch )
+
+	XFCONF=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable policykit polkit)
+		--with-xsession-prefix="${EPREFIX}"/usr
+		$(xfconf_use_debug)
+		)
+
+	use upower && XFCONF+=( --enable-upower )
+
+	DOCS=( AUTHORS BUGS ChangeLog NEWS README TODO )
+}
+
+src_install() {
+	xfconf_src_install
+
+	local sessiondir=/etc/X11/Sessions
+	echo startxfce4 > "${T}"/Xfce4
+	exeinto ${sessiondir}
+	doexe "${T}"/Xfce4
+	dosym Xfce4 ${sessiondir}/Xfce
+}
diff --git a/xfce-base/xfce4-settings/ChangeLog b/xfce-base/xfce4-settings/ChangeLog
index 0d31f5458521..a94315cf83c6 100644
--- a/xfce-base/xfce4-settings/ChangeLog
+++ b/xfce-base/xfce4-settings/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for xfce-base/xfce4-settings
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-settings/ChangeLog,v 1.126 2015/03/03 13:11:45 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-settings/ChangeLog,v 1.127 2015/03/08 15:06:38 mgorny Exp $
+
+*xfce4-settings-4.12.0 (08 Mar 2015)
+
+  08 Mar 2015; Michał Górny <mgorny@gentoo.org> +xfce4-settings-4.12.0.ebuild,
+  metadata.xml:
+  Xfce 4.12 version bump, bug #541962. https://github.com/gentoo/gentoo-portage-
+  rsync-mirror/pull/63 by me and damex.
 
   03 Mar 2015; Yixun Lan <dlan@gentoo.org> xfce4-settings-4.11.3.ebuild:
   add arm64 support, tested on A53 board
diff --git a/xfce-base/xfce4-settings/metadata.xml b/xfce-base/xfce4-settings/metadata.xml
index a80a93222213..9c387c24f73e 100644
--- a/xfce-base/xfce4-settings/metadata.xml
+++ b/xfce-base/xfce4-settings/metadata.xml
@@ -3,6 +3,7 @@
 <pkgmetadata>
   <herd>xfce</herd>
   <use>
+    <flag name='libinput'>Enable libinput Xorg driver (<pkg>x11-drivers/xf86-input-libinput</pkg>) support</flag>
     <flag name='libcanberra'>Enable sound event support using <pkg>media-libs/libcanberra</pkg></flag>
     <flag name='xklavier'>Enable keyboard layout selection support using <pkg>x11-libs/libxklavier</pkg></flag>
   </use>
diff --git a/xfce-base/xfce4-settings/xfce4-settings-4.12.0.ebuild b/xfce-base/xfce4-settings/xfce4-settings-4.12.0.ebuild
new file mode 100644
index 000000000000..82f9b2ebf3cd
--- /dev/null
+++ b/xfce-base/xfce4-settings/xfce4-settings-4.12.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-settings/xfce4-settings-4.12.0.ebuild,v 1.1 2015/03/08 15:06:38 mgorny Exp $
+
+EAPI=5
+inherit xfconf
+
+DESCRIPTION="Configuration system for the Xfce desktop environment"
+HOMEPAGE="http://www.xfce.org/projects/"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux"
+IUSE="debug libcanberra libinput libnotify upower +xklavier"
+
+RDEPEND=">=dev-libs/dbus-glib-0.100
+	>=dev-libs/glib-2.24
+	media-libs/fontconfig
+	>=x11-libs/gtk+-2.20:2
+	x11-libs/libX11
+	>=x11-libs/libXcursor-1.1
+	>=x11-libs/libXi-1.3
+	>=x11-libs/libXrandr-1.2
+	>=xfce-base/garcon-0.2
+	>=xfce-base/exo-0.8
+	>=xfce-base/libxfce4ui-4.11
+	>=xfce-base/libxfce4util-4.11
+	>=xfce-base/xfconf-4.10
+	libcanberra? ( >=media-libs/libcanberra-0.25[sound] )
+	libinput? ( x11-drivers/xf86-input-libinput )
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	upower? ( || ( >=sys-power/upower-0.9.23 sys-power/upower-pm-utils ) )
+	xklavier? ( >=x11-libs/libxklavier-5 )"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	virtual/pkgconfig
+	sys-devel/gettext
+	>=x11-proto/inputproto-1.4
+	x11-proto/xproto"
+
+pkg_setup() {
+	XFCONF=(
+		$(use_enable upower upower-glib)
+		$(use_enable libinput xorg-libinput)
+		$(use_enable libnotify)
+		$(use_enable xklavier libxklavier)
+		$(use_enable libcanberra sound-settings)
+		$(xfconf_use_debug)
+		)
+
+	DOCS=( AUTHORS ChangeLog NEWS TODO )
+}
diff --git a/xfce-base/xfconf/ChangeLog b/xfce-base/xfconf/ChangeLog
index 8cb2014e5468..ab493d5254a9 100644
--- a/xfce-base/xfconf/ChangeLog
+++ b/xfce-base/xfconf/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for xfce-base/xfconf
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfconf/ChangeLog,v 1.77 2015/03/03 13:13:04 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfconf/ChangeLog,v 1.78 2015/03/08 15:06:39 mgorny Exp $
+
+*xfconf-4.12.0 (08 Mar 2015)
+
+  08 Mar 2015; Michał Górny <mgorny@gentoo.org> +xfconf-4.12.0.ebuild:
+  Xfce 4.12 version bump, bug #541962. https://github.com/gentoo/gentoo-portage-
+  rsync-mirror/pull/63 by me and damex.
 
   03 Mar 2015; Yixun Lan <dlan@gentoo.org> xfconf-4.10.0.ebuild:
   add arm64 support, tested on A53 board
@@ -261,4 +267,3 @@
   10 Mar 2009; Christoph Mende <angelos@gentoo.org> +metadata.xml,
   +xfconf-4.6.0.ebuild:
   Xfce-4.6 bump
-
diff --git a/xfce-base/xfconf/xfconf-4.12.0.ebuild b/xfce-base/xfconf/xfconf-4.12.0.ebuild
new file mode 100644
index 000000000000..8f2fb3b95145
--- /dev/null
+++ b/xfce-base/xfconf/xfconf-4.12.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfconf/xfconf-4.12.0.ebuild,v 1.1 2015/03/08 15:06:39 mgorny Exp $
+
+EAPI=5
+inherit xfconf
+
+DESCRIPTION="A simple client-server configuration storage and query system for the Xfce desktop environment"
+HOMEPAGE="http://www.xfce.org/projects/"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~x64-solaris"
+IUSE="debug perl"
+
+RDEPEND=">=dev-libs/dbus-glib-0.98
+	>=dev-libs/glib-2.30
+	>=xfce-base/libxfce4util-4.10
+	perl? ( dev-perl/glib-perl )"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	virtual/pkgconfig
+	sys-devel/gettext
+	perl? (
+		dev-perl/extutils-depends
+		dev-perl/extutils-pkgconfig
+		)"
+
+pkg_setup() {
+	XFCONF=(
+		$(use_enable perl perl-bindings)
+		$(xfconf_use_debug)
+		$(use_enable debug checks)
+		--with-perl-options=INSTALLDIRS=vendor
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
+		)
+
+	[[ ${CHOST} == *-darwin* ]] && XFCONF+=( --disable-visibility ) #366857
+
+	DOCS=( AUTHORS ChangeLog NEWS TODO )
+}
+
+src_prepare() {
+	# http://bugzilla.xfce.org/show_bug.cgi?id=9556
+	cat <<-EOF >> po/POTFILES.skip
+	xfconf-perl/xs/Xfconf.c
+	xfconf-perl/xs/XfconfBinding.c
+	xfconf-perl/xs/XfconfChannel.c
+	EOF
+	xfconf_src_prepare
+}
+
+src_compile() {
+	emake OTHERLDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	xfconf_src_install
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
+	fi
+}
diff --git a/xfce-base/xfdesktop/ChangeLog b/xfce-base/xfdesktop/ChangeLog
index cb02da59813e..0af06d1ba4a0 100644
--- a/xfce-base/xfdesktop/ChangeLog
+++ b/xfce-base/xfdesktop/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for xfce-base/xfdesktop
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfdesktop/ChangeLog,v 1.251 2015/03/03 13:14:24 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfdesktop/ChangeLog,v 1.252 2015/03/08 15:06:39 mgorny Exp $
+
+*xfdesktop-4.12.0 (08 Mar 2015)
+
+  08 Mar 2015; Michał Górny <mgorny@gentoo.org> +xfdesktop-4.12.0.ebuild:
+  Xfce 4.12 version bump, bug #541962. https://github.com/gentoo/gentoo-portage-
+  rsync-mirror/pull/63 by me and damex.
 
   03 Mar 2015; Yixun Lan <dlan@gentoo.org> xfdesktop-4.11.8.ebuild:
   add arm64 support, tested on A53 board
diff --git a/xfce-base/xfdesktop/xfdesktop-4.12.0.ebuild b/xfce-base/xfdesktop/xfdesktop-4.12.0.ebuild
new file mode 100644
index 000000000000..cf15c3d7c1d2
--- /dev/null
+++ b/xfce-base/xfdesktop/xfdesktop-4.12.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfdesktop/xfdesktop-4.12.0.ebuild,v 1.1 2015/03/08 15:06:39 mgorny Exp $
+
+EAPI=5
+inherit xfconf
+
+DESCRIPTION="Desktop manager for the Xfce desktop environment"
+HOMEPAGE="http://www.xfce.org/projects/"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug libnotify +thunar"
+
+# src/xfdesktop-file-utils.c:#if GLIB_CHECK_VERSION (2, 38, 0)
+RDEPEND=">=x11-libs/cairo-1.6
+	>=dev-libs/dbus-glib-0.100
+	>=dev-libs/glib-2.20
+	>=x11-libs/gtk+-2.24:2
+	x11-libs/libSM
+	>=x11-libs/libwnck-2.30:1
+	x11-libs/libX11
+	>=xfce-base/exo-0.8
+	>=xfce-base/garcon-0.3
+	>=xfce-base/libxfce4ui-4.11
+	>=xfce-base/libxfce4util-4.11
+	>=xfce-base/xfconf-4.10
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	thunar? (
+		>=dev-libs/glib-2.38
+		>=xfce-base/thunar-1.6[dbus]
+		)"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+pkg_setup() {
+	XFCONF=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable thunar file-icons)
+		$(use_enable thunar thunarx)
+		$(use_enable libnotify notifications)
+		$(xfconf_use_debug)
+		)
+
+	DOCS=( AUTHORS ChangeLog NEWS README TODO )
+}
diff --git a/xfce-base/xfwm4/ChangeLog b/xfce-base/xfwm4/ChangeLog
index f1c0fa05d310..dcc6f8c7451f 100644
--- a/xfce-base/xfwm4/ChangeLog
+++ b/xfce-base/xfwm4/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for xfce-base/xfwm4
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfwm4/ChangeLog,v 1.229 2015/03/03 13:15:50 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfwm4/ChangeLog,v 1.230 2015/03/08 15:06:39 mgorny Exp $
+
+*xfwm4-4.12.0 (08 Mar 2015)
+
+  08 Mar 2015; Michał Górny <mgorny@gentoo.org> +xfwm4-4.12.0.ebuild:
+  Xfce 4.12 version bump, bug #541962. https://github.com/gentoo/gentoo-portage-
+  rsync-mirror/pull/63 by me and damex.
 
   03 Mar 2015; Yixun Lan <dlan@gentoo.org> xfwm4-4.11.2.ebuild:
   add arm64 support, tested on A53 board
diff --git a/xfce-base/xfwm4/xfwm4-4.12.0.ebuild b/xfce-base/xfwm4/xfwm4-4.12.0.ebuild
new file mode 100644
index 000000000000..67e7e069a3c7
--- /dev/null
+++ b/xfce-base/xfwm4/xfwm4-4.12.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfwm4/xfwm4-4.12.0.ebuild,v 1.1 2015/03/08 15:06:39 mgorny Exp $
+
+EAPI=5
+inherit xfconf
+
+DESCRIPTION="Window manager for the Xfce desktop environment"
+HOMEPAGE="http://www.xfce.org/projects/"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug dri startup-notification +xcomposite"
+
+RDEPEND=">=dev-libs/glib-2.20
+	>=x11-libs/gtk+-2.24:2
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/pango
+	>=x11-libs/libwnck-2.30:1
+	>=xfce-base/libxfce4util-4.10
+	>=xfce-base/libxfce4ui-4.10
+	>=xfce-base/xfconf-4.10
+	dri? ( >=x11-libs/libdrm-2.4 )
+	startup-notification? ( x11-libs/startup-notification )
+	xcomposite? (
+		x11-libs/libXcomposite
+		x11-libs/libXdamage
+		x11-libs/libXfixes
+		)"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+pkg_setup() {
+	XFCONF=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable dri libdrm)
+		$(use_enable startup-notification)
+		--enable-xsync
+		--enable-render
+		--enable-randr
+		$(use_enable xcomposite compositor)
+		$(xfconf_use_debug)
+		)
+
+	DOCS=( AUTHORS ChangeLog COMPOSITOR NEWS README TODO )
+}