Add more runtime dependencies. Respect CC. Make sed script more robust and less cryptic, run sed just once. Use do* instead of einstall.

(Portage version: 2.2.0_alpha101/cvs/Linux x86_64)

2 files changed, 28 insertions, 17 deletions

diff --git a/x11-misc/trayer/ChangeLog b/x11-misc/trayer/ChangeLog
index 13eb9f47a300..3c31b4555c6b 100644
--- a/x11-misc/trayer/ChangeLog
+++ b/x11-misc/trayer/ChangeLog
@@ -1,6 +1,10 @@
 # ChangeLog for x11-misc/trayer
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/trayer/ChangeLog,v 1.18 2011/03/28 14:34:48 nirbheek Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/trayer/ChangeLog,v 1.19 2012/05/01 20:55:58 jer Exp $
+
+  01 May 2012; Jeroen Roovers <jer@gentoo.org> trayer-1.0-r1.ebuild:
+  Add more runtime dependencies. Respect CC. Make sed script more robust and
+  less cryptic, run sed just once. Use do* instead of einstall.
 
   28 Mar 2011; Nirbheek Chauhan <nirbheek@gentoo.org> trayer-1.0.ebuild,
   trayer-1.0-r1.ebuild:
diff --git a/x11-misc/trayer/trayer-1.0-r1.ebuild b/x11-misc/trayer/trayer-1.0-r1.ebuild
index f70efe11d3c9..c7010d14b0b3 100644
--- a/x11-misc/trayer/trayer-1.0-r1.ebuild
+++ b/x11-misc/trayer/trayer-1.0-r1.ebuild
@@ -1,8 +1,9 @@
-# Copyright 1999-2011 Gentoo Foundation
+# Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/trayer/trayer-1.0-r1.ebuild,v 1.2 2011/03/28 14:34:48 nirbheek Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/trayer/trayer-1.0-r1.ebuild,v 1.3 2012/05/01 20:55:58 jer Exp $
 
-EAPI="1"
+EAPI=4
+inherit toolchain-funcs
 
 DESCRIPTION="Lightweight GTK+ based systray for UNIX desktop"
 HOMEPAGE="http://fvwm-crystal.org"
@@ -11,26 +12,32 @@ LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
 IUSE=""
-RDEPEND="x11-libs/gtk+:2"
-DEPEND="${RDEPEND}
-	dev-util/pkgconfig"
-
-src_unpack() {
-	unpack ${A}
-	cd "${S}"
+RDEPEND="
+	dev-libs/glib:2
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:2
+	x11-libs/libX11
+"
+DEPEND="
+	${RDEPEND}
+	dev-util/pkgconfig
+"
 
+src_prepare() {
 	# fix for as-needed, bug #141707
-	sed -i Makefile \
-		-e 's/$(LIBS) $(OBJ) $(SYSTRAYOBJ)/$(OBJ) $(SYSTRAYOBJ) $(LIBS)/'
 	# fix pre-stripped files, bug #252098
-	sed -i "40,+3d" Makefile || die "failed to fix Makefile"
+	sed -i Makefile \
+		-e 's:$(LIBS) $(OBJ) $(SYSTRAYOBJ):$(OBJ) $(SYSTRAYOBJ) $(LIBS):' \
+		-e 's:strip:true:g' \
+		|| die
 }
 
 src_compile() {
-	emake -j1 CFLAGS="${CFLAGS}" || die "emake failed"
+	emake -j1 CC=$(tc-getCC) CFLAGS="${CFLAGS}"
 }
 
 src_install() {
-	einstall PREFIX="${D}"/usr || die "einstall failed"
+	dobin trayer
+	doman trayer.1
 	dodoc CHANGELOG CREDITS README
 }