sci-visualization/veusz: Version Bump

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

2 files changed, 75 insertions, 1 deletions

diff --git a/sci-visualization/veusz/ChangeLog b/sci-visualization/veusz/ChangeLog
index 458ad4597664..b763a26b31ac 100644
--- a/sci-visualization/veusz/ChangeLog
+++ b/sci-visualization/veusz/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sci-visualization/veusz
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-visualization/veusz/ChangeLog,v 1.50 2014/09/23 12:03:41 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-visualization/veusz/ChangeLog,v 1.51 2014/10/27 16:46:35 jlec Exp $
+
+*veusz-1.22 (27 Oct 2014)
+
+  27 Oct 2014; Justin Lecher <jlec@gentoo.org> +veusz-1.22.ebuild:
+  Version Bump
 
 *veusz-1.21.1 (23 Sep 2014)
 
diff --git a/sci-visualization/veusz/veusz-1.22.ebuild b/sci-visualization/veusz/veusz-1.22.ebuild
new file mode 100644
index 000000000000..bd0cf3218131
--- /dev/null
+++ b/sci-visualization/veusz/veusz-1.22.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-visualization/veusz/veusz-1.22.ebuild,v 1.1 2014/10/27 16:46:35 jlec Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit eutils fdo-mime distutils-r1 virtualx
+
+DESCRIPTION="Qt scientific plotting package with good Postscript output"
+HOMEPAGE="http://home.gna.org/veusz/"
+SRC_URI="http://download.gna.org/${PN}/${P}.tar.gz"
+
+IUSE="dbus doc emf fits hdf5 vo"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+LICENSE="GPL-2"
+
+CDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	>=dev-python/PyQt4-4.6[X,svg,${PYTHON_USEDEP}]
+"
+RDEPEND="${CDEPEND}
+	dbus? ( dev-python/dbus-python[${PYTHON_USEDEP}] )
+	emf? ( dev-python/pyemf[$(python_gen_usedep 'python2*')] )
+	fits? ( dev-python/astropy[${PYTHON_USEDEP}] )
+	hdf5? ( dev-python/h5py[${PYTHON_USEDEP}] )
+	vo? (
+			dev-python/astropy[${PYTHON_USEDEP}]
+			dev-python/sampy[$(python_gen_usedep 'python2*')]
+		)"
+DEPEND="${CDEPEND}
+	dev-python/sip[${PYTHON_USEDEP}]
+	"
+
+python_test() {
+	distutils_install_for_testing
+	cd tests || die
+	VIRTUALX_COMMAND="${EPYTHON}" \
+		VEUSZ_RESOURCE_DIR="${TEST_DIR}/lib/veusz" \
+		virtualmake runselftest.py
+}
+
+python_install() {
+	distutils-r1_python_install
+	# symlink the license, bug #341653
+	ln -s "${PORTDIR}"/licenses/${LICENSE} \
+		"${D}/$(python_get_sitedir)"/${PN}/COPYING || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	use doc && dodoc Documents/manual.pdf && \
+		dohtml -r Documents/{manimages,manual.html}
+
+	doicon icons/veusz.png
+	domenu "${FILESDIR}"/veusz.desktop
+	insinto /usr/share/mime/packages
+	doins "${FILESDIR}"/veusz.xml
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+}