version bump, eapi bump and sync live ebuild.

(Portage version: 2.2.0_alpha171/cvs/Linux i686, signed Manifest commit with key 0x30C46538)

3 files changed, 118 insertions, 3 deletions

diff --git a/sys-apps/kmod/ChangeLog b/sys-apps/kmod/ChangeLog
index d25724481e34..945efd0d657c 100644
--- a/sys-apps/kmod/ChangeLog
+++ b/sys-apps/kmod/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/kmod
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/ChangeLog,v 1.80 2013/03/26 08:14:18 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/ChangeLog,v 1.81 2013/04/10 02:04:51 williamh Exp $
+
+*kmod-13 (10 Apr 2013)
+
+  10 Apr 2013; William Hubbs <williamh@gentoo.org> +kmod-13.ebuild,
+  kmod-9999.ebuild:
+  version bump, eapi bump and sync live ebuild.
 
   26 Mar 2013; Samuli Suominen <ssuominen@gentoo.org> kmod-12-r1.ebuild,
   kmod-9999.ebuild:
diff --git a/sys-apps/kmod/kmod-13.ebuild b/sys-apps/kmod/kmod-13.ebuild
new file mode 100644
index 000000000000..f161d0a216a6
--- /dev/null
+++ b/sys-apps/kmod/kmod-13.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-13.ebuild,v 1.1 2013/04/10 02:04:51 williamh Exp $
+
+EAPI=5
+
+VIRTUAL_MODUTILS=1
+
+inherit autotools eutils libtool multilib linux-mod
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/kernel/${PN}/${PN}.git"
+	inherit git-2
+else
+	SRC_URI="mirror://kernel/linux/utils/kernel/kmod/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+fi
+
+DESCRIPTION="library and tools for managing linux kernel modules"
+HOMEPAGE="http://git.kernel.org/?p=utils/kernel/kmod/kmod.git"
+
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="debug doc lzma static-libs +tools zlib"
+
+# Upstream does not support running the test suite with custom configure flags.
+# I was also told that the test suite is intended for kmod developers.
+# So we have to restrict it.
+# See bug #408915.
+RESTRICT="test"
+
+RDEPEND="!sys-apps/module-init-tools
+	!sys-apps/modutils
+	lzma? ( >=app-arch/xz-utils-5.0.4-r1 )
+	zlib? ( >=sys-libs/zlib-1.2.6 )" #427130
+DEPEND="${RDEPEND}
+	dev-libs/libxslt
+	doc? ( dev-util/gtk-doc )
+	lzma? ( virtual/pkgconfig )
+	zlib? ( virtual/pkgconfig )"
+
+pkg_setup() {
+	CONFIG_CHECK="~MODULES ~MODULE_UNLOAD"
+
+	linux-info_pkg_setup
+}
+
+src_prepare()
+{
+	if [ ! -e configure ]; then
+		if use doc; then
+			gtkdocize --copy --docdir libkmod/docs || die
+		else
+			touch libkmod/docs/gtk-doc.make
+		fi
+		eautoreconf
+	else
+		elibtoolize
+	fi
+}
+
+src_configure()
+{
+	econf \
+		--disable-silent-rules \
+		--bindir=/bin \
+		--with-rootlibdir=/$(get_libdir) \
+		$(use_enable static-libs static) \
+		$(use_enable tools) \
+		$(use_enable debug) \
+		$(use_enable doc gtk-doc) \
+		$(use_with lzma xz) \
+		$(use_with zlib)
+}
+
+src_install()
+{
+	default
+	prune_libtool_files
+
+	if use tools; then
+		local bincmd sbincmd
+		for sbincmd in depmod insmod lsmod modinfo modprobe rmmod; do
+			dosym /bin/kmod /sbin/${sbincmd}
+		done
+
+		# These are also usable as normal user
+		for bincmd in lsmod modinfo; do
+			dosym kmod /bin/${bincmd}
+		done
+	fi
+
+	cat <<-EOF > "${T}"/usb-load-ehci-first.conf
+	softdep uhci_hcd pre: ehci_hcd
+	softdep ohci_hcd pre: ehci_hcd
+	EOF
+
+	insinto /lib/modprobe.d
+	doins "${T}"/usb-load-ehci-first.conf #260139
+}
+
+pkg_postinst() {
+	# Upgrade path from sys-apps/module-init-tools
+	if [[ -d ${ROOT}/lib/modules/${KV_FULL} ]]; then
+		if [[ -z ${REPLACING_VERSIONS} ]]; then
+			update_depmod
+		fi
+	fi
+}
diff --git a/sys-apps/kmod/kmod-9999.ebuild b/sys-apps/kmod/kmod-9999.ebuild
index 243f0340a0be..30acacc5fa20 100644
--- a/sys-apps/kmod/kmod-9999.ebuild
+++ b/sys-apps/kmod/kmod-9999.ebuild
@@ -1,8 +1,8 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-9999.ebuild,v 1.52 2013/03/26 08:14:18 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-9999.ebuild,v 1.53 2013/04/10 02:04:51 williamh Exp $
 
-EAPI=4
+EAPI=5
 
 VIRTUAL_MODUTILS=1