Version bump.

(Portage version: 2.2.0_alpha185/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

3 files changed, 66 insertions, 3 deletions

diff --git a/x11-wm/herbstluftwm/ChangeLog b/x11-wm/herbstluftwm/ChangeLog
index 0d77fd51eebf..7af408bab8db 100644
--- a/x11-wm/herbstluftwm/ChangeLog
+++ b/x11-wm/herbstluftwm/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for x11-wm/herbstluftwm
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/herbstluftwm/ChangeLog,v 1.10 2013/01/06 05:33:27 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/herbstluftwm/ChangeLog,v 1.11 2013/06/28 22:04:48 radhermit Exp $
+
+*herbstluftwm-0.5.2 (28 Jun 2013)
+
+  28 Jun 2013; Tim Harder <radhermit@gentoo.org> +herbstluftwm-0.5.2.ebuild,
+  herbstluftwm-9999.ebuild:
+  Version bump.
 
 *herbstluftwm-0.5.1 (06 Jan 2013)
 
diff --git a/x11-wm/herbstluftwm/herbstluftwm-0.5.2.ebuild b/x11-wm/herbstluftwm/herbstluftwm-0.5.2.ebuild
new file mode 100644
index 000000000000..02c739e36775
--- /dev/null
+++ b/x11-wm/herbstluftwm/herbstluftwm-0.5.2.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/herbstluftwm/herbstluftwm-0.5.2.ebuild,v 1.1 2013/06/28 22:04:48 radhermit Exp $
+
+EAPI=5
+
+inherit toolchain-funcs bash-completion-r1
+
+DESCRIPTION="A manual tiling window manager for X"
+HOMEPAGE="http://wwwcip.cs.fau.de/~re06huxa/herbstluftwm/"
+SRC_URI="http://wwwcip.cs.fau.de/~re06huxa/${PN}/tarballs/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples xinerama zsh-completion"
+
+CDEPEND=">=dev-libs/glib-2.24:2
+	x11-libs/libX11
+	xinerama? ( x11-libs/libXinerama )"
+RDEPEND="${CDEPEND}
+	app-shells/bash
+	zsh-completion? ( app-shells/zsh )"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig"
+
+src_compile() {
+	emake CC="$(tc-getCC)" LD="$(tc-getCC)" COLOR=0 VERBOSE= \
+		$(use xinerama || echo XINERAMAFLAGS= XINERAMALIBS= )
+}
+
+src_install() {
+	dobin herbstluftwm herbstclient
+	dodoc BUGS MIGRATION NEWS README
+
+	doman doc/{herbstluftwm,herbstclient}.1
+
+	exeinto /etc/xdg/herbstluftwm
+	doexe share/{autostart,panel.sh,restartpanels.sh}
+
+	insinto /usr/share/xsessions
+	doins share/herbstluftwm.desktop
+
+	newbashcomp share/herbstclient-completion herbstclient
+
+	if use zsh-completion ; then
+		insinto /usr/share/zsh/site-functions
+		doins share/_herbstclient
+	fi
+
+	if use examples ; then
+		exeinto /usr/share/doc/${PF}/examples
+		doexe scripts/*.sh
+		docinto examples
+		dodoc scripts/README
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
diff --git a/x11-wm/herbstluftwm/herbstluftwm-9999.ebuild b/x11-wm/herbstluftwm/herbstluftwm-9999.ebuild
index 49cd3292f361..2688448d6156 100644
--- a/x11-wm/herbstluftwm/herbstluftwm-9999.ebuild
+++ b/x11-wm/herbstluftwm/herbstluftwm-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/herbstluftwm/herbstluftwm-9999.ebuild,v 1.6 2013/01/02 03:13:42 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/herbstluftwm/herbstluftwm-9999.ebuild,v 1.7 2013/06/28 22:04:48 radhermit Exp $
 
 EAPI=5
 
@@ -14,7 +14,6 @@ SRC_URI=""
 
 LICENSE="BSD-2"
 SLOT="0"
-KEYWORDS=""
 IUSE="examples xinerama zsh-completion"
 
 CDEPEND=">=dev-libs/glib-2.24:2