Version bump.

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 109 insertions, 2 deletions

diff --git a/media-sound/ecasound/ChangeLog b/media-sound/ecasound/ChangeLog
index 71f16fa74158..45a3f60fde37 100644
--- a/media-sound/ecasound/ChangeLog
+++ b/media-sound/ecasound/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/ecasound
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/ecasound/ChangeLog,v 1.67 2013/07/06 18:53:41 ottxor Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/ecasound/ChangeLog,v 1.68 2014/01/04 05:08:29 radhermit Exp $
+
+*ecasound-2.9.1 (04 Jan 2014)
+
+  04 Jan 2014; Tim Harder <radhermit@gentoo.org> +ecasound-2.9.1.ebuild:
+  Version bump.
 
   06 Jul 2013; Christoph Junghans <ottxor@gentoo.org> ecasound-2.9.0.ebuild:
   added prefix support
diff --git a/media-sound/ecasound/ecasound-2.9.1.ebuild b/media-sound/ecasound/ecasound-2.9.1.ebuild
new file mode 100644
index 000000000000..b004bbe369e6
--- /dev/null
+++ b/media-sound/ecasound/ecasound-2.9.1.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/ecasound/ecasound-2.9.1.ebuild,v 1.1 2014/01/04 05:08:29 radhermit Exp $
+
+EAPI=4
+PYTHON_DEPEND="python? 2"
+
+inherit eutils python autotools
+
+DESCRIPTION="a package for multitrack audio processing"
+HOMEPAGE="http://ecasound.seul.org/ecasound"
+SRC_URI="http://ecasound.seul.org/download/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="1"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="alsa audiofile debug doc jack libsamplerate lv2 mikmod ncurses oil osc oss
+python ruby sndfile static-libs test"
+REQUIRED_USE="test? ( lv2 )"
+
+RDEPEND="sys-libs/readline
+	alsa? ( media-libs/alsa-lib )
+	audiofile? ( media-libs/audiofile )
+	jack? ( media-sound/jack-audio-connection-kit )
+	libsamplerate? ( media-libs/libsamplerate )
+	lv2? ( >=media-libs/lilv-0.5.0 )
+	media-libs/ladspa-sdk
+	mikmod? ( media-libs/libmikmod:0 )
+	ncurses? ( sys-libs/ncurses )
+	oil? ( dev-libs/liboil )
+	osc? ( media-libs/liblo )
+	ruby? ( dev-lang/ruby )
+	sndfile? ( media-libs/libsndfile )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+pkg_setup() {
+	if use python ; then
+		python_set_active_version 2
+		python_pkg_setup
+	fi
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.8.1-ldflags.patch
+
+	if use python ; then
+		sed -i -e "s:\$(ecasoundc_libs):\0 $(python_get_library -l):" \
+			pyecasound/Makefile.am || die "sed failed"
+	fi
+
+	eautoreconf
+}
+
+src_configure() {
+	local pyconf
+
+	if use python ; then
+		pyconf="--with-python-includes=${EPREFIX}$(python_get_includedir)
+			--with-python-modules=${EPREFIX}$(python_get_libdir)"
+	fi
+
+	econf \
+		--disable-arts \
+		--enable-shared \
+		--enable-sys-readline \
+		--with-largefile \
+		$(use_enable alsa) \
+		$(use_enable audiofile) \
+		$(use_enable debug) \
+		$(use_enable jack) \
+		$(use_enable libsamplerate) \
+		$(use_enable lv2 liblilv) \
+		$(use_enable ncurses) \
+		$(use_enable oil liboil) \
+		$(use_enable osc liblo) \
+		$(use_enable oss) \
+		$(use_enable python pyecasound) \
+		$(use_enable ruby rubyecasound) \
+		$(use_enable sndfile) \
+		$(use_enable static-libs static) \
+		${pyconf}
+}
+
+src_install() {
+	default
+
+	if use doc ; then
+		dohtml Documentation/*.html
+		dodoc Documentation/programmers_guide/ecasound_programmers_guide.txt
+	fi
+
+	prune_libtool_files
+}
+
+pkg_postinst() {
+	use python && python_mod_optimize ecacontrol.py eci.py pyeca.py
+}
+
+pkg_postrm() {
+	use python && python_mod_cleanup ecacontrol.py eci.py pyeca.py
+}