Version bump, bug #297480. Add translations, support for X.{5.7,5.8,6}. Drop HAL support.

(Portage version: 2.2_rc63/cvs/Linux x86_64)

2 files changed, 62 insertions, 2 deletions

diff --git a/media-video/isight-firmware-tools/ChangeLog b/media-video/isight-firmware-tools/ChangeLog
index 5f391d01a2a3..6971dd4bfbf8 100644
--- a/media-video/isight-firmware-tools/ChangeLog
+++ b/media-video/isight-firmware-tools/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-video/isight-firmware-tools
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/isight-firmware-tools/ChangeLog,v 1.9 2009/06/28 21:18:41 eva Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/isight-firmware-tools/ChangeLog,v 1.10 2010/02/24 22:20:27 eva Exp $
+
+*isight-firmware-tools-1.5.90 (24 Feb 2010)
+
+  24 Feb 2010; Gilles Dartiguelongue <eva@gentoo.org>
+  +isight-firmware-tools-1.5.90.ebuild:
+  Version bump, bug #297480. Add translations, support for X.{5.7,5.8,6}.
+  Drop HAL support.
 
 *isight-firmware-tools-1.4.2 (28 Jun 2009)
 
diff --git a/media-video/isight-firmware-tools/isight-firmware-tools-1.5.90.ebuild b/media-video/isight-firmware-tools/isight-firmware-tools-1.5.90.ebuild
new file mode 100644
index 000000000000..4e31a0612577
--- /dev/null
+++ b/media-video/isight-firmware-tools/isight-firmware-tools-1.5.90.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/isight-firmware-tools/isight-firmware-tools-1.5.90.ebuild,v 1.1 2010/02/24 22:20:27 eva Exp $
+
+EAPI="2"
+
+inherit autotools eutils multilib versionator
+
+MY_MAJORV="$(get_version_component_range 1).6"
+DESCRIPTION="Extract, load or export firmware for the iSight webcams"
+HOMEPAGE="http://bersace03.free.fr/ift/"
+SRC_URI="http://launchpad.net/${PN}/main/${MY_MAJORV}/+download/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND=">=dev-libs/glib-2.14
+	virtual/libusb:0
+	dev-libs/libgcrypt"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.35.5
+	sys-apps/texinfo"
+
+src_prepare() {
+	# Fix multilib support
+	sed "s:/lib/firmware:/$(get_libdir)/firmware:" \
+		-i src/isight.rules.in.in || die "sed failed"
+
+	# Fix intltoolize broken file, see upstream #577133
+	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in \
+		|| die "sed failed"
+}
+
+src_configure() {
+	# https://bugs.launchpad.net/isight-firmware-tools/+bug/243255
+	econf --docdir="${ROOT}/usr/share/doc/${PF}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	mv "${D}"/etc/udev/rules.d/isight.rules "${D}"/etc/udev/rules.d/70-isight.rules
+	rm -f "${D}/usr/share/doc/${PF}/HOWTO"
+	dodoc AUTHORS ChangeLog HOWTO NEWS README || die "dodoc failed"
+}
+
+pkg_postinst() {
+	elog "You need to extract your firmware prior to being able to loading it"
+	elog "ift-extract --apple-driver /macos/System/Library/Extensions/IOUSBFamily.kext/Contents/PlugIns/AppleUSBVideoSupport.kext/Contents/MacOS/AppleUSBVideoSupport"
+	elog "If you do not have OSX you can get AppleUSBVideoSupport from"
+	elog "http://www.mediafire.com/?81xtkqyttjt"
+}