Revision bump to pull in two fixes for plugins from upstream CVS.

(Portage version: 2.0.51.22-r2)

1 files changed, 88 insertions, 0 deletions

diff --git a/net-irc/xchat/xchat-2.4.4-r1.ebuild b/net-irc/xchat/xchat-2.4.4-r1.ebuild
new file mode 100644
index 000000000000..442f8cedfa92
--- /dev/null
+++ b/net-irc/xchat/xchat-2.4.4-r1.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2005 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-irc/xchat/xchat-2.4.4-r1.ebuild,v 1.1 2005/07/20 14:36:53 swegener Exp $
+
+inherit flag-o-matic eutils versionator
+
+DESCRIPTION="Graphical IRC client"
+SRC_URI="http://www.xchat.org/files/source/$(get_version_component_range 1-2)/${P}.tar.bz2"
+HOMEPAGE="http://www.xchat.org/"
+
+LICENSE="GPL-2"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="perl tcltk python ssl mmx ipv6 nls xchattext xchatnogtk xchatdccserver"
+
+# Added for to fix a sparc seg fault issue by Jason Wever <weeve@gentoo.org>
+if [ ${ARCH} = "sparc" ]
+then
+	replace-flags "-O[3-9]" "-O2"
+fi
+
+RDEPEND=">=dev-libs/glib-2.0.3
+	!xchatnogtk? ( >=x11-libs/gtk+-2.0.3 )
+	ssl? ( >=dev-libs/openssl-0.9.6d )
+	perl? ( >=dev-lang/perl-5.6.1 )
+	python? ( dev-lang/python )
+	tcltk? ( dev-lang/tcl )
+	!net-irc/xchat-gnome"
+
+DEPEND="${RDEPEND}
+	>=dev-util/pkgconfig-0.7
+	>=sys-apps/sed-4
+	nls? ( sys-devel/gettext )"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}"/${PV}-plugin-fixes.patch
+	use xchatdccserver && epatch "${FILESDIR}"/xchat-dccserver-0.5.patch
+
+	# use libdir/xchat/plugins as the plugin directory
+	if [ $(get_libdir) != "lib" ] ; then
+		sed -i -e 's:${prefix}/lib/xchat:${libdir}/xchat:' \
+			"${S}"/configure{,.in} || die
+	fi
+}
+
+src_compile() {
+
+	# xchat's configure script uses sys.path to find library path
+	# instead of python-config (#25943)
+	unset PYTHONPATH
+
+	econf \
+		$(use_enable ssl openssl) \
+		$(use_enable perl) \
+		$(use_enable python) \
+		$(use_enable tcltk tcl) \
+		$(use_enable mmx) \
+		$(use_enable ipv6) \
+		$(use_enable nls) \
+		$(use_enable xchattext textfe) \
+		$(use_enable !xchatnogtk gtkfe) \
+		--program-suffix=-2 \
+		|| die "Configure failed"
+
+	emake || die "Compile failed"
+
+}
+
+src_install() {
+
+	# some magic to create a menu entry for xchat 2
+	sed -i \
+		-e "s:^Exec=xchat$:Exec=xchat-2:" \
+		-e "s:Name=XChat IRC:Name=XChat 2 IRC:" \
+		xchat.desktop
+
+	make DESTDIR="${D}" install || die "Install failed"
+
+	# install plugin development header
+	insinto /usr/include/xchat
+	doins src/common/xchat-plugin.h || die "doins failed"
+
+	dodoc ChangeLog README* || die "dodoc failed"
+
+}