Set -fno-strict-aliasing (bug #505026 by David).

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A792A613)

3 files changed, 111 insertions, 1 deletions

diff --git a/net-libs/libnids/ChangeLog b/net-libs/libnids/ChangeLog
index a7d2b4f86825..bc65fdd02c8f 100644
--- a/net-libs/libnids/ChangeLog
+++ b/net-libs/libnids/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for net-libs/libnids
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libnids/ChangeLog,v 1.63 2014/03/19 15:47:03 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libnids/ChangeLog,v 1.64 2014/04/08 14:02:10 jer Exp $
+
+*libnids-1.24-r5 (08 Apr 2014)
+*libnids-1.18-r4 (08 Apr 2014)
+
+  08 Apr 2014; Jeroen Roovers <jer@gentoo.org> +libnids-1.18-r4.ebuild,
+  +libnids-1.24-r5.ebuild:
+  Set -fno-strict-aliasing (bug #505026 by David).
 
 *libnids-1.18-r3 (19 Mar 2014)
 
diff --git a/net-libs/libnids/libnids-1.18-r4.ebuild b/net-libs/libnids/libnids-1.18-r4.ebuild
new file mode 100644
index 000000000000..9b781f772f49
--- /dev/null
+++ b/net-libs/libnids/libnids-1.18-r4.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libnids/libnids-1.18-r4.ebuild,v 1.1 2014/04/08 14:02:10 jer Exp $
+
+EAPI=5
+
+inherit eutils flag-o-matic toolchain-funcs
+
+DESCRIPTION="an implementation of an E-component of Network Intrusion Detection System"
+HOMEPAGE="http://www.packetfactory.net/Projects/libnids/"
+SRC_URI="http://www.packetfactory.net/Projects/libnids/dist/${P/_}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="1.1"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="static-libs"
+
+DEPEND="
+	net-libs/libpcap
+	>=net-libs/libnet-1.1.0-r3
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${P}-chksum.c-ebx.patch \
+		"${FILESDIR}"/${P}-elif.patch \
+		"${FILESDIR}"/${PN}-1.24-ldflags.patch \
+		"${FILESDIR}"/${PN}-1.24-static-libs.patch
+}
+
+src_configure() {
+	tc-export AR
+	append-flags -fno-strict-aliasing
+
+	econf --enable-shared
+}
+
+src_compile() {
+	emake shared $(usex static-libs static '')
+}
+
+src_install() {
+	local tgt
+	for tgt in _installshared $(usex static-libs _install ''); do
+		emake install_prefix="${D}" ${tgt}
+	done
+
+	dodoc CHANGES CREDITS MISC README
+}
diff --git a/net-libs/libnids/libnids-1.24-r5.ebuild b/net-libs/libnids/libnids-1.24-r5.ebuild
new file mode 100644
index 000000000000..55ddd7385151
--- /dev/null
+++ b/net-libs/libnids/libnids-1.24-r5.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libnids/libnids-1.24-r5.ebuild,v 1.1 2014/04/08 14:02:10 jer Exp $
+
+EAPI=5
+inherit eutils flag-o-matic toolchain-funcs
+
+DESCRIPTION="an implementation of an E-component of Network Intrusion Detection System"
+HOMEPAGE="http://libnids.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="1.2"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="+glib +libnet static-libs"
+
+DEPEND="
+	net-libs/libpcap
+	glib? ( dev-libs/glib )
+	libnet? ( >=net-libs/libnet-1.1.0-r3 )
+"
+RDEPEND="
+	${DEPEND}
+	!net-libs/libnids:1.1
+"
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-ldflags.patch"
+	epatch "${FILESDIR}/${P}-static-libs.patch"
+}
+
+src_configure() {
+	tc-export AR
+	append-flags -fno-strict-aliasing
+
+	econf \
+		--enable-shared \
+		$(use_enable glib libglib) \
+		$(use_enable libnet libnet)
+}
+
+src_compile() {
+	emake shared $(usex static-libs static '')
+}
+
+src_install() {
+	local tgt
+	for tgt in _installshared $(usex static-libs _install ''); do
+		emake install_prefix="${D}" ${tgt}
+	done
+
+	dodoc CHANGES CREDITS MISC README doc/*
+}