Version Bump

(Portage version: 2.2.17/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

3 files changed, 152 insertions, 5 deletions

diff --git a/sci-libs/scipy/ChangeLog b/sci-libs/scipy/ChangeLog
index bf4738390e31..d0638dfd118f 100644
--- a/sci-libs/scipy/ChangeLog
+++ b/sci-libs/scipy/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sci-libs/scipy
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/scipy/ChangeLog,v 1.121 2015/02/19 08:58:02 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/scipy/ChangeLog,v 1.122 2015/03/03 15:18:59 jlec Exp $
+
+*scipy-0.15.1 (03 Mar 2015)
+
+  03 Mar 2015; Justin Lecher <jlec@gentoo.org> +scipy-0.15.1.ebuild,
+  scipy-0.15.0.ebuild:
+  Version Bump
 
   19 Feb 2015; Justin Lecher <jlec@gentoo.org> -scipy-0.12.1.ebuild,
   -scipy-0.13.2.ebuild, -scipy-0.13.3.ebuild, -scipy-0.14.0.ebuild:
diff --git a/sci-libs/scipy/scipy-0.15.0.ebuild b/sci-libs/scipy/scipy-0.15.0.ebuild
index 37dbbb7a6675..f60d6738d870 100644
--- a/sci-libs/scipy/scipy-0.15.0.ebuild
+++ b/sci-libs/scipy/scipy-0.15.0.ebuild
@@ -1,12 +1,12 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/scipy/scipy-0.15.0.ebuild,v 1.1 2015/02/19 08:25:29 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/scipy/scipy-0.15.0.ebuild,v 1.2 2015/03/03 15:18:59 jlec Exp $
 
 EAPI=5
 
 PYTHON_COMPAT=( python2_7 python3_{3,4} )
 
-DOC_PV=0.13.0
+DOC_PV=0.15.0
 
 inherit eutils fortran-2 distutils-r1 flag-o-matic multilib toolchain-funcs
 
@@ -15,8 +15,8 @@ HOMEPAGE="http://www.scipy.org/"
 SRC_URI="
 	mirror://sourceforge/${PN}/${P}.tar.gz
 	doc? (
-		http://docs.scipy.org/doc/${PN}-${DOC_PV}/${PN}-html.zip -> ${PN}-${DOC_PV}-html.zip
-		http://docs.scipy.org/doc/${PN}-${DOC_PV}/${PN}-ref.pdf -> ${PN}-${DOC_PV}-ref.pdf
+		http://docs.scipy.org/doc/${PN}-${DOC_PV}/${PN}-html-${PV}.zip -> ${PN}-${DOC_PV}-html.zip
+		http://docs.scipy.org/doc/${PN}-${DOC_PV}/${PN}-ref-${PV}.pdf -> ${PN}-${DOC_PV}-ref.pdf
 	)"
 
 LICENSE="BSD LGPL-2"
diff --git a/sci-libs/scipy/scipy-0.15.1.ebuild b/sci-libs/scipy/scipy-0.15.1.ebuild
new file mode 100644
index 000000000000..e7e9e2b9379c
--- /dev/null
+++ b/sci-libs/scipy/scipy-0.15.1.ebuild
@@ -0,0 +1,141 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/scipy/scipy-0.15.1.ebuild,v 1.1 2015/03/03 15:18:59 jlec Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4} )
+
+DOC_PV=0.15.1
+
+inherit eutils fortran-2 distutils-r1 flag-o-matic multilib toolchain-funcs
+
+DESCRIPTION="Scientific algorithms library for Python"
+HOMEPAGE="http://www.scipy.org/"
+SRC_URI="
+	mirror://sourceforge/${PN}/${P}.tar.gz
+	doc? (
+		http://docs.scipy.org/doc/${PN}-${DOC_PV}/${PN}-html-${PV}.zip -> ${PN}-${DOC_PV}-html.zip
+		http://docs.scipy.org/doc/${PN}-${DOC_PV}/${PN}-ref-${PV}.pdf -> ${PN}-${DOC_PV}-ref.pdf
+	)"
+
+LICENSE="BSD LGPL-2"
+SLOT="0"
+IUSE="doc sparse test"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+
+CDEPEND="
+	dev-python/numpy[lapack,${PYTHON_USEDEP}]
+	sci-libs/arpack:0=
+	virtual/cblas
+	virtual/lapack
+	sparse? ( sci-libs/umfpack:0= )"
+DEPEND="${CDEPEND}
+	dev-lang/swig
+	>=dev-python/cython-0.19.1[${PYTHON_USEDEP}]
+	virtual/pkgconfig
+	doc? ( app-arch/unzip )
+	test? (	dev-python/nose[${PYTHON_USEDEP}] )
+	"
+
+RDEPEND="${CDEPEND}
+	virtual/python-imaging[${PYTHON_USEDEP}]"
+
+DOCS=( HACKING.rst.txt THANKS.txt )
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+src_unpack() {
+	unpack ${P}.tar.gz
+	if use doc; then
+		unzip -qo "${DISTDIR}"/${PN}-${DOC_PV}-html.zip -d html || die
+	fi
+}
+
+pc_incdir() {
+	$(tc-getPKG_CONFIG) --cflags-only-I $@ | \
+		sed -e 's/^-I//' -e 's/[ ]*-I/:/g' -e 's/[ ]*$//' -e 's|^:||'
+}
+
+pc_libdir() {
+	$(tc-getPKG_CONFIG) --libs-only-L $@ | \
+		sed -e 's/^-L//' -e 's/[ ]*-L/:/g' -e 's/[ ]*$//' -e 's|^:||'
+}
+
+pc_libs() {
+	$(tc-getPKG_CONFIG) --libs-only-l $@ | \
+		sed -e 's/[ ]-l*\(pthread\|m\)\([ ]\|$\)//g' \
+		-e 's/^-l//' -e 's/[ ]*-l/,/g' -e 's/[ ]*$//' \
+		| tr ',' '\n' | sort -u | tr '\n' ',' | sed -e 's|,$||'
+}
+
+python_prepare_all() {
+	# scipy automatically detects libraries by default
+	export {FFTW,FFTW3,UMFPACK}=None
+	use sparse && unset UMFPACK
+	# the missing symbols are in -lpythonX.Y, but since the version can
+	# differ, we just introduce the same scaryness as on Linux/ELF
+	[[ ${CHOST} == *-darwin* ]] \
+		&& append-ldflags -bundle "-undefined dynamic_lookup" \
+		|| append-ldflags -shared
+	[[ -z ${FC}  ]] && export FC="$(tc-getFC)"
+	# hack to force F77 to be FC until bug #278772 is fixed
+	[[ -z ${F77} ]] && export F77="$(tc-getFC)"
+	export F90="${FC}"
+	export SCIPY_FCONFIG="config_fc --noopt --noarch"
+	append-fflags -fPIC
+
+	local libdir="${EPREFIX}"/usr/$(get_libdir)
+	cat >> site.cfg <<-EOF
+		[blas]
+		include_dirs = $(pc_incdir cblas)
+		library_dirs = $(pc_libdir cblas blas):${libdir}
+		blas_libs = $(pc_libs cblas blas)
+		[lapack]
+		library_dirs = $(pc_libdir lapack):${libdir}
+		lapack_libs = $(pc_libs lapack)
+	EOF
+
+	# Drop hashes to force rebuild of cython based .c code
+	rm cythonize.dat || die
+
+	local PATCHES=(
+		"${FILESDIR}"/${PN}-0.12.0-blitz.patch
+		"${FILESDIR}"/${PN}-0.12.0-restore-sys-argv.patch
+	)
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	${EPYTHON} tools/cythonize.py || die
+	distutils-r1_python_compile ${SCIPY_FCONFIG}
+}
+
+python_test() {
+	# fails with bdist_egg. should it be fixed in distutils-r1 eclass?
+	distutils_install_for_testing ${SCIPY_FCONFIG}
+	cd "${TEST_DIR}" || die "no ${TEST_DIR} available"
+	"${EPYTHON}" -c "
+import scipy, sys
+r = scipy.test('fast',verbose=2)
+sys.exit(0 if r.wasSuccessful() else 1)" || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use doc; then
+		dodoc "${DISTDIR}"/${PN}*pdf
+		docinto html
+		dodoc -r "${WORKDIR}"/html/.
+	fi
+	distutils-r1_python_install_all
+}
+
+python_install() {
+	distutils-r1_python_install ${SCIPY_FCONFIG}
+}
+
+pkg_postinst() {
+	elog "You might want to set the variable SCIPY_PIL_IMAGE_VIEWER"
+	elog "to your prefered image viewer. Example:"
+	elog "\t echo \"export SCIPY_PIL_IMAGE_VIEWER=display\" >> ~/.bashrc"
+}