Initial commit, thanks to Stefan Salewski and Rafael Martins.

(Portage version: 2.1.7.1/cvs/Linux i686)

3 files changed, 95 insertions, 0 deletions

diff --git a/sci-electronics/geda-xgsch2pcb/ChangeLog b/sci-electronics/geda-xgsch2pcb/ChangeLog
new file mode 100644
index 000000000000..6a72690d4b5e
--- /dev/null
+++ b/sci-electronics/geda-xgsch2pcb/ChangeLog
@@ -0,0 +1,10 @@
+# ChangeLog for sci-electronics/geda-xgsch2pcb
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-electronics/geda-xgsch2pcb/ChangeLog,v 1.1 2009/11/23 06:00:47 calchan Exp $
+
+*geda-xgsch2pcb-0.1.3 (23 Nov 2009)
+
+  23 Nov 2009; Denis Dupeyron <calchan@gentoo.org>
+  +geda-xgsch2pcb-0.1.3.ebuild, +metadata.xml:
+  Initial commit, thanks to Stefan Salewski and Rafael Martins.
+
diff --git a/sci-electronics/geda-xgsch2pcb/geda-xgsch2pcb-0.1.3.ebuild b/sci-electronics/geda-xgsch2pcb/geda-xgsch2pcb-0.1.3.ebuild
new file mode 100644
index 000000000000..eee5a14a60a8
--- /dev/null
+++ b/sci-electronics/geda-xgsch2pcb/geda-xgsch2pcb-0.1.3.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-electronics/geda-xgsch2pcb/geda-xgsch2pcb-0.1.3.ebuild,v 1.1 2009/11/23 06:00:47 calchan Exp $
+
+EAPI="2"
+
+WANT_AUTOCONF="2.5"
+
+inherit autotools fdo-mime gnome2-utils
+
+DESCRIPTION="A graphical front-end for the gschem -> pcb workflow"
+HOMEPAGE="http://www.gpleda.org/tools/xgsch2pcb/index.html"
+SRC_URI="http://geda.seul.org/dist/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnome nls"
+
+CDEPEND="
+	<dev-lang/python-3
+	>=dev-python/pygtk-2.10
+	>=dev-python/pygobject-2.10
+	dev-python/dbus-python
+	sci-electronics/pcb[dbus]
+	sci-electronics/geda
+	nls? ( virtual/libintl )"
+
+RDEPEND="
+	${CDEPEND}
+	sci-electronics/electronics-menu
+	gnome? ( dev-python/gnome-python )"
+
+DEPEND="
+	${CDEPEND}
+	dev-util/intltool
+	dev-lang/perl
+	nls? ( sys-devel/gettext )"
+
+src_prepare(){
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		--disable-update-desktop-database \
+		--disable-dependency-tracking
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc README ChangeLog
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+}
diff --git a/sci-electronics/geda-xgsch2pcb/metadata.xml b/sci-electronics/geda-xgsch2pcb/metadata.xml
new file mode 100644
index 000000000000..55a84c45251b
--- /dev/null
+++ b/sci-electronics/geda-xgsch2pcb/metadata.xml
@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<herd>sci-electronics</herd>
+	<longdescription>
+		``gsch2pcb`` is a command-line tool, part of the gEDA suite, which is used
+		to generate and update a PCB layout.  It works with schematics created
+		by ``gschem``, part of the gEDA suite, and layouts created by ``pcb``, a
+		PCB layout system commonly used with gEDA.
+
+		``xgsch2pcb`` provides an intuitive, user-friendly graphical interface to
+		``gsch2pcb``.
+	</longdescription>
+</pkgmetadata>
+