Version bump

(Portage version: 2.2_rc67/cvs/Linux x86_64)

2 files changed, 72 insertions, 1 deletions

diff --git a/x11-libs/qscintilla/ChangeLog b/x11-libs/qscintilla/ChangeLog
index 0e4a68145d88..2d7852ad6116 100644
--- a/x11-libs/qscintilla/ChangeLog
+++ b/x11-libs/qscintilla/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for x11-libs/qscintilla
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/ChangeLog,v 1.47 2010/07/05 14:02:21 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/ChangeLog,v 1.48 2010/07/13 08:11:54 hwoarang Exp $
+
+*qscintilla-2.4.4 (13 Jul 2010)
+
+  13 Jul 2010; Markos Chandras <hwoarang@gentoo.org>
+  +qscintilla-2.4.4.ebuild:
+  Version bump
 
   05 Jul 2010; Samuli Suominen <ssuominen@gentoo.org>
   qscintilla-2.4.3.ebuild:
diff --git a/x11-libs/qscintilla/qscintilla-2.4.4.ebuild b/x11-libs/qscintilla/qscintilla-2.4.4.ebuild
new file mode 100644
index 000000000000..2820ab6cd7a2
--- /dev/null
+++ b/x11-libs/qscintilla/qscintilla-2.4.4.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/qscintilla-2.4.4.ebuild,v 1.1 2010/07/13 08:11:54 hwoarang Exp $
+
+EAPI="2"
+
+inherit qt4-r2
+
+MY_P="QScintilla-gpl-${PV/_pre/-snapshot-}"
+
+DESCRIPTION="A Qt port of Neil Hodgson's Scintilla C++ editor class"
+HOMEPAGE="http://www.riverbankcomputing.co.uk/software/qscintilla/intro"
+SRC_URI="http://www.riverbankcomputing.co.uk/static/Downloads/QScintilla2/${MY_P}.tar.gz"
+
+LICENSE="|| ( GPL-2 GPL-3 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="doc python"
+
+DEPEND="x11-libs/qt-gui:4"
+RDEPEND="${DEPEND}"
+PDEPEND="python? ( ~dev-python/qscintilla-python-${PV} )"
+
+S=${WORKDIR}/${MY_P}
+
+PATCHES=( "${FILESDIR}/${PN}-2.4-designer.patch" )
+
+src_configure() {
+	cd "${S}"/Qt4
+	einfo "Configuring qscintilla"
+	eqmake4 qscintilla.pro
+
+	cd "${S}"/designer-Qt4
+	einfo "Configuring designer plugin"
+	eqmake4 designer.pro
+}
+
+src_compile() {
+	cd "${S}"/Qt4
+	einfo "Building qscintilla"
+	emake || die "failed to build qscintilla"
+
+	cd "${S}"/designer-Qt4
+	einfo "Building designer plugin"
+	emake || die "failed to build designer plugin"
+}
+
+src_install() {
+	cd "${S}"/Qt4
+	einfo "Installing qscintilla"
+	emake INSTALL_ROOT="${D}" install || die "failed to install qscintilla"
+
+	cd "${S}"/designer-Qt4
+	einfo "Installing designer plugin"
+	emake INSTALL_ROOT="${D}" install || die "failed to install designer plugin"
+
+	cd "${S}"
+	dodoc NEWS
+	if use doc; then
+		einfo "Installing documentation"
+		dohtml doc/html-Qt4/* || die
+		insinto /usr/share/doc/${PF}/Scintilla
+		doins doc/Scintilla/* || die
+	fi
+}