Version bump.

(Portage version: 2.2.0_alpha173/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 67 insertions, 1 deletions

diff --git a/sys-apps/moreutils/ChangeLog b/sys-apps/moreutils/ChangeLog
index 7645b2cccc8c..8ec2aa80bbd4 100644
--- a/sys-apps/moreutils/ChangeLog
+++ b/sys-apps/moreutils/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/moreutils
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/moreutils/ChangeLog,v 1.53 2013/03/06 05:22:49 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/moreutils/ChangeLog,v 1.54 2013/05/06 06:24:35 radhermit Exp $
+
+*moreutils-0.48 (06 May 2013)
+
+  06 May 2013; Tim Harder <radhermit@gentoo.org> +moreutils-0.48.ebuild:
+  Version bump.
 
   06 Mar 2013; Tim Harder <radhermit@gentoo.org> moreutils-0.47.ebuild,
   +files/moreutils-doc-build.patch:
diff --git a/sys-apps/moreutils/moreutils-0.48.ebuild b/sys-apps/moreutils/moreutils-0.48.ebuild
new file mode 100644
index 000000000000..c5fbf27cd8fd
--- /dev/null
+++ b/sys-apps/moreutils/moreutils-0.48.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/moreutils/moreutils-0.48.ebuild,v 1.1 2013/05/06 06:24:35 radhermit Exp $
+
+EAPI=4
+inherit eutils toolchain-funcs prefix
+
+DESCRIPTION="a growing collection of the unix tools that nobody thought to write thirty years ago"
+HOMEPAGE="http://joeyh.name/code/moreutils/"
+SRC_URI="mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86 ~x86-linux"
+IUSE="+doc +perl"
+
+RDEPEND="
+	perl? (
+		dev-lang/perl
+		dev-perl/IPC-Run
+		dev-perl/Time-Duration
+		dev-perl/TimeDate
+	)"
+DEPEND="
+	doc? (
+		dev-lang/perl
+		>=app-text/docbook2X-0.8.8-r2
+		app-text/docbook-xml-dtd:4.4
+	)"
+
+S=${WORKDIR}/${PN}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-0.47-dtd-path.patch
+	eprefixify *.docbook
+
+	# don't build manpages
+	if ! use doc ; then
+		sed -i -e '/^all:/s/$(MANS)//' -e '/man1/d' Makefile || die
+	fi
+
+	# don't install perl scripts
+	if ! use perl ; then
+		sed -i -e '/PERLSCRIPTS/d' Makefile || die
+	fi
+}
+
+src_compile() {
+	tc-export CC
+	emake CFLAGS="${CFLAGS}" DOCBOOK2XMAN=docbook2man.pl PREFIX="${EPREFIX}/usr"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" INSTALL_BIN=install install
+
+	# sys-process is more advanced than parallel from moreutils, rename it
+	if use doc; then
+		mv "${ED}"usr/share/man/man1/{,${PN}_}parallel.1 || die
+	fi
+	mv "${ED}"usr/bin/{,${PN}_}parallel || die
+}