Migrate to EAPI=4.

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

2 files changed, 52 insertions, 3 deletions

diff --git a/sys-libs/libnih/ChangeLog b/sys-libs/libnih/ChangeLog
index 15b1001f8136..45632a0570e5 100644
--- a/sys-libs/libnih/ChangeLog
+++ b/sys-libs/libnih/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-libs/libnih
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/libnih/ChangeLog,v 1.4 2012/05/24 05:13:29 vapier Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/libnih/ChangeLog,v 1.5 2014/10/30 18:45:56 vapier Exp $
+
+*libnih-1.0.3-r1 (30 Oct 2014)
+
+  30 Oct 2014; Mike Frysinger <vapier@gentoo.org> +libnih-1.0.3-r1.ebuild:
+  Migrate to EAPI=4.
 
   24 May 2012; Mike Frysinger <vapier@gentoo.org> libnih-1.0.3.ebuild:
   Inherit toolchain-funcs for gen_usr_ldscript.
@@ -18,4 +23,3 @@
   +files/libnih-1.0.3-pkg-config.patch, +metadata.xml:
   Initial ebuild merging the ChromeOS version, dev-zero, Bruno Tarquini, and my
   work #310093.
-
diff --git a/sys-libs/libnih/libnih-1.0.3-r1.ebuild b/sys-libs/libnih/libnih-1.0.3-r1.ebuild
new file mode 100644
index 000000000000..82c6975e6010
--- /dev/null
+++ b/sys-libs/libnih/libnih-1.0.3-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/libnih/libnih-1.0.3-r1.ebuild,v 1.1 2014/10/30 18:45:56 vapier Exp $
+
+EAPI="4"
+
+inherit versionator eutils autotools toolchain-funcs multilib
+
+DESCRIPTION="Light-weight 'standard library' of C functions"
+HOMEPAGE="https://launchpad.net/libnih"
+SRC_URI="http://launchpad.net/${PN}/$(get_version_component_range 1-2)/${PV}/+download/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="+dbus nls static-libs test +threads"
+
+RDEPEND="dbus? ( dev-libs/expat >=sys-apps/dbus-1.2.16 )"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? ( dev-util/valgrind )"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-1.0.3-optional-dbus.patch
+	epatch "${FILESDIR}"/${PN}-1.0.3-pkg-config.patch
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_with dbus) \
+		$(use_enable nls) \
+		$(use_enable static-libs static) \
+		$(use_enable threads) \
+		$(use_enable threads threading)
+}
+
+src_install() {
+	default
+
+	# we need to be in / because upstart needs libnih
+	gen_usr_ldscript -a nih $(use dbus && echo nih-dbus)
+	use static-libs || rm "${ED}"/usr/$(get_libdir)/*.la
+}