Add 0.26.0_alpha7. Update epydoc dep.

(Portage version: 2.1.4)

8 files changed, 159 insertions, 11 deletions

diff --git a/sys-apps/paludis/ChangeLog b/sys-apps/paludis/ChangeLog
index feb99a7a686a..9d4ccfc430eb 100644
--- a/sys-apps/paludis/ChangeLog
+++ b/sys-apps/paludis/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for sys-apps/paludis
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/paludis/ChangeLog,v 1.80 2008/01/13 18:10:19 peper Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/paludis/ChangeLog,v 1.81 2008/01/18 13:52:50 peper Exp $
+
+*paludis-0.26.0_alpha7 (18 Jan 2008)
+
+  18 Jan 2008; Piotr Jaroszyński <peper@gentoo.org>
+  paludis-0.26.0_alpha3.ebuild, paludis-0.26.0_alpha4.ebuild,
+  paludis-0.26.0_alpha5.ebuild, paludis-0.26.0_alpha5-r1.ebuild,
+  paludis-0.26.0_alpha6.ebuild, +paludis-0.26.0_alpha7.ebuild:
+  Add 0.26.0_alpha7. Update epydoc dep.
 
 *paludis-0.26.0_alpha6 (13 Jan 2008)
 
diff --git a/sys-apps/paludis/files/digest-paludis-0.26.0_alpha7 b/sys-apps/paludis/files/digest-paludis-0.26.0_alpha7
new file mode 100644
index 000000000000..98e1e6997a7d
--- /dev/null
+++ b/sys-apps/paludis/files/digest-paludis-0.26.0_alpha7
@@ -0,0 +1,3 @@
+MD5 6d7b240f78f8c6eb21d5ecb2a5f18b58 paludis-0.26.0_alpha7.tar.bz2 1418797
+RMD160 0e0b5624cb60be91066ea251fde4620c257e7618 paludis-0.26.0_alpha7.tar.bz2 1418797
+SHA256 56e28d4d1a3178b7410212338d54b2217ab72dd11f6a777ce782971f3b1f743d paludis-0.26.0_alpha7.tar.bz2 1418797
diff --git a/sys-apps/paludis/paludis-0.26.0_alpha3.ebuild b/sys-apps/paludis/paludis-0.26.0_alpha3.ebuild
index 0f5176bcd9c6..c2907fe386a4 100644
--- a/sys-apps/paludis/paludis-0.26.0_alpha3.ebuild
+++ b/sys-apps/paludis/paludis-0.26.0_alpha3.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/paludis/paludis-0.26.0_alpha3.ebuild,v 1.6 2008/01/02 17:09:05 peper Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/paludis/paludis-0.26.0_alpha3.ebuild,v 1.7 2008/01/18 13:52:50 peper Exp $
 
 inherit bash-completion eutils flag-o-matic
 
@@ -31,7 +31,7 @@ DEPEND="${COMMON_DEPEND}
 		|| ( >=app-doc/doxygen-1.5.3 <=app-doc/doxygen-1.5.1 )
 		media-gfx/imagemagick
 	)
-	python? ( dev-python/epydoc )"
+	python? ( <dev-python/epydoc-3.0_beta1 )"
 
 RDEPEND="${COMMON_DEPEND}
 	!>=app-shells/bash-3.2_p25
diff --git a/sys-apps/paludis/paludis-0.26.0_alpha4.ebuild b/sys-apps/paludis/paludis-0.26.0_alpha4.ebuild
index df69f8e8379a..43acff8d3e47 100644
--- a/sys-apps/paludis/paludis-0.26.0_alpha4.ebuild
+++ b/sys-apps/paludis/paludis-0.26.0_alpha4.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/paludis/paludis-0.26.0_alpha4.ebuild,v 1.5 2008/01/02 17:09:05 peper Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/paludis/paludis-0.26.0_alpha4.ebuild,v 1.6 2008/01/18 13:52:50 peper Exp $
 
 inherit bash-completion eutils flag-o-matic
 
@@ -31,7 +31,7 @@ DEPEND="${COMMON_DEPEND}
 		|| ( >=app-doc/doxygen-1.5.3 <=app-doc/doxygen-1.5.1 )
 		media-gfx/imagemagick
 	)
-	python? ( dev-python/epydoc dev-python/pygments )
+	python? ( <dev-python/epydoc-3.0_beta1 dev-python/pygments )
 	ruby? ( dev-ruby/syntax )"
 
 RDEPEND="${COMMON_DEPEND}
diff --git a/sys-apps/paludis/paludis-0.26.0_alpha5-r1.ebuild b/sys-apps/paludis/paludis-0.26.0_alpha5-r1.ebuild
index 6bc05d280398..1462a27d5b34 100644
--- a/sys-apps/paludis/paludis-0.26.0_alpha5-r1.ebuild
+++ b/sys-apps/paludis/paludis-0.26.0_alpha5-r1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/paludis/paludis-0.26.0_alpha5-r1.ebuild,v 1.1 2008/01/05 05:18:34 peper Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/paludis/paludis-0.26.0_alpha5-r1.ebuild,v 1.2 2008/01/18 13:52:50 peper Exp $
 
 inherit bash-completion eutils flag-o-matic
 
@@ -31,7 +31,7 @@ DEPEND="${COMMON_DEPEND}
 		|| ( >=app-doc/doxygen-1.5.3 <=app-doc/doxygen-1.5.1 )
 		media-gfx/imagemagick
 	)
-	python? ( dev-python/epydoc dev-python/pygments )
+	python? ( <dev-python/epydoc-3.0_beta1 dev-python/pygments )
 	ruby? ( dev-ruby/syntax )
 	dev-util/pkgconfig"
 
diff --git a/sys-apps/paludis/paludis-0.26.0_alpha5.ebuild b/sys-apps/paludis/paludis-0.26.0_alpha5.ebuild
index f6b0c39ac54e..d65b9cec1426 100644
--- a/sys-apps/paludis/paludis-0.26.0_alpha5.ebuild
+++ b/sys-apps/paludis/paludis-0.26.0_alpha5.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/paludis/paludis-0.26.0_alpha5.ebuild,v 1.1 2008/01/05 00:20:32 peper Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/paludis/paludis-0.26.0_alpha5.ebuild,v 1.2 2008/01/18 13:52:50 peper Exp $
 
 inherit bash-completion eutils flag-o-matic
 
@@ -31,7 +31,7 @@ DEPEND="${COMMON_DEPEND}
 		|| ( >=app-doc/doxygen-1.5.3 <=app-doc/doxygen-1.5.1 )
 		media-gfx/imagemagick
 	)
-	python? ( dev-python/epydoc dev-python/pygments )
+	python? ( <dev-python/epydoc-3.0_beta1 dev-python/pygments )
 	ruby? ( dev-ruby/syntax )
 	dev-util/pkgconfig"
 
diff --git a/sys-apps/paludis/paludis-0.26.0_alpha6.ebuild b/sys-apps/paludis/paludis-0.26.0_alpha6.ebuild
index cc0bda6c1902..0f2211266b7d 100644
--- a/sys-apps/paludis/paludis-0.26.0_alpha6.ebuild
+++ b/sys-apps/paludis/paludis-0.26.0_alpha6.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/paludis/paludis-0.26.0_alpha6.ebuild,v 1.1 2008/01/13 18:10:19 peper Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/paludis/paludis-0.26.0_alpha6.ebuild,v 1.2 2008/01/18 13:52:50 peper Exp $
 
 inherit bash-completion eutils flag-o-matic
 
@@ -31,7 +31,7 @@ DEPEND="${COMMON_DEPEND}
 		|| ( >=app-doc/doxygen-1.5.3 <=app-doc/doxygen-1.5.1 )
 		media-gfx/imagemagick
 	)
-	python? ( dev-python/epydoc dev-python/pygments )
+	python? ( <dev-python/epydoc-3.0_beta1 dev-python/pygments )
 	ruby? ( dev-ruby/syntax )
 	dev-util/pkgconfig"
 
diff --git a/sys-apps/paludis/paludis-0.26.0_alpha7.ebuild b/sys-apps/paludis/paludis-0.26.0_alpha7.ebuild
new file mode 100644
index 000000000000..f333feaac60b
--- /dev/null
+++ b/sys-apps/paludis/paludis-0.26.0_alpha7.ebuild
@@ -0,0 +1,137 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/paludis/paludis-0.26.0_alpha7.ebuild,v 1.1 2008/01/18 13:52:50 peper Exp $
+
+inherit bash-completion eutils flag-o-matic
+
+DESCRIPTION="paludis, the other package mangler"
+HOMEPAGE="http://paludis.pioto.org/"
+SRC_URI="http://paludis.pioto.org/download/${P}.tar.bz2"
+
+IUSE="doc glsa inquisitio portage pink python qa ruby vim-syntax zsh-completion visibility"
+LICENSE="GPL-2 vim-syntax? ( vim )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+
+COMMON_DEPEND="
+	>=app-admin/eselect-1.0.2
+	>=app-admin/eselect-news-20071201
+	>=app-shells/bash-3
+	qa? ( dev-libs/pcre++ >=dev-libs/libxml2-2.6 app-crypt/gnupg )
+	inquisitio? ( dev-libs/pcre++ )
+	glsa? ( >=dev-libs/libxml2-2.6 )
+	ruby? ( >=dev-lang/ruby-1.8 )
+	python? ( >=dev-lang/python-2.4 >=dev-libs/boost-1.33.1-r1 )
+	virtual/c++-tr1-functional
+	virtual/c++-tr1-memory
+	virtual/c++-tr1-type-traits"
+
+DEPEND="${COMMON_DEPEND}
+	doc? (
+		|| ( >=app-doc/doxygen-1.5.3 <=app-doc/doxygen-1.5.1 )
+		media-gfx/imagemagick
+	)
+	python? ( <dev-python/epydoc-3.0_beta1 dev-python/pygments )
+	ruby? ( doc? ( dev-ruby/syntax dev-ruby/allison ) )
+	dev-util/pkgconfig"
+
+RDEPEND="${COMMON_DEPEND}
+	net-misc/wget
+	net-misc/rsync
+	sys-apps/sandbox"
+
+# Keep this as a PDEPEND. It avoids issues when Paludis is used as the
+# default virtual/portage provider.
+PDEPEND="
+	vim-syntax? ( >=app-editors/vim-core-7 )"
+
+PROVIDE="virtual/portage"
+
+pkg_setup() {
+	replace-flags -Os -O2
+	replace-flags -O3 -O2
+
+	enewgroup "paludisbuild"
+	enewuser "paludisbuild" "-1" "-1" "/var/tmp/paludis" "paludisbuild"
+
+	FIXED_MAKEOPTS=""
+	m=$(free -m | sed -n -e '/cache:/s,^[^[:digit:]]\+[[:digit:]]\+[^[:digit:]]\+\([[:digit:]]\+\).*,\1,p')
+	j=$(echo "$MAKEOPTS" | sed -n -e 's,.*-j\([[:digit:]]\+\).*,\1,p' )
+	if [[ -n "${m}" ]] && [[ -n "${j}" ]] && (( ${j} > 1 )); then
+		if (( m < j * 512 )) ; then
+			FIXED_MAKEOPTS="-j$(( m / 512 ))"
+			[[ ${FIXED_MAKEOPTS} == "-j0" ]] && FIXED_MAKEOPTS="-j1"
+			ewarn "Your MAKEOPTS -j is too high. To stop the kernel from throwing a hissy fit"
+			ewarn "when g++ eats all your RAM, we'll use ${FIXED_MAKEOPTS} instead."
+		fi
+	fi
+}
+
+src_compile() {
+	local repositories=`echo default unpackaged $(usev cran ) | tr -s \  ,`
+	local clients=`echo default accerso adjutrix contrarius importare \
+		$(usev inquisitio ) instruo paludis reconcilio | tr -s \  ,`
+	local environments=`echo default $(usev portage ) | tr -s \  ,`
+	econf \
+		$(use_enable doc doxygen ) \
+		$(use_enable pink ) \
+		$(use_enable qa ) \
+		$(use_enable ruby ) \
+		$(useq ruby && useq doc && echo --enable-ruby-doc ) \
+		$(use_enable python ) \
+		$(use_enable glsa ) \
+		$(use_enable vim-syntax vim ) \
+		$(use_enable visibility ) \
+		--with-vim-install-dir=/usr/share/vim/vimfiles \
+		--enable-sandbox \
+		--with-repositories=${repositories} \
+		--with-clients=${clients} \
+		--with-environments=${environments} \
+		|| die "econf failed"
+
+	emake ${FIXED_MAKEOPTS} || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "install failed"
+	dodoc AUTHORS README ChangeLog NEWS
+
+	BASH_COMPLETION_NAME="adjutrix" dobashcompletion bash-completion/adjutrix
+	BASH_COMPLETION_NAME="paludis" dobashcompletion bash-completion/paludis
+	BASH_COMPLETION_NAME="accerso" dobashcompletion bash-completion/accerso
+	BASH_COMPLETION_NAME="contrarius" dobashcompletion bash-completion/contrarius
+	BASH_COMPLETION_NAME="importare" dobashcompletion bash-completion/importare
+	BASH_COMPLETION_NAME="instruo" dobashcompletion bash-completion/instruo
+	BASH_COMPLETION_NAME="reconcilio" dobashcompletion bash-completion/reconcilio
+	use qa && \
+		BASH_COMPLETION_NAME="qualudis" \
+		dobashcompletion bash-completion/qualudis
+	use inquisitio && \
+		BASH_COMPLETION_NAME="inquisitio" \
+		dobashcompletion bash-completion/inquisitio
+
+	if use zsh-completion ; then
+		insinto /usr/share/zsh/site-functions
+		doins zsh-completion/_paludis
+		doins zsh-completion/_adjutrix
+		doins zsh-completion/_importare
+		doins zsh-completion/_reconcilio
+		use inquisitio && doins zsh-completion/_inquisitio
+		doins zsh-completion/_paludis_packages
+	fi
+}
+
+src_test() {
+	# Work around Portage bugs
+	export PALUDIS_DO_NOTHING_SANDBOXY="portage sucks"
+	export BASH_ENV=/dev/null
+
+	emake check || die "Make check failed"
+}
+
+pkg_postinst() {
+	# Remove the symlink created by app-admin/eselect-news
+	if [[ -L "${ROOT}/var/lib/paludis/news" ]] ; then
+		rm "${ROOT}/var/lib/paludis/news"
+	fi
+}