Version bump.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0x06B1F38DCA45A1EC!)

2 files changed, 84 insertions, 2 deletions

diff --git a/sys-auth/polkit-qt/ChangeLog b/sys-auth/polkit-qt/ChangeLog
index 62a957af6219..228733e52381 100644
--- a/sys-auth/polkit-qt/ChangeLog
+++ b/sys-auth/polkit-qt/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-auth/polkit-qt
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-auth/polkit-qt/ChangeLog,v 1.30 2013/08/01 06:04:43 kensington Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/polkit-qt/ChangeLog,v 1.31 2014/07/22 13:37:19 kensington Exp $
+
+*polkit-qt-0.112.0 (22 Jul 2014)
+
+  22 Jul 2014; Michael Palimaka <kensington@gentoo.org>
+  +polkit-qt-0.112.0.ebuild:
+  Version bump.
 
   01 Aug 2013; Michael Palimaka <kensington@gentoo.org>
   polkit-qt-0.103.0.ebuild:
diff --git a/sys-auth/polkit-qt/polkit-qt-0.112.0.ebuild b/sys-auth/polkit-qt/polkit-qt-0.112.0.ebuild
new file mode 100644
index 000000000000..3cc6773bdbac
--- /dev/null
+++ b/sys-auth/polkit-qt/polkit-qt-0.112.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/polkit-qt/polkit-qt-0.112.0.ebuild,v 1.1 2014/07/22 13:37:19 kensington Exp $
+
+EAPI=5
+
+MY_P="${P/qt/qt-1}"
+
+inherit cmake-utils multibuild
+
+DESCRIPTION="PolicyKit Qt4 API wrapper library."
+HOMEPAGE="http://www.kde.org/"
+SRC_URI="mirror://kde/stable/apps/KDE4.x/admin/${MY_P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="debug examples +qt4 qt5"
+
+REQUIRED_USE="|| ( qt4 qt5 )"
+
+RDEPEND="
+	dev-libs/glib:2
+	>=sys-auth/polkit-0.103
+	qt4? (
+		dev-qt/qtcore:4[glib]
+		dev-qt/qtdbus:4
+		dev-qt/qtgui:4[glib]
+	)
+	qt5? (
+		dev-qt/qtcore:5[glib]
+		dev-qt/qtdbus:5
+		dev-qt/qtgui:5[glib]
+		dev-qt/qtwidgets:5
+		examples? ( dev-qt/qtxml:5 )
+	)
+"
+DEPEND="${RDEPEND}"
+
+DOCS=( AUTHORS README README.porting TODO )
+
+S=${WORKDIR}/${MY_P}
+
+pkg_setup() {
+	MULTIBUILD_VARIANTS=()
+	use qt4 && MULTIBUILD_VARIANTS+=( qt4 )
+	use qt5 && MULTIBUILD_VARIANTS+=( qt5 )
+}
+
+src_configure() {
+	myconfigure() {
+		local mycmakeargs=(
+			-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+			$(cmake-utils_use_build examples)
+		)
+
+		if [[ ${MULTIBUILD_VARIANT} = qt4 ]] ; then
+			mycmakeargs+=( -DUSE_QT4=ON )
+		fi
+		if [[ ${MULTIBUILD_VARIANT} = qt5 ]] ; then
+			mycmakeargs+=( -DUSE_QT5=ON )
+		fi
+
+		cmake-utils_src_configure
+	}
+
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake-utils_src_compile
+}
+
+src_install() {
+	multibuild_foreach_variant cmake-utils_src_install
+}