version bump

(Portage version: 2.2_rc23/cvs/Linux x86_64)

2 files changed, 76 insertions, 2 deletions

diff --git a/media-sound/mpg123/ChangeLog b/media-sound/mpg123/ChangeLog
index 86fca5ea20a1..15a848f66a7e 100644
--- a/media-sound/mpg123/ChangeLog
+++ b/media-sound/mpg123/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/mpg123
-# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/ChangeLog,v 1.170 2008/12/16 19:25:19 armin76 Exp $
+# Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/ChangeLog,v 1.171 2009/02/11 18:14:53 aballier Exp $
+
+*mpg123-1.6.4 (11 Feb 2009)
+
+  11 Feb 2009; Alexis Ballier <aballier@gentoo.org> +mpg123-1.6.4.ebuild:
+  version bump
 
   16 Dec 2008; Raúl Porcel <armin76@gentoo.org> mpg123-1.6.2.ebuild:
   ia64 stable wrt #250666
diff --git a/media-sound/mpg123/mpg123-1.6.4.ebuild b/media-sound/mpg123/mpg123-1.6.4.ebuild
new file mode 100644
index 000000000000..aa8d9889aa53
--- /dev/null
+++ b/media-sound/mpg123/mpg123-1.6.4.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/mpg123-1.6.4.ebuild,v 1.1 2009/02/11 18:14:53 aballier Exp $
+
+DESCRIPTION="a realtime MPEG 1.0/2.0/2.5 audio player for layers 1, 2 and 3."
+HOMEPAGE="http://www.mpg123.org"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="3dnow 3dnowext alsa altivec arts esd ipv6 jack mmx nas network oss portaudio pulseaudio sdl sse"
+
+RDEPEND="alsa? ( media-libs/alsa-lib )
+	esd? ( media-sound/esound )
+	jack? ( media-sound/jack-audio-connection-kit )
+	nas? ( media-libs/nas )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-sound/pulseaudio )
+	sdl? ( media-libs/libsdl )
+	arts? ( kde-base/arts )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+src_unpack() {
+	unpack ${A}
+	sed -i -e 's:-faltivec::' "${S}"/configure || die "sed failed."
+}
+
+src_compile() {
+	local myaudio
+
+	use alsa && myaudio="${myaudio} alsa"
+	use esd && myaudio="${myaudio} esd"
+	use jack && myaudio="${myaudio} jack"
+	use nas && myaudio="${myaudio} nas"
+	use oss && myaudio="${myaudio} oss"
+	use portaudio && myaudio="${myaudio} portaudio"
+	use pulseaudio && myaudio="${myaudio} pulse"
+	use sdl && myaudio="${myaudio} sdl"
+	use arts && myaudio="${myaudio} arts"
+
+	local mycpu
+
+	if use altivec; then
+		mycpu="--with-cpu=altivec"
+	elif use 3dnowext; then
+		mycpu="--with-cpu=3dnowext"
+	elif use 3dnow; then
+		mycpu="--with-cpu=3dnow"
+	elif use sse; then
+		mycpu="--with-cpu=sse"
+	elif use mmx; then
+		mycpu="--with-cpu=mmx"
+	fi
+
+	econf --disable-dependency-tracking \
+		--with-optimization=0 ${mycpu} \
+		--with-audio="${myaudio}" \
+		$(use_enable network) \
+		$(use_enable ipv6)
+
+	emake || die "emake failed."
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed."
+	dodoc AUTHORS ChangeLog NEWS* README
+}