Version bump wrt bug #483550.

(Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key 675D0D2C)

3 files changed, 96 insertions, 63 deletions

diff --git a/media-sound/cantata/ChangeLog b/media-sound/cantata/ChangeLog
index 743840d5d57a..788f966afb92 100644
--- a/media-sound/cantata/ChangeLog
+++ b/media-sound/cantata/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/cantata
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/cantata/ChangeLog,v 1.18 2013/06/14 23:23:18 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/cantata/ChangeLog,v 1.19 2013/09/04 17:34:51 kensington Exp $
+
+*cantata-1.1.2 (04 Sep 2013)
+
+  04 Sep 2013; Michael Palimaka <kensington@gentoo.org> +cantata-1.1.2.ebuild,
+  -cantata-0.9.2.ebuild:
+  Version bump wrt bug #483550.
 
   14 Jun 2013; Johannes Huber <johu@gentoo.org>
   +files/cantata-1.0.3-audiocd-automagic.patch,
diff --git a/media-sound/cantata/cantata-0.9.2.ebuild b/media-sound/cantata/cantata-0.9.2.ebuild
deleted file mode 100644
index 863d9b242768..000000000000
--- a/media-sound/cantata/cantata-0.9.2.ebuild
+++ /dev/null
@@ -1,62 +0,0 @@
-# Copyright 1999-2013 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/cantata/cantata-0.9.2.ebuild,v 1.2 2013/03/02 21:53:52 hwoarang Exp $
-
-EAPI=5
-KDE_REQUIRED="optional"
-inherit kde4-base
-
-DESCRIPTION="A featureful and configurable Qt4 client for the music player daemon (MPD)"
-HOMEPAGE="http://kde-apps.org/content/show.php?content=147733"
-SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.bz2"
-
-LICENSE="GPL-2"
-SLOT="4"
-KEYWORDS="~amd64 ~x86"
-IUSE="kde mtp phonon replaygain webkit"
-REQUIRED_USE="mtp? ( kde )"
-
-DEPEND="
-	dev-qt/qtcore:4
-	dev-qt/qtdbus:4
-	dev-qt/qtgui:4
-	kde? (
-		media-libs/taglib[asf,mp4]
-		media-libs/taglib-extras
-		mtp? ( media-libs/libmtp )
-	)
-	phonon? ( || ( media-libs/phonon dev-qt/qtphonon:4 ) )
-	replaygain? (
-		media-libs/speex
-		media-libs/taglib[asf,mp4]
-		media-libs/taglib-extras
-		media-sound/mpg123
-		virtual/ffmpeg
-	)
-	webkit? ( dev-qt/qtwebkit:4 )
-"
-RDEPEND="${DEPEND}
-	$(add_kdebase_dep oxygen-icons)
-"
-
-src_configure() {
-	local mycmakeargs=(
-		$(cmake-utils_use_enable kde)
-		$(cmake-utils_use_enable phonon)
-		$(cmake-utils_use_enable replaygain FFMPEG)
-		$(cmake-utils_use_enable replaygain MPG123)
-		$(cmake-utils_use_enable replaygain SPEEXDSP)
-		$(cmake-utils_use_enable mtp)
-	)
-
-	# kde fails to build without taglib
-	# taglib is required to enable replaygain
-	if use kde || use replaygain; then
-		mycmakeargs+=(
-			-DENABLE_TAGLIB=ON
-			-DENABLE_TAGLIB_EXTRAS=ON
-		)
-	fi
-
-	kde4-base_src_configure
-}
diff --git a/media-sound/cantata/cantata-1.1.2.ebuild b/media-sound/cantata/cantata-1.1.2.ebuild
new file mode 100644
index 000000000000..135db63375eb
--- /dev/null
+++ b/media-sound/cantata/cantata-1.1.2.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/cantata/cantata-1.1.2.ebuild,v 1.1 2013/09/04 17:34:51 kensington Exp $
+
+EAPI=5
+KDE_REQUIRED="optional"
+inherit kde4-base
+
+DESCRIPTION="A featureful and configurable Qt4 client for the music player daemon (MPD)"
+HOMEPAGE="https://code.google.com/p/cantata/"
+SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="4"
+KEYWORDS="~amd64 ~x86"
+IUSE="cddb cdparanoia kde lame mtp musicbrainz online-services phonon qt5 replaygain taglib"
+REQUIRED_USE="
+	cddb? ( cdparanoia taglib )
+	cdparanoia? ( || ( cddb musicbrainz )  )
+	lame? ( cdparanoia taglib )
+	mtp? ( taglib )
+	musicbrainz? ( cdparanoia taglib )
+	online-services? ( taglib )
+	qt5? ( !kde !phonon )
+	replaygain? ( taglib )
+"
+
+DEPEND="
+	cddb? ( media-libs/libcddb )
+	cdparanoia? ( media-sound/cdparanoia )
+	lame? ( media-sound/lame )
+	mtp? ( media-libs/libmtp )
+	musicbrainz? ( media-libs/musicbrainz:5 )
+	phonon? ( || ( media-libs/phonon dev-qt/qtphonon:4 ) )
+	qt5? (
+		dev-qt/qtconcurrent:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtxml:5
+	)
+	!qt5? (
+		dev-qt/qtcore:4
+		dev-qt/qtdbus:4
+		dev-qt/qtgui:4
+	)
+	replaygain? (
+		media-libs/speex
+		media-sound/mpg123
+		virtual/ffmpeg
+	)
+	taglib? (
+		media-libs/taglib[asf,mp4]
+		media-libs/taglib-extras
+		!kde? ( sys-fs/udisks:2 )
+	)
+	dev-libs/qjson
+	sys-libs/zlib
+	x11-libs/libX11
+"
+RDEPEND="${DEPEND}
+	$(add_kdebase_dep oxygen-icons)
+"
+
+src_prepare() {
+	kde4-base_src_prepare
+
+	rm -rf 3rdparty/qjson/
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_enable cddb)
+		$(cmake-utils_use_enable cdparanoia)
+		$(cmake-utils_use_enable kde)
+		$(cmake-utils_use_enable lame)
+		$(cmake-utils_use_enable mtp)
+		$(cmake-utils_use_enable musicbrainz)
+		$(cmake-utils_use_enable online-services ONLINE_SERVICES)
+		$(cmake-utils_use_enable phonon)
+		$(cmake-utils_use_enable qt5)
+		$(cmake-utils_use_enable replaygain FFMPEG)
+		$(cmake-utils_use_enable replaygain MPG123)
+		$(cmake-utils_use_enable replaygain SPEEXDSP)
+		$(cmake-utils_use_enable taglib)
+		$(cmake-utils_use_enable taglib TAGLIB_EXTRAS)
+		-DENABLE_UDISKS2=ON
+	)
+	kde4-base_src_configure
+}