Version bump. Fixes bug #322173. Thanks to Michael Weber <gentoo@xmw.de> for the patch

(Portage version: 2.1.8.3/cvs/Linux i686)

3 files changed, 131 insertions, 1 deletions

diff --git a/net-p2p/qbittorrent/ChangeLog b/net-p2p/qbittorrent/ChangeLog
index 4bac5870a4e0..0d68fdd594a7 100644
--- a/net-p2p/qbittorrent/ChangeLog
+++ b/net-p2p/qbittorrent/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for net-p2p/qbittorrent
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/qbittorrent/ChangeLog,v 1.85 2010/05/31 11:53:18 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/qbittorrent/ChangeLog,v 1.86 2010/06/02 14:27:35 hwoarang Exp $
+
+*qbittorrent-2.3.0_beta1 (02 Jun 2010)
+*qbittorrent-2.2.8 (02 Jun 2010)
+
+  02 Jun 2010; Markos Chandras <hwoarang@gentoo.org>
+  +qbittorrent-2.2.8.ebuild, +qbittorrent-2.3.0_beta1.ebuild:
+  Version bump. Fixes bug #322173. Thanks to Michael Weber <gentoo@xmw.de>
+  for the patch
 
   31 May 2010; Pawel Hajdan jr <phajdan.jr@gentoo.org>
   qbittorrent-2.2.6.ebuild:
diff --git a/net-p2p/qbittorrent/qbittorrent-2.2.8.ebuild b/net-p2p/qbittorrent/qbittorrent-2.2.8.ebuild
new file mode 100644
index 000000000000..ec7529774747
--- /dev/null
+++ b/net-p2p/qbittorrent/qbittorrent-2.2.8.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/qbittorrent/qbittorrent-2.2.8.ebuild,v 1.1 2010/06/02 14:27:35 hwoarang Exp $
+
+EAPI="2"
+PYTHON_DEPEND="2"
+inherit python confutils qt4-r2 versionator
+
+DESCRIPTION="BitTorrent client in C++ and Qt"
+HOMEPAGE="http://www.qbittorrent.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+X geoip libnotify"
+
+# boost version so that we always have thread support
+CDEPEND="net-libs/rb_libtorrent
+	x11-libs/qt-core:4
+	X? ( x11-libs/qt-gui:4
+		libnotify? ( x11-libs/qt-gui:4[glib] ) )
+	dev-libs/boost"
+DEPEND="${CDEPEND}
+	dev-util/pkgconfig"
+RDEPEND="${CDEPEND}
+	geoip? ( dev-libs/geoip )
+	libnotify? ( x11-libs/libnotify )"
+
+DOCS="AUTHORS Changelog NEWS README TODO"
+
+pkg_setup() {
+	confutils_use_depend_all libnotify X
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+src_prepare() {
+	# Respect LDFLAGS
+	sed -i -e 's/-Wl,--as-needed/$(LDFLAGS)/g' src/src.pro
+	qt4-r2_src_prepare
+}
+
+src_configure() {
+	local myconf
+	use X         || myconf+=" --disable-gui"
+	use geoip     || myconf+=" --disable-geoip-database"
+	use libnotify || myconf+=" --disable-libnotify"
+
+	# slotted boost detection, bug #309415
+	BOOST_PKG="$(best_version ">=dev-libs/boost-1.34.1")"
+	BOOST_VER="$(get_version_component_range 1-2 "${BOOST_PKG/*boost-/}")"
+	BOOST_VER="$(replace_all_version_separators _ "${BOOST_VER}")"
+	myconf+=" --with-libboost-inc=/usr/include/boost-${BOOST_VER}"
+
+	# econf fails, since this uses qconf
+	./configure --prefix=/usr --qtdir=/usr ${myconf} || die "configure failed"
+	eqmake4
+}
diff --git a/net-p2p/qbittorrent/qbittorrent-2.3.0_beta1.ebuild b/net-p2p/qbittorrent/qbittorrent-2.3.0_beta1.ebuild
new file mode 100644
index 000000000000..17d77e1164a5
--- /dev/null
+++ b/net-p2p/qbittorrent/qbittorrent-2.3.0_beta1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/qbittorrent/qbittorrent-2.3.0_beta1.ebuild,v 1.1 2010/06/02 14:27:35 hwoarang Exp $
+
+EAPI="2"
+PYTHON_DEPEND="2"
+
+inherit python confutils qt4-r2 versionator
+
+MY_P="${P/_/}"
+DESCRIPTION="BitTorrent client in C++ and Qt"
+HOMEPAGE="http://www.qbittorrent.org/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+X geoip libnotify"
+
+# boost version so that we always have thread support
+CDEPEND="net-libs/rb_libtorrent
+	x11-libs/qt-core:4
+	X? ( x11-libs/qt-gui:4
+		libnotify? ( x11-libs/qt-gui:4[glib] ) )
+	dev-libs/boost"
+DEPEND="${CDEPEND}
+	dev-util/pkgconfig"
+RDEPEND="${CDEPEND}
+	geoip? ( dev-libs/geoip )
+	libnotify? ( x11-libs/libnotify )"
+
+DOCS="AUTHORS Changelog NEWS README TODO"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	confutils_use_depend_all libnotify X
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+src_prepare() {
+	# Respect LDFLAGS
+	sed -i -e 's/-Wl,--as-needed/$(LDFLAGS)/g' src/src.pro
+	qt4-r2_src_prepare
+}
+
+src_configure() {
+	local myconf
+	use X         || myconf+=" --disable-gui"
+	use geoip     || myconf+=" --disable-geoip-database"
+	use libnotify || myconf+=" --disable-libnotify"
+
+	# slotted boost detection, bug #309415
+	BOOST_PKG="$(best_version ">=dev-libs/boost-1.34.1")"
+	BOOST_VER="$(get_version_component_range 1-2 "${BOOST_PKG/*boost-/}")"
+	BOOST_VER="$(replace_all_version_separators _ "${BOOST_VER}")"
+	myconf+=" --with-libboost-inc=/usr/include/boost-${BOOST_VER}"
+
+	# econf fails, since this uses qconf
+	./configure --prefix=/usr --qtdir=/usr ${myconf} || die "configure failed"
+	eqmake4
+}