Version bump for Gnome 3.8

(Portage version: 2.1.11.60/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

2 files changed, 61 insertions, 1 deletions

diff --git a/net-misc/networkmanager-vpnc/ChangeLog b/net-misc/networkmanager-vpnc/ChangeLog
index b8fca2423756..e41d6ad4729f 100644
--- a/net-misc/networkmanager-vpnc/ChangeLog
+++ b/net-misc/networkmanager-vpnc/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/networkmanager-vpnc
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager-vpnc/ChangeLog,v 1.29 2013/02/03 11:26:40 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager-vpnc/ChangeLog,v 1.30 2013/04/07 15:23:35 pacho Exp $
+
+*networkmanager-vpnc-0.9.8.0 (07 Apr 2013)
+
+  07 Apr 2013; Pacho Ramos <pacho@gentoo.org>
+  +networkmanager-vpnc-0.9.8.0.ebuild:
+  Version bump for Gnome 3.8
 
   03 Feb 2013; Pacho Ramos <pacho@gentoo.org> metadata.xml:
   Cleanup due #333419
diff --git a/net-misc/networkmanager-vpnc/networkmanager-vpnc-0.9.8.0.ebuild b/net-misc/networkmanager-vpnc/networkmanager-vpnc-0.9.8.0.ebuild
new file mode 100644
index 000000000000..d127203599ce
--- /dev/null
+++ b/net-misc/networkmanager-vpnc/networkmanager-vpnc-0.9.8.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager-vpnc/networkmanager-vpnc-0.9.8.0.ebuild,v 1.1 2013/04/07 15:23:35 pacho Exp $
+
+EAPI=5
+GNOME_ORG_MODULE="NetworkManager-${PN##*-}"
+
+inherit eutils gnome2-utils gnome.org
+
+DESCRIPTION="NetworkManager VPNC plugin"
+HOMEPAGE="http://www.gnome.org/projects/NetworkManager/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gtk test"
+
+RDEPEND="
+	>=net-misc/networkmanager-${PV}
+	>=dev-libs/dbus-glib-0.74
+	>=net-misc/vpnc-0.5
+	gtk? (
+		>=x11-libs/gtk+-2.91.4:3
+		gnome-base/gnome-keyring
+	)"
+
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	dev-util/intltool
+	virtual/pkgconfig"
+
+src_prepare() {
+	# Test will fail if the machine doesn't have a particular locale installed
+	sed '/test_non_utf8_import (plugin/ d' \
+		-i properties/tests/test-import-export.c || die "sed failed"
+
+	# Drop DEPRECATED flags, bug #384987
+	gnome2_disable_deprecation_warning
+}
+
+src_configure() {
+	econf \
+		--disable-more-warnings \
+		--disable-static \
+		--with-dist-version=Gentoo \
+		--with-gtkver=3 \
+		$(use_with gtk gnome) \
+		$(use_with test tests)
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}