net-analyzer/openvas-scanner: Version Bump

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

3 files changed, 80 insertions, 5 deletions

diff --git a/net-analyzer/openvas-scanner/ChangeLog b/net-analyzer/openvas-scanner/ChangeLog
index fe1bfbf7e860..6efda5460faf 100644
--- a/net-analyzer/openvas-scanner/ChangeLog
+++ b/net-analyzer/openvas-scanner/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-analyzer/openvas-scanner
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/openvas-scanner/ChangeLog,v 1.17 2014/12/01 16:49:48 jlec Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/openvas-scanner/ChangeLog,v 1.18 2015/02/03 09:08:30 jlec Exp $
+
+*openvas-scanner-5.0_beta5 (03 Feb 2015)
+
+  03 Feb 2015; Justin Lecher <jlec@gentoo.org> openvas-scanner-4.0.5.ebuild,
+  +openvas-scanner-5.0_beta5.ebuild:
+  Version Bump
 
 *openvas-scanner-5.0_beta4 (01 Dec 2014)
 *openvas-scanner-4.0.5 (01 Dec 2014)
diff --git a/net-analyzer/openvas-scanner/openvas-scanner-4.0.5.ebuild b/net-analyzer/openvas-scanner/openvas-scanner-4.0.5.ebuild
index 7271c877520b..6064a734c496 100644
--- a/net-analyzer/openvas-scanner/openvas-scanner-4.0.5.ebuild
+++ b/net-analyzer/openvas-scanner/openvas-scanner-4.0.5.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2014 Gentoo Foundation
+# Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/openvas-scanner/openvas-scanner-4.0.5.ebuild,v 1.1 2014/12/01 16:49:48 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/openvas-scanner/openvas-scanner-4.0.5.ebuild,v 1.2 2015/02/03 09:08:30 jlec Exp $
 
 EAPI=5
 
@@ -20,7 +20,7 @@ KEYWORDS="~amd64 ~arm ~ppc ~x86"
 IUSE=""
 
 RDEPEND="
-	~net-analyzer/openvas-libraries-7.0.6
+	~net-analyzer/openvas-libraries-7.0.7
 	!net-analyzer/openvas-plugins
 	!net-analyzer/openvas-server"
 DEPEND="${RDEPEND}
diff --git a/net-analyzer/openvas-scanner/openvas-scanner-5.0_beta5.ebuild b/net-analyzer/openvas-scanner/openvas-scanner-5.0_beta5.ebuild
new file mode 100644
index 000000000000..a3a04ab523ef
--- /dev/null
+++ b/net-analyzer/openvas-scanner/openvas-scanner-5.0_beta5.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/openvas-scanner/openvas-scanner-5.0_beta5.ebuild,v 1.1 2015/02/03 09:08:30 jlec Exp $
+
+EAPI=5
+
+inherit cmake-utils systemd
+
+MY_PN=openvassd
+
+DL_ID=1870
+
+DESCRIPTION="A remote security scanner for Linux (OpenVAS-scanner)"
+HOMEPAGE="http://www.openvas.org/"
+SRC_URI="http://wald.intevation.org/frs/download.php/${DL_ID}/${P/_beta/+beta}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS=""
+IUSE=""
+
+RDEPEND="
+	>=dev-libs/glib-2.16:2
+	~net-analyzer/openvas-libraries-8_beta5
+	!net-analyzer/openvas-plugins
+	!net-analyzer/openvas-server"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S="${WORKDIR}"/${P/_beta/+beta}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.0.3-mkcertclient.patch
+	"${FILESDIR}"/${PN}-4.0.3-rulesdir.patch
+	"${FILESDIR}"/${PN}-4.0.3-run.patch
+	)
+
+src_prepare() {
+	sed \
+		-e '/^install.*OPENVAS_CACHE_DIR.*/d' \
+		-i CMakeLists.txt || die
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		"-DLOCALSTATEDIR=${EPREFIX}/var"
+		"-DSYSCONFDIR=${EPREFIX}/etc"
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	newinitd "${FILESDIR}"/${MY_PN}.init ${MY_PN}
+
+	insinto /etc/openvas
+	doins "${FILESDIR}"/${MY_PN}.conf "${FILESDIR}"/${MY_PN}-daemon.conf
+	dosym ../openvas/${MY_PN}-daemon.conf /etc/conf.d/${PN}
+
+	insinto /etc/logrotate.d
+	doins "${FILESDIR}"/${MY_PN}.logrotate
+
+	dodoc "${FILESDIR}"/openvas-nvt-sync-cron
+
+	systemd_newtmpfilesd "${FILESDIR}"/${MY_PN}.tmpfiles.d ${MY_PN}.conf
+	systemd_dounit "${FILESDIR}"/${MY_PN}.service
+}