Version bump. Update license. Unconditionally install certain docs.

(Portage version: 2.2_rc96/cvs/Linux i686)

2 files changed, 69 insertions, 2 deletions

diff --git a/net-analyzer/netwox/ChangeLog b/net-analyzer/netwox/ChangeLog
index 04567c48fca6..3aec23e1b07f 100644
--- a/net-analyzer/netwox/ChangeLog
+++ b/net-analyzer/netwox/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-analyzer/netwox
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/netwox/ChangeLog,v 1.29 2009/11/23 00:17:29 jer Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/netwox/ChangeLog,v 1.30 2010/10/15 01:52:30 jer Exp $
+
+*netwox-5.38.0 (15 Oct 2010)
+
+  15 Oct 2010; Jeroen Roovers <jer@gentoo.org> +netwox-5.38.0.ebuild:
+  Version bump. Update license. Unconditionally install certain docs.
 
   23 Nov 2009; Jeroen Roovers <jer@gentoo.org> netwox-5.36.0.ebuild:
   Only use LDFLAGS when linking.
diff --git a/net-analyzer/netwox/netwox-5.38.0.ebuild b/net-analyzer/netwox/netwox-5.38.0.ebuild
new file mode 100644
index 000000000000..89f197ae28f1
--- /dev/null
+++ b/net-analyzer/netwox/netwox-5.38.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/netwox/netwox-5.38.0.ebuild,v 1.1 2010/10/15 01:52:30 jer Exp $
+
+# NOTE: netwib, netwox and netwag go together, bump all or bump none
+
+EAPI="2"
+
+inherit toolchain-funcs multilib
+
+DESCRIPTION="Toolbox of 217 utilities for testing Ethernet/IP networks"
+HOMEPAGE="http://www.laurentconstantin.com/en/netw/netwox/"
+BASEURI="http://www.laurentconstantin.com/common/netw/${PN}/download/"
+SRC_URI="
+	${BASEURI}v${PV/.*}/${P}-src.tgz
+	doc? ( ${BASEURI}v${PV/.*}/${P}-doc_html.tgz )
+"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~sparc ~x86"
+IUSE="doc"
+
+RDEPEND=">=net-libs/libnet-1.1.1"
+
+DEPEND="net-libs/libpcap
+	~net-libs/netwib-${PV}
+	${RDEPEND}"
+
+S="${WORKDIR}/${P}-src/src"
+
+src_prepare() {
+	sed -i \
+		-e 's:/man$:/share/man:g' \
+		-e "s:/lib:/$(get_libdir):" \
+		-e "s:/usr/local:/usr:" \
+		-e "s:=ar:=$(tc-getAR):" \
+		-e "s:=ranlib:=$(tc-getRANLIB):" \
+		-e "s:=gcc:=$(tc-getCC):" \
+		-e "s:-O2:${CFLAGS}:" \
+		config.dat || die "patching config.dat failed"
+	sed -i \
+		-e "s:-o netwox:& \${LDFLAGS}:g" \
+		-e 's: ; make: ; \\$(MAKE):g' \
+		genemake || die "patching genemake failed"
+}
+
+src_configure() {
+	sh genemake || die "problem creating Makefile"
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die "install failed"
+	dodoc ../README.TXT
+	if use doc;
+	then
+		mv "${WORKDIR}"/${P}-doc_html "${D}"/usr/share/doc/${PF}/html
+	fi
+
+	dodoc "${S}"/../doc/{changelog.txt,credits.txt} \
+		"${S}"/../doc/{problemreport.txt,problemusageunix.txt,todo.txt}
+}