Version bump to the 0.9.2 release; mostly UI improvements. Skip test that requires a specific locale to be installed (other tests pass).

(Portage version: 2.2.0_alpha77/cvs/Linux x86_64)

2 files changed, 61 insertions, 1 deletions

diff --git a/net-misc/networkmanager-vpnc/ChangeLog b/net-misc/networkmanager-vpnc/ChangeLog
index 7e2154046d19..dd3fc57d5dad 100644
--- a/net-misc/networkmanager-vpnc/ChangeLog
+++ b/net-misc/networkmanager-vpnc/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for net-misc/networkmanager-vpnc
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager-vpnc/ChangeLog,v 1.16 2011/10/03 21:14:25 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager-vpnc/ChangeLog,v 1.17 2011/11/25 04:28:08 tetromino Exp $
+
+*networkmanager-vpnc-0.9.2.0 (25 Nov 2011)
+
+  25 Nov 2011; Alexandre Rostovtsev <tetromino@gentoo.org>
+  +networkmanager-vpnc-0.9.2.0.ebuild:
+  Version bump to the 0.9.2 release; mostly UI improvements. Skip test that
+  requires a specific locale to be installed (other tests pass).
 
   03 Oct 2011; Pacho Ramos <pacho@gentoo.org> networkmanager-vpnc-0.8.2.ebuild:
   Drop DEPRECATED flags, bug #384987
diff --git a/net-misc/networkmanager-vpnc/networkmanager-vpnc-0.9.2.0.ebuild b/net-misc/networkmanager-vpnc/networkmanager-vpnc-0.9.2.0.ebuild
new file mode 100644
index 000000000000..dbe33216aeac
--- /dev/null
+++ b/net-misc/networkmanager-vpnc/networkmanager-vpnc-0.9.2.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager-vpnc/networkmanager-vpnc-0.9.2.0.ebuild,v 1.1 2011/11/25 04:28:08 tetromino Exp $
+
+EAPI="4"
+GNOME_ORG_MODULE="NetworkManager-${PN##*-}"
+
+inherit gnome.org
+
+DESCRIPTION="NetworkManager VPNC plugin"
+HOMEPAGE="http://www.gnome.org/projects/NetworkManager/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnome test"
+
+RDEPEND="
+	>=net-misc/networkmanager-${PV}
+	>=dev-libs/dbus-glib-0.74
+	>=net-misc/vpnc-0.5
+	gnome? (
+		>=x11-libs/gtk+-2.91.4:3
+		gnome-base/gnome-keyring
+	)"
+
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	dev-util/intltool
+	dev-util/pkgconfig"
+
+src_prepare() {
+	# Test will fail if the machine doesn't have a particular locale installed
+	sed '/test_non_utf8_import (plugin/ d' \
+		-i properties/tests/test-import-export.c || die "sed failed"
+}
+
+src_configure() {
+	ECONF="--disable-more-warnings
+		--disable-static
+		--with-dist-version=Gentoo
+		--with-gtkver=3
+		$(use_with gnome)
+		$(use_with test tests)"
+
+	econf ${ECONF}
+}
+
+src_install() {
+	default
+	# Remove useless .la files
+	find "${D}" -name '*.la' -exec rm -f {} +
+}