Version bump.

(Portage version: 2.2.0_alpha89/cvs/Linux x86_64)

4 files changed, 100 insertions, 1 deletions

diff --git a/media-sound/sox/ChangeLog b/media-sound/sox/ChangeLog
index 07230dde3942..fa1f0aaffb52 100644
--- a/media-sound/sox/ChangeLog
+++ b/media-sound/sox/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/sox
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/sox/ChangeLog,v 1.139 2012/02/08 20:39:30 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/sox/ChangeLog,v 1.140 2012/03/07 00:02:09 radhermit Exp $
+
+*sox-14.4.0 (07 Mar 2012)
+
+  07 Mar 2012; Tim Harder <radhermit@gentoo.org> +sox-14.4.0.ebuild,
+  +files/sox-14.4.0-ffmpeg.patch, metadata.xml:
+  Version bump.
 
   08 Feb 2012; Fabian Groffen <grobian@gentoo.org> sox-14.3.2-r1.ebuild:
   Marked ~x64-macos
diff --git a/media-sound/sox/files/sox-14.4.0-ffmpeg.patch b/media-sound/sox/files/sox-14.4.0-ffmpeg.patch
new file mode 100644
index 000000000000..74dcc57901d4
--- /dev/null
+++ b/media-sound/sox/files/sox-14.4.0-ffmpeg.patch
@@ -0,0 +1,11 @@
+--- sox-14.4.0/src/ffmpeg.h
++++ sox-14.4.0/src/ffmpeg.h
+@@ -27,6 +27,8 @@
+ #include <ffmpeg/avformat.h>
+ #endif
+ 
++#include <libavutil/mathematics.h>
++
+ #if defined __SUNPRO_C
+   #pragma enable_warn
+ #elif defined _MSC_VER
diff --git a/media-sound/sox/metadata.xml b/media-sound/sox/metadata.xml
index 0a20177aa452..b50e87abb62c 100644
--- a/media-sound/sox/metadata.xml
+++ b/media-sound/sox/metadata.xml
@@ -5,5 +5,6 @@
   <use>
     <flag name="amr">Enables Adaptive Multi-Rate Audio support</flag>
     <flag name="id3tag">Enables ID3 tagging with id3tag library</flag>
+    <flag name="twolame">Enables twolame support (MPEG Audio Layer 2 encoder)</flag>
   </use>
 </pkgmetadata>
diff --git a/media-sound/sox/sox-14.4.0.ebuild b/media-sound/sox/sox-14.4.0.ebuild
new file mode 100644
index 000000000000..e6394242152a
--- /dev/null
+++ b/media-sound/sox/sox-14.4.0.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/sox/sox-14.4.0.ebuild,v 1.1 2012/03/07 00:02:09 radhermit Exp $
+
+EAPI=4
+inherit eutils flag-o-matic
+
+DESCRIPTION="The swiss army knife of sound processing programs"
+HOMEPAGE="http://sox.sourceforge.net"
+SRC_URI="mirror://sourceforge/sox/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-solaris"
+IUSE="alsa amr ao debug encode ffmpeg flac id3tag ladspa mad ogg openmp oss png pulseaudio sndfile static-libs twolame wavpack"
+
+# libtool required for libltdl
+RDEPEND=">=sys-devel/libtool-2.2.6b
+	>=media-sound/gsm-1.0.12-r1
+	alsa? ( media-libs/alsa-lib )
+	amr? ( media-libs/opencore-amr )
+	ao? ( media-libs/libao )
+	encode? ( >=media-sound/lame-3.98.4 )
+	ffmpeg? ( virtual/ffmpeg )
+	flac? ( media-libs/flac )
+	id3tag? ( media-libs/libid3tag )
+	ladspa? ( media-libs/ladspa-sdk )
+	mad? ( media-libs/libmad )
+	ogg? ( media-libs/libvorbis	media-libs/libogg )
+	png? ( media-libs/libpng sys-libs/zlib )
+	pulseaudio? ( media-sound/pulseaudio )
+	sndfile? ( media-libs/libsndfile )
+	twolame? ( media-sound/twolame )
+	wavpack? ( media-sound/wavpack )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+DOCS=( AUTHORS ChangeLog NEWS README )
+
+src_prepare() {
+	sed -i -e 's:CFLAGS="-g":CFLAGS="$CFLAGS -g":' configure || die #386027
+
+	epatch \
+		"${FILESDIR}"/${PN}-14.3.2-uclibc.patch \
+		"${FILESDIR}"/${P}-ffmpeg.patch
+}
+
+src_configure() {
+	# Fixes wav segfaults. See Bug #35745.
+	append-flags -fsigned-char
+
+	econf \
+		$(use_with alsa) \
+		$(use_with amr amrnb) \
+		$(use_with amr amrwb) \
+		$(use_with ao) \
+		$(use_enable debug) \
+		$(use_with encode lame) \
+		$(use_with ffmpeg) \
+		$(use_with flac) \
+		$(use_with id3tag) \
+		$(use_with ladspa) \
+		$(use_with mad) \
+		$(use_enable openmp gomp) \
+		$(use_with ogg oggvorbis) \
+		$(use_with oss) \
+		$(use_with png) \
+		$(use_with pulseaudio) \
+		$(use_with sndfile) \
+		$(use_enable static-libs static) \
+		$(use_with twolame) \
+		$(use_with wavpack) \
+		--with-distro="Gentoo"
+}
+
+src_install() {
+	default
+	# libltdl is used for loading plugins, keeping libtool files with empty
+	# dependency_libs what otherwise would be -exec rm -f {} +
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+}