Version bump www-apps/trac to 0.12.

(Portage version: 2.1.8.3/cvs/Linux x86_64)

3 files changed, 133 insertions, 1 deletions

diff --git a/www-apps/trac/ChangeLog b/www-apps/trac/ChangeLog
index c5b10edbfb24..275cb9cde5ff 100644
--- a/www-apps/trac/ChangeLog
+++ b/www-apps/trac/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for www-apps/trac
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/trac/ChangeLog,v 1.102 2010/05/28 14:47:02 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-apps/trac/ChangeLog,v 1.103 2010/06/14 08:45:31 djc Exp $
+
+*trac-0.12 (14 Jun 2010)
+
+  14 Jun 2010; Dirkjan Ochtman <djc@gentoo.org> +trac-0.12.ebuild,
+  metadata.xml:
+  Version bump to 0.12.
 
   28 May 2010; Arfrever Frehtes Taifersar Arahesis <arfrever@gentoo.org>
   trac-0.11.7.ebuild:
diff --git a/www-apps/trac/metadata.xml b/www-apps/trac/metadata.xml
index a256f32b1335..9b6a5c4efe9f 100644
--- a/www-apps/trac/metadata.xml
+++ b/www-apps/trac/metadata.xml
@@ -6,4 +6,7 @@
     <email>djc@gentoo.org</email>
     <name>Dirkjan Ochtman</name>
   </maintainer>
+  <use>
+    <flag name="i18n">Enable support for i18n with dev-python/Babel</flag>
+  </use>
 </pkgmetadata>
diff --git a/www-apps/trac/trac-0.12.ebuild b/www-apps/trac/trac-0.12.ebuild
new file mode 100644
index 000000000000..87797fc11ff7
--- /dev/null
+++ b/www-apps/trac/trac-0.12.ebuild
@@ -0,0 +1,123 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-apps/trac/trac-0.12.ebuild,v 1.1 2010/06/14 08:45:31 djc Exp $
+
+EAPI="2"
+PYTHON_DEPEND="2"
+SUPPORT_PYTHON_ABIS="1"
+
+inherit distutils eutils webapp
+
+MY_PV=${PV/_beta/b}
+MY_P=Trac-${MY_PV}
+S=${WORKDIR}/${MY_P}
+
+DESCRIPTION="Trac is a minimalistic web-based project management, wiki and bug/issue tracking system."
+HOMEPAGE="http://trac.edgewall.com/"
+LICENSE="BSD"
+SRC_URI="http://ftp.edgewall.com/pub/trac/${MY_P}.tar.gz"
+
+IUSE="cgi fastcgi i18n mysql postgres +sqlite subversion"
+
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+
+# doing so because tools, python packages... overlap
+SLOT="0"
+WEBAPP_MANUAL_SLOT="yes"
+
+RDEPEND="
+	dev-python/setuptools
+	>=dev-python/docutils-0.3.9
+	dev-python/flup
+	>=dev-python/genshi-0.5
+	dev-python/pygments
+	dev-python/pytz
+	i18n? ( >=dev-python/Babel-0.9.5 )
+	cgi? ( virtual/httpd-cgi )
+	fastcgi? ( virtual/httpd-fastcgi )
+	mysql? (
+		>=dev-python/mysql-python-1.2.1
+		>=virtual/mysql-4.1
+	)
+	postgres? ( >=dev-python/psycopg-2 )
+	sqlite? (
+		>=dev-db/sqlite-3.3.4
+		|| (
+			>=dev-lang/python-2.5[sqlite]
+			>=dev-python/pysqlite-2.3.2
+		)
+	)
+	subversion? ( >=dev-util/subversion-1.4.2[python] )
+	!www-apps/trac-webadmin
+	"
+DEPEND="${RDEPEND}"
+RESTRICT_PYTHON_ABIS="3.*"
+
+pkg_setup() {
+	python_pkg_setup
+	webapp_pkg_setup
+
+	if ! use mysql && ! use postgres && ! use sqlite; then
+		eerror "You must select at least one database backend, by enabling"
+		eerror "at least one of the 'mysql', 'postgres' or 'sqlite' USE flags."
+		die "no database backend selected"
+	fi
+
+	enewgroup tracd
+	enewuser tracd -1 -1 -1 tracd
+}
+
+src_test() {
+
+	testing() {
+		PYTHONPATH=. "$(PYTHON)" trac/test.py
+	}
+	python_execute_function testing
+
+	if use i18n; then
+		make check
+	fi
+
+}
+
+# the default src_compile just calls setup.py build
+# currently, this switches i18n catalog compilation based on presence of Babel
+
+src_install() {
+	webapp_src_preinst
+	distutils_src_install
+
+	# project environments might go in here
+	keepdir /var/lib/trac
+
+	# Use this as the egg-cache for tracd
+	dodir /var/lib/trac/egg-cache
+	keepdir /var/lib/trac/egg-cache
+	fowners tracd:tracd /var/lib/trac/egg-cache
+
+	# documentation
+	cp -r contrib "${D}"/usr/share/doc/${P}/
+
+	# tracd init script
+	newconfd "${FILESDIR}"/tracd.confd tracd
+	newinitd "${FILESDIR}"/tracd.initd tracd
+
+	if use cgi; then
+		cp cgi-bin/trac.cgi "${D}"/${MY_CGIBINDIR} || die
+	fi
+	if use fastcgi; then
+		cp cgi-bin/trac.fcgi "${D}"/${MY_CGIBINDIR} || die
+	fi
+
+	for lang in en; do
+		webapp_postinst_txt ${lang} "${FILESDIR}"/postinst-${lang}.txt
+		webapp_postupgrade_txt ${lang} "${FILESDIR}"/postupgrade-${lang}.txt
+	done
+
+	webapp_src_install
+}
+
+pkg_postinst() {
+	distutils_pkg_postinst
+	webapp_pkg_postinst
+}